"Fossies" - the Fresh Open Source Software Archive

Member "xorriso-1.5.4/configure.ac" (30 Jan 2021, 20917 Bytes) of package /linux/misc/xorriso-1.5.4.pl02.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the last Fossies "Diffs" side-by-side code changes report for "configure.ac": 1.5.2_vs_1.5.4.

    1 
    2 # configure.ac stems from xorriso/configure_ac.txt and leads to ./configure
    3 # Copyright (c) 2007 - 2021 Thomas Schmitt <scdbackup@gmx.net>
    4 # Provided under GPL version 2 or later.
    5 
    6 AC_INIT([xorriso], [1.5.4], [http://libburnia-project.org])
    7 AC_PREREQ([2.50])
    8 
    9 AC_CANONICAL_HOST
   10 AC_CANONICAL_TARGET
   11 
   12 LIBBURNIA_SET_FLAGS
   13 
   14 AM_INIT_AUTOMAKE([subdir-objects])
   15 AC_CONFIG_MACRO_DIR([./])
   16 
   17 dnl Let autoheader produce config.h.in and let configure produce config.h
   18 dnl This saves about 500 characters of compile message per source file.
   19 AC_CONFIG_HEADER(config.h)
   20 
   21 AH_TEMPLATE([Xorriso_standalonE], [Define to prepare sources for statically linked xorriso])
   22 AC_DEFINE([Xorriso_standalonE], [])
   23 
   24 BURN_MAJOR_VERSION=1
   25 BURN_MINOR_VERSION=5
   26 BURN_MICRO_VERSION=4
   27 AC_SUBST(BURN_MAJOR_VERSION)
   28 AC_SUBST(BURN_MINOR_VERSION)
   29 AC_SUBST(BURN_MICRO_VERSION)
   30 
   31 LIBISOFS_MAJOR_VERSION=1
   32 LIBISOFS_MINOR_VERSION=5
   33 LIBISOFS_MICRO_VERSION=4
   34 AC_SUBST(LIBISOFS_MAJOR_VERSION)
   35 AC_SUBST(LIBISOFS_MINOR_VERSION)
   36 AC_SUBST(LIBISOFS_MICRO_VERSION)
   37 
   38 dnl The API version codes are defined in libisoburn/libisoburn.h
   39 dnl #define  isoburn_header_version_*
   40 
   41 
   42 AC_PREFIX_DEFAULT([/usr/local])
   43 test "$prefix" = "NONE" && prefix=$ac_default_prefix
   44 
   45 dnl ts B90405 : Disabled on advise of Ross Burton
   46 dnl AM_MAINTAINER_MODE
   47 
   48 AM_PROG_CC_C_O
   49 AC_C_CONST
   50 AC_C_INLINE
   51 AC_C_BIGENDIAN
   52 
   53 dnl Large file support
   54 AC_SYS_LARGEFILE
   55 AC_FUNC_FSEEKO
   56 AC_CHECK_FUNC([fseeko])
   57 if test ! $ac_cv_func_fseeko; then
   58    AC_ERROR([Libburn requires largefile support.])
   59 fi
   60 
   61 AH_TEMPLATE([ICONV_CONST], [Whether to apply const qualifier to iconv inbuf])
   62 if test x$XORRISO_OLD_ICONV_CONFIGURE = x
   63 then
   64 
   65 dnl ts B00410 : To detect the need for -liconv and const argument of iconv()
   66 LIBBURNIA_CHECK_ICONV
   67 dnl ts B00411 : To abort configuration if iconv() still cannot be compiled
   68 LIBBURNIA_ASSERT_ICONV
   69 
   70 else
   71 
   72 dnl Outdated: produces double -liconv and warnings about parameter mismatch
   73 dnl If iconv(3) is in an extra libiconv, then it gets added to variable LIBS.
   74 dnl If not, then no -liconv will be added.
   75 AC_CHECK_LIB(iconv, iconv, , )
   76 dnl GNU iconv has no function iconv() but libiconv() and a macro iconv()
   77 AC_CHECK_LIB(iconv, libiconv, , )
   78 
   79 fi
   80 
   81 AC_PROG_LIBTOOL
   82 AC_SUBST(LIBTOOL_DEPS)
   83 dnl LIBTOOL="$LIBTOOL --silent"
   84 
   85 AC_PROG_INSTALL
   86 
   87 AC_CHECK_HEADERS()
   88 
   89 AC_CHECK_MEMBER([struct tm.tm_gmtoff],
   90 	[AC_DEFINE(HAVE_TM_GMTOFF, 1,
   91 		[Define this if tm structure includes a tm_gmtoff entry.])],
   92 	,
   93 	[#include <time.h>])
   94 
   95 dnl Check if non standard timegm() function is available
   96 AC_CHECK_DECL([timegm],
   97         [AC_DEFINE(HAVE_TIMEGM, 1, [Define this if timegm function is available])],
   98         ,
   99         [#include <time.h>])
  100 
  101 dnl Whether timezone is an integer variable
  102 AH_TEMPLATE([Libburnia_timezonE], [Either timezone or 0])
  103 LIBBURNIA_TRY_TIMEZONE
  104 if test x$LIBBURNIA_TIMEZONE = xtimezone
  105 then
  106    AC_DEFINE([Libburnia_timezonE], [timezone])
  107 else
  108    AC_DEFINE([Libburnia_timezonE], [0])
  109 fi
  110 
  111 dnl Check if non standard eaccess() function is available
  112 AC_CHECK_DECL([eaccess],
  113         [AC_DEFINE(HAVE_EACCESS, 1, [Define this if eaccess function is available])],
  114         ,
  115         [#include <unistd.h>])
  116 
  117 THREAD_LIBS=-lpthread
  118 AC_SUBST(THREAD_LIBS)
  119 
  120 TARGET_SHIZZLE
  121 AC_SUBST(ARCH)
  122 AC_SUBST(LIBBURNIA_PKGCONFDIR)
  123 AC_SUBST(LIBBURN_ARCH_LIBS)
  124 
  125 dnl Check the preconditions for using statvfs() in sg-dummy
  126 dnl (sg-linux and sg-freebsd use statvfs() unconditionally)
  127 AH_TEMPLATE([Libburn_os_has_statvfS], [Define to use statvfs() with libburn stdio])
  128 STATVFS_DEF=-DLibburn_os_has_statvfS
  129 AC_CHECK_HEADER(sys/statvfs.h, X=, STATVFS_DEF=)
  130 AC_CHECK_FUNC([statvfs], X=, STATVFS_DEF=)
  131 if test x$STATVFS_DEF = x-DLibburn_os_has_statvfS
  132 then
  133     AC_DEFINE([Libburn_os_has_statvfS], [])
  134 fi
  135 
  136 dnl xorriso-dd-target is addicted to the Linux kernel and util-linux lsblk
  137 if uname -s | grep '^Linux' >/dev/null
  138 then
  139   XORRISO_DD_TARGET=xorriso-dd-target/xorriso-dd-target
  140   XORRISO_DD_TARGET_MAN=xorriso-dd-target/xorriso-dd-target.1
  141   XORRISO_DD_TARGET_TEXI=xorriso-dd-target/xorriso-dd-target.texi
  142   echo "enabled  installation of xorriso-dd-target/xorriso-dd-target"
  143 else
  144   XORRISO_DD_TARGET=
  145   XORRISO_DD_TARGET_MAN=
  146   XORRISO_DD_TARGET_TEXI=
  147   echo "disabled installation of xorriso-dd-target/xorriso-dd-target"
  148 fi
  149 AC_SUBST(XORRISO_DD_TARGET)
  150 AC_SUBST(XORRISO_DD_TARGET_MAN)
  151 AC_SUBST(XORRISO_DD_TARGET_TEXI)
  152 
  153 dnl Add compiler-specific flags
  154 
  155 dnl See if the user wants aggressive optimizations of the code
  156 AC_ARG_ENABLE(debug,
  157 [  --enable-debug          Disable aggressive optimizations [default=yes]],
  158               , enable_debug=yes)
  159 if test x$enable_debug != xyes; then
  160     if test x$GCC = xyes; then
  161         CFLAGS="-O3 $CFLAGS"
  162         CFLAGS="-fexpensive-optimizations $CFLAGS"
  163     fi
  164     CFLAGS="-DNDEBUG $CFLAGS"
  165 else
  166     if test x$GCC = xyes; then
  167         CFLAGS="-g -pedantic -Wall -Wextra -Wno-unused-parameter -Wno-char-subscripts -Wno-strict-aliasing $CFLAGS"
  168     fi
  169     CFLAGS="-DDEBUG $CFLAGS"
  170 fi
  171 
  172 
  173 dnl Determine target directory for libisoburn-*.pc
  174 dnl Important: Must be performed _after_ TARGET_SHIZZLE
  175 dnl
  176 LIBBURNIA_SET_PKGCONFIG
  177 
  178 
  179 AH_TEMPLATE([Xorriso_with_readlinE], [Define to use libreadline])
  180 AC_ARG_ENABLE(libreadline,
  181 [  --enable-libreadline    Enable use of libreadline by xorriso, default=yes],
  182                , enable_libreadline=yes)
  183 if test x$enable_libreadline = xyes; then
  184 dnl Check whether there is readline-devel and readline-runtime.
  185 dnl If not, erase this macro which would enable use of readline(),add_history()
  186     READLINE_DEF="-DXorriso_with_readlinE"
  187 
  188     if test x$XORRISO_OLD_READLINE_CONFIGURE = x
  189     then
  190 
  191 dnl ts B00411 : To disable readline if not all needed functions are present
  192         LIBBURNIA_ASSERT_READLINE
  193 
  194     else
  195 dnl The empty yes case obviously causes -lreadline to be linked
  196         AC_CHECK_HEADER(readline/readline.h, AC_CHECK_LIB(readline, readline, , READLINE_DEF= ), READLINE_DEF= )
  197 dnl The X= in the yes case prevents that -lreadline gets linked twice
  198         AC_CHECK_HEADER(readline/history.h, AC_CHECK_LIB(readline, add_history, X= , READLINE_DEF= ), READLINE_DEF= )
  199 
  200     fi
  201 else
  202     READLINE_DEF=
  203     echo "disabled libreadline"
  204 fi
  205 if test x$READLINE_DEF = x; then
  206     AH_TEMPLATE([Xorriso_with_editlinE],
  207                 [Define to use libedit if not libreadline])
  208     if test x$enable_libreadline = xyes; then
  209         libedit_deflt=yes
  210     else
  211         libedit_deflt=no
  212     fi
  213     AC_ARG_ENABLE(libedit,
  214 [  --enable-libedit        Enable use of libedit by xorriso if not libreadline,                           default= setting of --enable-libreadline],
  215                    , enable_libedit=$libedit_deflt)
  216     if test x$enable_libedit = xyes; then
  217         READLINE_DEF="-DXorriso_with_editlinE"
  218 
  219         LIBBURNIA_ASSERT_EDITLINE
  220 
  221     else
  222         READLINE_DEF=
  223         echo "disabled libedit"
  224     fi
  225 fi
  226 if test x$READLINE_DEF = x-DXorriso_with_readlinE
  227 then
  228     AC_DEFINE([Xorriso_with_readlinE], [])
  229 elif test x$READLINE_DEF = x-DXorriso_with_editlinE
  230 then
  231     AC_DEFINE([Xorriso_with_editlinE], [])
  232 fi
  233 
  234 
  235 AH_TEMPLATE([Libisofs_with_aaip_acL], [Define to use ACL capabilities])
  236 AC_ARG_ENABLE(libacl,
  237 [  --enable-libacl         Enable use of ACL functions by libisofs, default=yes],
  238                , enable_libacl=yes)
  239 LIBACL_DEF=
  240 has_acl_h_but_no_func=0
  241 if test x$LIBBURNIA_SUPP_ACL = xlibacl
  242 then
  243     if test x$enable_libacl = xyes; then
  244 dnl Check whether there is libacl-devel and libacl-runtime.
  245 dnl If not, erase this macro which would enable use of acl_to_text and others
  246         LIBACL_DEF="-DLibisofs_with_aaip_acL"
  247 dnl The empty yes case obviously causes -lacl to be linked
  248         AC_CHECK_HEADER(sys/acl.h, AC_CHECK_LIB(acl, acl_to_text, , has_acl_h_but_no_libacl=1 ), LIBACL_DEF= )
  249         if test "$has_acl_h_but_no_libacl" = 1
  250         then
  251             AC_CHECK_LIB(c, acl_to_text, X= , LIBACL_DEF= )
  252         fi
  253     fi
  254 fi
  255 if test x$LIBACL_DEF = x-DLibisofs_with_aaip_acL
  256 then
  257     AC_DEFINE([Libisofs_with_aaip_acL], [])
  258     if test x$has_acl_h_but_no_libacl = x1
  259     then
  260         echo "enabled  local processing of ACL"
  261     else
  262         echo "enabled  libacl, local processing of ACL"
  263     fi
  264 else
  265     echo "disabled local processing of ACL"
  266 fi
  267 
  268 
  269 AH_TEMPLATE([Libisofs_with_aaip_xattR],
  270             [Define to use Linux xattr capabilities])
  271 AH_TEMPLATE([Libisofs_with_sys_xattR],
  272             [Define to include Linux sys/xattr.h instead of attr/xattr.h])
  273 AH_TEMPLATE([Libisofs_with_freebsd_extattR],
  274             [Define to use FreeBSD extattr capabilities])
  275 AC_ARG_ENABLE(xattr,
  276               [  --enable-xattr          Enable use of extended file attributes by libisofs, default=yes],
  277               , enable_xattr=yes)
  278 AC_ARG_ENABLE(xattr_h_pref_attr,
  279               [  --enable-xattr-h-pref-attr   Prefer include file attr/xattr.h over sys/xattr.h, default=no],
  280               , enable_xattr_h_pref_attr=no)
  281 
  282 XATTR_DEF=
  283 if test x"$LIBBURNIA_SUPP_FATTR" = xxattr
  284 then
  285     if test "x$enable_xattr" = xyes; then
  286 dnl Check whether there is the header for Linux xattr.
  287 dnl If not, erase this macro which would enable use of listxattr and others
  288         XATTR_A_DEF=
  289         XATTR_S_DEF=
  290         if test x"$enable_xattr_h_pref_attr" = xyes
  291         then
  292             echo "prefering include file attr/xattr.h over sys/attr.h"
  293             XATTR_A_DEF=1
  294             AC_CHECK_HEADER(attr/xattr.h, AC_CHECK_LIB(c, listxattr, X= ,
  295                                                  XATTR_A_DEF= ), XATTR_A_DEF= )
  296             if test x"$XATTR_A_DEF" = x1
  297             then
  298                 XATTR_DEF="-DLibisofs_with_aaip_xattR"
  299             else
  300                 XATTR_S_DEF=1
  301                 AC_CHECK_HEADER(sys/xattr.h, AC_CHECK_LIB(c, listxattr, X= ,
  302                                                  XATTR_S_DEF= ), XATTR_S_DEF= )
  303                 if test x"$XATTR_S_DEF" = x1
  304                 then
  305                     XATTR_DEF="-DLibisofs_with_aaip_xattR"
  306                     AC_DEFINE([Libisofs_with_sys_xattR], [])
  307                 fi
  308             fi
  309         else
  310             XATTR_S_DEF=1
  311             AC_CHECK_HEADER(sys/xattr.h, AC_CHECK_LIB(c, listxattr, X= ,
  312                                                  XATTR_S_DEF= ), XATTR_S_DEF= )
  313             if test x"$XATTR_S_DEF" = x1
  314             then
  315                 XATTR_DEF="-DLibisofs_with_aaip_xattR"
  316                 AC_DEFINE([Libisofs_with_sys_xattR], [])
  317             else
  318                 XATTR_A_DEF=1
  319                 AC_CHECK_HEADER(attr/xattr.h, AC_CHECK_LIB(c, listxattr, X= ,
  320                                                  XATTR_A_DEF= ), XATTR_A_DEF= )
  321                 if test x"$XATTR_A_DEF" = x1
  322                 then
  323                     XATTR_DEF="-DLibisofs_with_aaip_xattR"
  324                 fi
  325             fi
  326         fi
  327         if test x"$XATTR_S_DEF" = x1
  328         then
  329             echo "decided  to include file sys/attr.h"
  330         elif test x"$XATTR_A_DEF" = x1
  331         then
  332             echo "decided  to include file attr/xattr.h"
  333         fi
  334     fi
  335 elif test x"$LIBBURNIA_SUPP_FATTR" = xextattr
  336 then
  337     if test "x$enable_xattr" = xyes; then
  338         XATTR_DEF="-DLibisofs_with_freebsd_extattR"
  339         AC_CHECK_HEADER(sys/extattr.h, AC_CHECK_LIB(c, extattr_list_file, X=,
  340                                                     XATTR_DEF= ), XATTR_DEF= )
  341     fi
  342 fi
  343 
  344 if test x$XATTR_DEF = x-DLibisofs_with_aaip_xattR
  345 then
  346     AC_DEFINE([Libisofs_with_aaip_xattR], [])
  347     echo "enabled  xattr, local processing of extended file attributes Linux style"
  348 elif test x$XATTR_DEF = x-DLibisofs_with_freebsd_extattR
  349 then
  350     AC_DEFINE([Libisofs_with_freebsd_extattR], [])
  351     echo "enabled  extattr, local processing of extended file attributes FreeBSD style"
  352 else
  353     echo "disabled local processing of extended file attributes"
  354 fi
  355 
  356 
  357 AH_TEMPLATE([Libisofs_with_zliB], [Define to use compression via zlib])
  358 AH_TEMPLATE([LIBJTE_WITH_ZLIB], [Allow libjte to use zlib])
  359 AC_ARG_ENABLE(zlib,
  360 [  --enable-zlib           Enable use of zlib by libisofs, default=yes],
  361                , enable_zlib=yes)
  362 if test x$enable_zlib = xyes; then
  363 dnl Check whether there is the header for zlib.
  364 dnl If not, erase this macro which would enable use of compress2() and others.
  365 dnl Linking fails on SuSE 9.0 because zlib has compress2() but lacks 
  366 dnl compressBound(). So compressBound is the more modern thing to test.
  367 dnl The empty parameter after "compressBound" causes -lz.
  368     ZLIB_DEF=yes
  369     AC_CHECK_HEADER(zlib.h, AC_CHECK_LIB(z, compressBound, , ZLIB_DEF= ), ZLIB_DEF= )
  370 else
  371     echo "disabled use of zlib"
  372     ZLIB_DEF=
  373 fi
  374 if test x$ZLIB_DEF = xyes
  375 then
  376     AC_DEFINE([Libisofs_with_zliB], [])
  377     AC_DEFINE([LIBJTE_WITH_ZLIB], [])
  378 fi
  379 
  380 # There are Linuxes with no public generic SCSI interface
  381 LIBBURNIA_CHECK_LINUX_SCSI
  382 
  383 # libjte source is included in GNU xorriso. Enable it if zlib is enabled.
  384 AH_TEMPLATE([Xorriso_with_libjtE],
  385             [Define to use Jigdo Template Extraction via libjte])
  386 AH_TEMPLATE([Libisofs_with_libjtE],
  387             [Define to use Jigdo Template Extraction via libjte])
  388 if test x$ZLIB_DEF = xyes
  389 then
  390     AC_DEFINE([Xorriso_with_libjtE], [])
  391     AC_DEFINE([Libisofs_with_libjtE], [])
  392     LIBJTE_DEF=yes
  393     echo "enabled  built-in libjte"
  394 else
  395     LIBJTE_DEF=
  396     echo "disabled libjte because zlib not enabled or not available"
  397 fi
  398 
  399 
  400 AH_TEMPLATE([THREADED_CHECKSUMS],
  401             [Define to use multi-threading in built-in libjte])
  402 AC_ARG_ENABLE(jtethreads,
  403 [  --enable-jtethreads     Enable multi-threading in libjte, default=yes],
  404                , enable_jtethreads=yes) 
  405 if test x$LIBJTE_DEF = xyes
  406 then
  407     if test "x$enable_jtethreads" = xyes; then
  408         mem_LDFLAGS="$LDFLAGS"
  409         LDFLAGS="$LDFLAGS $THREAD_LIBS"
  410         AC_MSG_CHECKING([for pthread_cancel()]) 
  411         AC_TRY_LINK([#include <pthread.h>],
  412                     [pthread_cancel((pthread_t) NULL);],
  413                     [],
  414                     [enable_jtethreads=no])
  415         AC_MSG_RESULT([$enable_jtethreads])
  416         LDFLAGS="$mem_LDFLAGS"
  417     fi
  418     if test "x$enable_jtethreads" = xyes; then
  419         AC_DEFINE([THREADED_CHECKSUMS], [])
  420         echo "enabled  multi-threading in libjte"
  421     else
  422         echo "disabled multi-threading in libjte"
  423     fi
  424 
  425 fi
  426 
  427 
  428 AH_TEMPLATE([LIBJTE_WITH_LIBBZ2],
  429             [Define to use libbz2 by built-in libjte])
  430 AC_ARG_ENABLE(libbz2,
  431 [  --enable-libbz2         Enable use of libbz2 by libjte, default=yes],
  432                , enable_libbz2=yes)
  433 if test "x$enable_libbz2" = xyes -a x$LIBJTE_DEF = xyes ; then
  434 dnl Check whether there is the header for libbz2.
  435     BZIP2_DEF=yes
  436     AC_CHECK_HEADER(bzlib.h, AC_CHECK_LIB(bz2, BZ2_bzCompressInit, , BZIP2_DEF= ), BZIP2_DEF= )
  437 else
  438     BZIP2_DEF=
  439 fi
  440 if test x$BZIP2_DEF = xyes
  441 then
  442     AC_DEFINE([LIBJTE_WITH_LIBBZ2], [])
  443     BZIP2_DEF="-DLIBJTE_WITH_LIBBZ2"
  444 fi
  445 
  446 
  447 case $host_os in
  448     cygwin*|mingw*)
  449         default_libcdio=yes
  450         ;;
  451     *)
  452         default_libcdio=no
  453         ;;
  454 esac
  455 AH_TEMPLATE([Libburn_use_libcdiO], [Define to use libcdio as system adapter])
  456 AC_ARG_ENABLE(libcdio,
  457 [  --enable-libcdio        Enable use of libcdio as system adapter, default=no (except on MSWindows)],
  458                , enable_libcdio=$default_libcdio)
  459 if test x$enable_libcdio = xyes; then
  460 dnl Check whether there is libcdio-devel and libcdio-runtime.
  461 dnl If not, erase this macro
  462     LIBCDIO_DEF="-DLibburn_use_libcdiO"
  463 dnl The empty yes case obviously causes -lcdio to be linked
  464     AC_CHECK_HEADER(cdio/cdio.h, AC_CHECK_LIB(cdio, mmc_last_cmd_sense, , LIBCDIO_DEF= ), LIBCDIO_DEF= )
  465 else
  466     LIBCDIO_DEF=
  467 fi
  468 if test x$LIBCDIO_DEF = x
  469 then
  470     if test x$enable_libcdio = xyes
  471     then
  472       echo "WARNING: could not enable use of libcdio as system adapter"
  473     fi
  474 else
  475     if echo " $CFLAGS $LDFLAGS " | grep ' -static ' >/dev/null
  476     then
  477       echo "WARNING : found option -static in CFLAGS or LDFLAGS"
  478       echo "WARNING : libcdio API conflicts with inner symbols of xorriso"
  479       echo "WARNING : use of libcdio as system adapter disabled"
  480       LIBCDIO_DEF=
  481     else
  482       echo "enabled  use of libcdio as system adapter"
  483     fi
  484 fi
  485 if test x$LIBCDIO_DEF = x-DLibburn_use_libcdiO
  486 then
  487     AC_DEFINE([Libburn_use_libcdiO], [])
  488 fi
  489 
  490 
  491 AH_TEMPLATE([Xorriso_allow_external_filterS], [Define to allow xorriso to start external filter processes])
  492 AC_ARG_ENABLE(external-filters,
  493 [  --enable-external-filters   Enable use of external filter programs by xorriso, default=yes],
  494                , enable_external_filters=yes)
  495 if test x"$enable_external_filters" = xyes; then
  496     EXTF_DEF="-DXorriso_allow_external_filterS"
  497     echo "enabled  xorriso external filter programs"
  498 else
  499     EXTF_DEF=
  500     echo "disabled xorriso external filter programs"
  501 fi
  502 if test x$EXTF_DEF = x-DXorriso_allow_external_filterS
  503 then
  504     AC_DEFINE([Xorriso_allow_external_filterS], [])
  505 fi
  506 
  507 
  508 AH_TEMPLATE([Xorriso_allow_extf_suiD], [Define to allow external filters to xorriso when running under setuid])
  509 AC_ARG_ENABLE(external-filters-setuid,
  510 [  --enable-external-filters-setuid   Enable xorriso external filter programs under setuid, default=no],
  511                , enable_external_filters_setuid=no)
  512 if test x$enable_external_filters_setuid = xyes; then
  513     EXTF_SUID_DEF="-DXorriso_allow_extf_suiD"
  514     echo "enabled  xorriso external filter programs under setuid"
  515 else
  516     EXTF_SUID_DEF=
  517     echo "disabled xorriso external filter programs under setuid"
  518 fi
  519 if test x$EXTF_SUID_DEF = x-DXorriso_allow_extf_suiD
  520 then
  521     AC_DEFINE([Xorriso_allow_extf_suiD], [])
  522 fi
  523 
  524 AH_TEMPLATE([Xorriso_allow_launch_frontenD], [Define to allow xorriso command -launch_frontend])
  525 AC_ARG_ENABLE(launch-frontend,
  526 [  --enable-launch-frontend        Enable start of piped frontend program by xorriso, default=yes],
  527                , enable_launch_frontend=yes)
  528 if test x"$enable_launch_frontend" = xyes; then
  529     LFRONT_DEF="-DXorriso_allow_launch_frontenD"
  530     echo "enabled  xorriso command -launch_frontend"
  531 else
  532     LFRONT_DEF=
  533     echo "disabled xorriso command -launch_frontend"
  534 fi
  535 if test x$LFRONT_DEF = x-DXorriso_allow_launch_frontenD
  536 then
  537     AC_DEFINE([Xorriso_allow_launch_frontenD], [])
  538 fi
  539 
  540 AH_TEMPLATE([Xorriso_allow_extf_suiD], [Define to allow xorriso command -launch_frontend when running under setuid])
  541 AC_ARG_ENABLE(launch-frontend-setuid,
  542 [  --enable-launch-frontend-setuid   Enable start of piped frontend program under setuid, default=no],
  543                , enable_launch_frontend_setuid=no)
  544 if test x$enable_launch_frontend_setuid = xyes; then
  545     LFRONT_SUID_DEF="-DXorriso_allow_extf_suiD"
  546     echo "enabled  xorriso command -launch_frontend under setuid"
  547 else
  548     LFRONT_SUID_DEF=
  549     echo "disabled xorriso command -launch_frontend under setuid"
  550 fi
  551 if test x$LFRONT_SUID_DEF = x-DXorriso_allow_extf_suiD
  552 then
  553     AC_DEFINE([Xorriso_allow_extf_suiD], [])
  554 fi
  555 
  556 
  557 AH_TEMPLATE([Xorriso_dvd_obs_default_64K], [Define to make 64 KB default size for DVD writing])
  558 AC_ARG_ENABLE(dvd-obs-64k,
  559 [  --enable-dvd-obs-64k         64 KB default size for DVD writing, default=no],
  560                , enable_dvd_obs=no)
  561 if test x$enable_dvd_obs_64k = xyes; then
  562     XORRISO_DVD_OBS_64K="-DXorriso_dvd_obs_default_64K"
  563     echo "enabled  xorriso write size default 64 KB on DVD"
  564 else
  565     XORRISO_DVD_OBS_64K=
  566     echo "disabled xorriso write size default 64 KB on DVD"
  567 fi
  568 if test x$XORRISO_DVD_OBS_64K = x-DXorriso_dvd_obs_default_64K
  569 then
  570     AC_DEFINE([Xorriso_dvd_obs_default_64K], [])
  571 fi
  572 
  573 
  574 AH_TEMPLATE([Libburn_read_o_direcT], [Define to use O_DIRECT with -as cdrskin])
  575 AC_ARG_ENABLE(track-src-odirect,
  576 [  --enable-track-src-odirect   Enable use of O_DIRECT with -as cdrskin, default=no],
  577                , enable_track_src_odirect=no)
  578 if test x$enable_track_src_odirect = xyes; then
  579     LIBBURN_O_DIRECT_DEF="-DLibburn_read_o_direcT"
  580     echo "enabled  use of O_DIRECT with input of -as cdrskin"
  581 else
  582     LIBBURN_O_DIRECT_DEF=
  583     echo "disabled use of O_DIRECT with input of -as cdrskin"
  584 fi
  585 if test x$LIBBURN_O_DIRECT_DEF = x-DLibburn_read_o_direcT
  586 then
  587     AC_DEFINE([Libburn_read_o_direcT], [])
  588 fi
  589 
  590 # Check for system dependent mandatory libraries (LIBBURN_ARCH_LIBS)
  591 LIBBURNIA_CHECK_ARCH_LIBS(mandatory)
  592 
  593 
  594 # ------- Visible mark in configure : Start of library check
  595 
  596 # Check for proper library versions if this is desired.
  597 # (It fails too often on too many systems.)
  598 AC_ARG_ENABLE(pkg-check-modules,
  599 [  --enable-pkg-check-modules      Enable pkg-config check for libburn and libisofs , default=no],
  600                , enable_pkg_check_modules=no)
  601 if test x$enable_pkg_check_modules = xyes; then
  602 
  603 dnl If PKG_CHECK_MODULES is to be used after this if-block,
  604 dnl then it might be necessary to perform PKG_PROG_PKG_CONFIG before the block.
  605 
  606   if test x$LIBCDIO_DEF = x; then
  607     dummy=dummy
  608   else
  609     LIBCDIO_REQUIRED=0.83
  610     PKG_CHECK_MODULES(LIBCDIO, libcdio >= $LIBCDIO_REQUIRED)
  611   fi
  612 else
  613   if test x$LIBCDIO_DEF = x; then
  614     dummy=dummy
  615   else
  616     echo "checking for LIBCDIO... skipped, no --enable-pkg-check-modules"
  617   fi
  618 fi
  619 
  620 # ------- Visible mark in configure : End of library check
  621 
  622 
  623 AC_CONFIG_FILES([
  624 	Makefile
  625 	version.h
  626 	])
  627 AC_OUTPUT
  628 #	xorriso.pc
  629