"Fossies" - the Fresh Open Source Software Archive

Member "ftss-0.9.3/configure.ac" (2 Nov 2009, 3547 Bytes) of package /linux/www/old/ftss-0.9.3.tar.gz:

    1 AC_INIT(ftss, esyscmd([tr -d '\n' <VERSION]), mopo@fabletech.com)
    2 AC_COPYRIGHT([Copyright (C) 2009 FableTech])
    3 
    4 VERSION=$PACKAGE_VERSION
    5 AC_SUBST(VERSION)
    6 
    7 AM_INIT_AUTOMAKE(ftss, $VERSION)
    8 AC_CONFIG_SRCDIR([src/ftss.c])
    9 #AM_CONFIG_HEADER([config.h])
   10 
   11 # Checks for programs.
   12 AC_PROG_CC
   13 
   14 AC_LIB_PREFIX
   15 
   16 dnl PKG_PROG_PKG_CONFIG
   17 
   18 dnl PKG_CHECK_MODULES(LIBAPR1,[apr-1])
   19 
   20 
   21 dnl ----- libapr -----
   22 
   23 AC_ARG_WITH(apr_config,
   24         AS_HELP_STRING([--with-apr-config=program-path],
   25                    [Specify location of Apache Portable Runtime config tool]),,
   26         [with_apr_config=default])
   27 APR_PATH="$PATH"
   28 APR_PATH="$APR_PATH:/opt/hpws/apache/bin"
   29 APR_PATH="$APR_PATH:/opt/IBMIHS/bin:/usr/IBMIHS/bin:/opt/freeware/bin"
   30 APR_PATH="$APR_PATH:/usr/apache2/bin"
   31 APR_PATH="$APR_PATH:/usr/local/bin:/usr/sbin:/usr/bin"
   32 APR_PATH="$APR_PATH:/usr/local/apache2:/usr/local/apache"
   33 
   34 if test x"$with_apr_config" = x"default"; then
   35     AC_PATH_PROG([APR0_CONFIG], [apr-config], [no], [$APR_PATH])
   36     if test x"$APR0_CONFIG" = x"no"; then
   37         AC_PATH_PROG([APR_CONFIG], [apr-1-config], [no], [$APR_PATH])
   38     else
   39         APR_CONFIG="$APR0_CONFIG"
   40     fi
   41 else
   42     APR_CONFIG="$with_apr_config"
   43 fi
   44 if test x"$APR_CONFIG" = x"no"; then
   45     AC_MSG_FAILURE([no apr-config found. Is the Apache developer kit installed?])
   46 fi
   47 
   48 dnl -- APR CFLAGS
   49 AC_CACHE_CHECK([APR CFLAGS], [ftss_cv_libapr_cflags],
   50     [ftss_cv_libapr_cflags=`$APR_CONFIG --cflags --cppflags --includes`])
   51 CFLAGS="$CFLAGS $ftss_cv_libapr_cflags"
   52 
   53 dnl -- APR LIBS
   54 AC_CACHE_CHECK([APR LIBS], [ftss_cv_libapr_libs],
   55     [ftss_cv_libapr_libs=`$APR_CONFIG --link-ld`])
   56 LIBS="$LIBS $ftss_cv_libapr_libs"
   57 
   58 
   59 dnl ----- apxs -----
   60 
   61 dnl -- APXS is Apache's extension tool.
   62 dnl We trust it completely to do the right thing.
   63 dnl If it is busted, then the user is on their own.
   64 AC_ARG_WITH(apxs,
   65         AS_HELP_STRING([--with-apxs=program-path],
   66                    [Specify location of Apache extension tool]),,
   67         [with_apxs=default])
   68 dnl -- Search path for finding apxs2/apxs
   69 APXS_PATH="$PATH"
   70 APXS_PATH="$APXS_PATH:/opt/hpws/apache/bin"
   71 APXS_PATH="$APXS_PATH:/opt/IBMIHS/bin:/usr/IBMIHS/bin:/opt/freeware/bin"
   72 APXS_PATH="$APXS_PATH:/usr/apache2/bin"
   73 APXS_PATH="$APXS_PATH:/usr/local/bin:/usr/sbin:/usr/bin"
   74 APXS_PATH="$APXS_PATH:/usr/local/apache2:/usr/local/apache"
   75 
   76 if test x"$with_apxs" = x"default"; then
   77     AC_PATH_PROG([APXS2], [apxs2], [no], [$APXS_PATH])
   78     if test x"$APXS2" = x"no"; then
   79         AC_PATH_PROG([APXS], [apxs], [no], [$APXS_PATH])
   80     else
   81         APXS="$APXS2"
   82     fi
   83 else
   84     APXS="$with_apxs"
   85 fi
   86 if test x"$APXS" = x"no"; then
   87     AC_MSG_FAILURE([no apxs found. Is the Apache developer kit installed?])
   88 fi
   89 AC_SUBST(APXS)
   90 
   91 dnl -- use this as a sanity test that apxs is working
   92 AC_MSG_CHECKING([Apache extension target])
   93 apxs_target=`$APXS -q TARGET || echo error`
   94 AC_MSG_RESULT([$apxs_target])
   95 
   96 if test x"$apxs_target" = x"error"; then
   97     AC_MSG_FAILURE([$APXS does not appear to work])
   98 fi
   99 
  100 dnl -- APXS CFLAGS
  101 AC_CACHE_CHECK([APXS CFLAGS], [ftss_cv_apxs_cflags],
  102     [ftss_cv_apxs_cflags=`$APXS -q CFLAGS`])
  103 CFLAGS="$CFLAGS $ftss_cv_apxs_cflags"
  104 
  105 dnl -- APXS INCLUDEDIR
  106 AC_CACHE_CHECK([APXS INCLUDEDIR], [ftss_cv_apxs_includedir],
  107     [ftss_cv_apxs_includedir=`$APXS -q INCLUDEDIR`])
  108 CFLAGS="$CFLAGS -I$ftss_cv_apxs_includedir"
  109 
  110 
  111 AC_MSG_CHECKING([for load balancer support in mod_status])
  112 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  113 #include "httpd.h"
  114 #include "scoreboard.h"
  115 ]], [[
  116 scoreboard sb;
  117 if (sb.balancers) return 0
  118 ]])],
  119 [
  120     AC_MSG_RESULT([yes])
  121     CFLAGS="$CFLAGS -DSCOREBOARD_BALANCERS"
  122 ], [
  123         AC_MSG_RESULT([no])
  124 ])
  125 
  126 
  127 AC_CONFIG_FILES([Makefile])
  128 AC_CONFIG_FILES([src/Makefile])
  129 AC_OUTPUT