"Fossies" - the Fresh Open Source Software Archive

Member "src/posterazor.pro" (28 Sep 2008, 1751 Bytes) of package /windows/misc/PosteRazor-1.9.5-Source.zip:


As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) Prolog source code syntax highlighting (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file.

    1 TARGET = PosteRazor
    2 
    3 DESTDIR = $$PWD
    4 
    5 SOURCES += \
    6     controller.cpp \
    7     mainwindow.cpp \
    8     paintcanvas.cpp \
    9     pdfwriter.cpp \
   10     posterazorcore.cpp \
   11     snapspinbox.cpp \
   12     types.cpp \
   13     wizardcontroller.cpp \
   14     main.cpp
   15 
   16 HEADERS += \
   17     controller.h \
   18     imageloaderinterface.h \
   19     mainwindow.h \
   20     paintcanvas.h \
   21     paintcanvasinterface.h \
   22     pdfwriter.h \
   23     posterazorcore.h \
   24     snapspinbox.h \
   25     types.h \
   26     wizardcontroller.h
   27 
   28 win32:DEFINES -= \
   29     UNICODE
   30     
   31 macx:QMAKE_INFO_PLIST = \
   32     Info.plist
   33 
   34 macx:ICON = \
   35     posterazor.icns
   36 
   37 macx:CONFIG += \
   38     x86 ppc
   39 
   40 macx:QMAKE_MAC_SDK = \
   41     /Developer/SDKs/MacOSX10.4u.sdk
   42 
   43 macx:QMAKE_MACOSX_DEPLOYMENT_TARGET = \
   44     10.3
   45 
   46 FORMS += \
   47     mainwindow.ui
   48 
   49 RESOURCES += \
   50     posterazor.qrc
   51 
   52 RC_FILE += \
   53     posterazor.rc
   54 
   55 TRANSLATIONS += \
   56     de.ts \
   57     en.ts \
   58     es.ts \
   59     fi.ts \
   60     fr.ts \
   61     it.ts \
   62     nl.ts \
   63     pl.ts \
   64     pt_BR.ts \
   65     zh_CN.ts
   66 
   67 # Uncomment the following line in order to build PosteRazor with FreeImage
   68 #DEFINES += FREEIMAGE_LIB
   69 
   70 contains (DEFINES, FREEIMAGE_LIB) {
   71     SOURCES += \
   72         imageloaderfreeimage.cpp
   73 
   74     HEADERS += \
   75         imageloaderfreeimage.h
   76 
   77     win32:INCLUDEPATH += \
   78         thirdparty/FreeImage/Dist
   79 
   80     win32:LIBS += \
   81         thirdparty/FreeImage/Dist/FreeImage.lib
   82 
   83     macx:INCLUDEPATH += \
   84         /usr/local/include
   85 
   86     unix:LIBS += \
   87         -lfreeimage
   88 } else {
   89     SOURCES += \
   90         imageloaderqt.cpp
   91 
   92     HEADERS += \
   93         imageloaderqt.h
   94 
   95     macx|win32:QTPLUGIN += \
   96         qgif \
   97         qjpeg \
   98         qtiff
   99 }
  100 
  101 !contains(CONFIG, build_pass) system(lrelease posterazor.pro)