"Fossies" - the Fresh Open Source Software Archive

Member "UNICORE-Client-7.4.1/applications/povca2.pov" (9 Aug 2018, 4946 Bytes) of package /windows/misc/UNICORE_Client-7.4.1-win32.win32.x86.zip:


As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) POV-Ray source code syntax highlighting (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file.

    1 // POV-Ray 3.6 Scene File "povca2.pov"
    2 // created by Friedrich A. Lohmueller, 2003
    3 // email: Friedrich.Lohmueller_at_t-online.de
    4 // homepage: http://www.f-lohmueller.de
    5 //
    6 #version 3.5;
    7 #global_settings { assumed_gamma 1.0 }
    8 #default{ finish{ ambient 0.1 diffuse 0.9 }} 
    9 global_settings { noise_generator 1 }
   10 
   11 #include "colors.inc"
   12 #include "textures.inc"
   13 #include "glass.inc"
   14 // camera -----------------------------------------------------
   15 #declare Camera_0 = camera {ultra_wide_angle angle 75       
   16                             location  <0.0 , 1.0, -12.0>
   17                             right x*image_width/image_height
   18                             look_at <0.0 , 5.0, 0.0>}
   19 #declare Camera_1 = camera {ultra_wide_angle angle 85       
   20                             location   <-9, 14, -15>
   21                             right x*image_width/image_height
   22                             look_at   < -2, 3.0,-4.5>}
   23 #declare Camera_2 = camera {ultra_wide_angle angle 75       
   24                             location  < 10, 3, -11.0>
   25                             right x*image_width/image_height
   26                             look_at  < -3, 1, 0>}
   27 camera{Camera_1} 
   28 // sun --------------------------------------------------------
   29 light_source{<1500,2500,-2500> color White}
   30 // sky ---------------------------------------------------------------------
   31 sky_sphere { pigment { gradient <0,1,0>
   32                        color_map { [0.00 rgb <1.0,1.0,1.0>]
   33                                    [0.30 rgb <0.0,0.1,1.0>]
   34                                    [0.70 rgb <0.0,0.1,1.0>]
   35                                    [1.00 rgb <1.0,1.0,1.0>] 
   36                                  } 
   37                        scale 2         
   38                      } // end of pigment
   39            } //end of skysphere
   40 // ground ------------------------------------------------------------------
   41 difference{plane{<0,1,0>, 0}
   42            box{<-15,-5,-15>,<15,1,15>}
   43        texture{ pigment { color rgb <0.85,0.55,0.30>}
   44                 normal  { bumps 0.75 scale 0.025  }
   45                 finish  { phong 0.1 } 
   46               } // end of texture
   47      } // end of difference
   48 // water -----------------------------------------------------
   49  box{<-15,-5,-15>,<15,-0.80,15>
   50    texture{T_Green_Glass pigment{quick_color Turquoise}
   51            normal{ ripples 0.5 scale 0.25}
   52                    finish{ phong 0.1 }
   53           }
   54    interior{I_Glass}
   55     }
   56 //--------------------------------------------------------------------------
   57 //------------------------------------------------------------
   58 #declare Walltex =  texture{ pigment{ color White}
   59                              finish { phong 1}}
   60 #declare Rooftex =  texture{ pigment{ color rgb<0.3,0,0>}
   61                              finish { phong 1}}
   62 // Mauern im Burggraben - Walls in the moat ------------------
   63 #declare G_Wall =
   64 box {<-15.3,-6,-0.3 >,< 15.3,  0.2,0.3> rotate<-5,0,0> 
   65      texture{Walltex}}
   66 // zeichne 4 GrabenMauern ----------------------------
   67 object{G_Wall rotate<0,  0,0> translate<  0,-0.25,-15>}
   68 object{G_Wall rotate<0,180,0> translate<  0,-0.25, 15>}
   69 object{G_Wall rotate<0, 90,0> translate<-15,-0.25,  0>}
   70 object{G_Wall rotate<0,-90,0> translate< 15,-0.25,  0>}
   71 //----------------------- Turm  ------------------------------
   72 #declare TR =  2.0;   //TurmRadius tower radius
   73 #declare TH =  5.0;   //TurmH�he   tower height
   74 //------------------------------------------------------------
   75 #declare Tower =  union{     
   76 cone{<0,-TH,0>,TR+1.0,<0,0,0>,TR   texture{Walltex}}
   77 cylinder {<0,0,0>,<0,TH,0>,TR      texture{Walltex}}
   78 cylinder {<0,0.0,0>,<0,0.1,0>,2.05 texture{Walltex}}
   79 cylinder {<0,2.5,0>,<0,2.6,0>,2.05 texture{Walltex}}
   80 cone{<0,0,0>,TR+0.5,<0,TR+0.5,0>,0
   81                     translate<0,TH,0> texture{Rooftex}}
   82 cone{<0,0,0>,TR -0.2,<0,2*TR+0.5,0>,0
   83                     translate<0,TH,0> texture{Rooftex}}
   84 }// --- Ende Turm-Definition -- end of Tower definition ------
   85 //----- SchlossMauern - The walls of the castle --------------
   86 #declare Wall = union{
   87   box {<-4,0,-0.3>,< 4,3.5,0.3> }
   88   box {<-4.5,-6,-0.3 >,<4.5,0,0.3> rotate<-5,0,0>}
   89   texture{Walltex}}
   90 // - Zusammenbau des Schlosses --- Building of the castle ---
   91 object{Tower translate<-6, 0,-6>}
   92 object{Tower translate< 6, 0,-6>}
   93 object{Tower translate< 6, 0, 6>}
   94 object{Tower translate<-6, 0, 6>}
   95 // ---------------- zeichne 4 Mauern -------------------------
   96 difference{object{Wall} // das Tor -- the door -----
   97            box{<-1,0,-0.4>,<1,2,0.4>       texture{Walltex}}
   98            cylinder{<0,2,-0.5>,<0,2,0.5>,1 texture{Walltex}}
   99                              translate< 0,0,-6>}
  100 object{Wall rotate<0,  0,0> translate< 0, 0, 6>}
  101 object{Wall rotate<0, 90,0> translate<-6, 0, 0>}
  102 object{Wall rotate<0,-90,0> translate< 6, 0, 0>}
  103 // ------------------- Hof-Boden - Floor inside the castle --
  104 box {<-6,-4,-6>,< 6,0.01,6>
  105      texture{pigment{color Gray90}
  106              finish {ambient 0.1 diffuse 0.9 phong 1}}}
  107 //--------------------------------------------------------end-