"Fossies" - the Fresh Open Source Software Archive

Member "tcshrc/src/tcshrc.set" (24 Jan 2009, 7996 Bytes) of package /linux/privat/old/tcshrc-1.6.2.tar.gz:

As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file.

A hint: This file contains one or more very long lines, so maybe it is better readable using the pure text view mode that shows the contents as wrapped lines within the browser window.

    1 #############################################################################
    2 ##
    3 ## .tcshrc.set
    4 ##
    5 ## Author: Simos Xenitellis (simos.lists@googlemail.com)
    6 ##
    7 
    8 ## This is the .tcshrc.set file, part of the TCSHRC project
    9 ## at http://tcshrc.sourceforge.net
   10 
   11 ## Has two sections, GENERAL and SYSTEM SPECIFIC
   12 
   13 ## GENERAL
   14 
   15 # When you press "Ctrl-D", should you exit the shell?
   16 # If you are used to exit the shell with "Ctrl-D", disable this.
   17 #set ignoreeof
   18 
   19 # Define new prompt.
   20 # Basic prompt.      (do a 'man tcsh' to get more about the flags)
   21 # This shows the current path in inverse color and that is nice.
   22 # It is important to know all the time in what directory you are.
   23 #   explanation: %B begin bold, %b end bold, %S begin inverse, %s end inverse
   24 #   explanation: %m short system name, %/ full directory name, %# is # or %
   25 #   explanation: depending if you are root or non-root.
   26 
   27 ####### OLD, Until tcshrc-1.2.0 prompt.#######
   28 # set prompt="%B%m%b:%S%/%s%# "
   29 
   30 # New prompt, please try it out. Took me 3 days to get used to it fully.
   31 # It's better in some respects than the previous one.
   32 #   - more space to type command.
   33 #   - shows username@currenthost currentdirectory
   34 #   - can double-click with mouse to select so latter can paste somewhere
   35 # Source: "UNIX Power Tools" from O'Reilly, note from Tim Cera (timcera@sourceforge.net).
   36 set prompt='\
   37 %B%n%b@%U%m%u %S%/%s\
   38 %# '
   39 
   40 # Prompt used when waiting for stufffor 'for' or 'while'...
   41 set prompt2="%R?"
   42 
   43 # Prompt used when correcting.
   44 # Correct????
   45 # 	y: yes, n: no, e: edit
   46 # 	<SPACE>: yes
   47 # 	<ENTER>: no
   48 set prompt3="CORRECT> %B%R%b (y|n|e)?"
   49 
   50 # Don't beep at all...
   51 # beeping is annoying, perhaps it is good only when you learn TCSH.
   52 # If you are a rookie in TCSH, try commenting it out.
   53 set nobeep
   54 
   55 # This is the history of each individual shell.
   56 # It defines only the size and it usefull when invoking previous commands.
   57 set history=2048
   58 
   59 # Make sure that there is no logging of the session.
   60 # Privacy issues and it was mentioned that logging makes slow the logout
   61 unset histfile
   62 
   63 # Watch any(1) other users every 0 seconds from any(2) console, 
   64 # when logging in/out.(I like this one!)
   65 # It gives something like "root has logged on tty1 from local."
   66 # You may find it annoying on busy systems (like shell1.sourceforge.net)
   67 set watch=(0 any any)
   68 
   69 # Format of output string when someone logins or logouts.(Look above)
   70 # Hmm, can't be internationalised easily.
   71 set who="%n has %a %l from %M."
   72 
   73 # Set to 'insert' mode. Possible values 'insert' or 'overwrite'.
   74 # By default, we are in "insert" mode.
   75 set inputmode=insert
   76 
   77 # Do autolisting of commands while completing.
   78 # Very handy. Example with "chmod". 
   79 #  % ch<TAB>
   80 #  now it shows all possible commands that start with "ch*".
   81 #  % chm<TAB>
   82 #  we have seen that there is only one chm* command. Thus, the <TAB> does:
   83 #  % chmod 
   84 #  This is among best tricks of TCSH. Learn this and you will be very fast
   85 #  on the command line.
   86 set autolist
   87 
   88 # Do autocorrection while completing...
   89 # It does some very rudimentary corrections. I was not disatisfied yet.
   90 # Try:
   91 # % cd /usr/loca/bin<TAB>
   92 # % cd /usr/local/bin     <- you get
   93 set autocorrect
   94 
   95 # Use the history of commands to aid expansion.
   96 # Found in new versions of tcsh (at least 6.10)
   97 set autoexpand
   98 
   99 # Enabled "complete" to "enhance".
  100 # If you have a file called "complete.tcsh" and you
  101 # want to edit it, do "vi c.t<TAB>" and that's it.
  102 set complete=enhance
  103 
  104 # Possible values : cmd complete all
  105 # Put it to extreme auto.
  106 set correct=all
  107 
  108 # Don't want to be autologed out.
  109 # You can set it to autologout you after x minutes of idle time.
  110 # You would do: set autologout=3  for 3 minutes of inactivity.
  111 unset autologout
  112 
  113 # Symbolic links are expanded to their true values : chase
  114 # (possible values 'chase' 'ignore' 'expand')
  115 # When traversing directories with symlinks, this substitures them
  116 # with the real value. You will like it.
  117 set symlinks=chase
  118 
  119 # After a 'Ctrl-Z', it lists all the jobs.
  120 set listjobs
  121 
  122 # If the exit value is non-zero, print it.
  123 # Very handy when you do scripting.
  124 set printexitvalue
  125 
  126 # Ask for confirmation when 'rm *'.
  127 set rmstar
  128 
  129 # Set the command to be run instead of a BEEP.(does this one work???)
  130 #set beepcmd
  131 
  132 # Files that are to be ignored from completion.
  133 # These are the .o files that GCC produces. Usually you do not touch them.
  134 set fignore=(.o)
  135 
  136 # Various statistics.
  137 # You can unset it or set it (it is set a bit later).
  138 #unset time
  139 
  140 #set time="%Uu %Ss %E %P %X+%Dk %I+%Oio %Fpf+%Ww"
  141 
  142 # Do "man tcsh" to find about more data that can be shown
  143 # with this command. I have used only those that are available
  144 # on a Linux box without kernel debugging enabled.
  145 # That is, a stock kernel from a distribution.
  146 set time=(8 "\
  147 Time spent in user mode   (CPU seconds) : %Us\
  148 Time spent in kernel mode (CPU seconds) : %Ss\
  149 Total time                              : %Es\
  150 CPU utilisation (percentage)            : %P\
  151 Times the process was swapped           : %W\
  152 Times of major page faults              : %F\
  153 Times of minor page faults              : %R")
  154 
  155 # page faults are the "memory" pages that had to be brought
  156 # from the swap area.
  157  
  158 # Before printing prompt after a command, do :
  159 #alias precmd date
  160 
  161 # Setting the 'echo_style' parameter to 'both'.
  162 # Other values are bsd, sysv, etc.
  163 # This way, both 'set -n' and set '\003' styles will work.
  164 # On Linux it's already set to 'both.
  165 # Submission by miklos.
  166 set echo_style=both
  167 
  168 ## Addition by Hunter Eidson (eeidson).
  169 # Execute command after changing directory.
  170 # This changes the title bar/icon description of the console window.
  171 setenv SHORT_HOST `echo $HOST | cut -f 1 -d. | tr 'a-z' 'A-Z'`
  172 switch ( $TERM )
  173       case "dtterm*":         # dtterm
  174       case "xterm*":          # xterm
  175               alias seticon 'echo -n "\033]1;\!*\007"'
  176               alias sethead 'echo -n "\033]2;\!*\007"'
  177               alias cwdcmd  'sethead "${SHORT_HOST} - ${PWD}"'
  178               breaksw;
  179       case "sun*":            # SunView cmdtool/shelltool
  180               alias seticon 'echo -n "\033]L\!*\033\\"'
  181               alias sethead 'echo -n "\033]l\!*\033\\"'
  182               alias cwdcmd  'sethead "${SHORT_HOST} - ${PWD}"'
  183               breaksw;
  184       case "vt[24]20*":       # TNVT and SecureCRT (Windows clients)
  185               alias seticon 'echo -n ""'
  186               alias sethead 'echo -n "\033]0;\!*\007\033\\"'
  187               alias cwdcmd  'sethead "${SHORT_HOST} - ${PWD}"'
  188               breaksw;
  189       default:
  190               alias seticon echo -n ""
  191               alias sethead echo -n ""
  192               unalias cwdcmd
  193 endsw
  194 sethead ${SHORT_HOST} - ${PWD}
  195 seticon ${SHORT_HOST}
  196 
  197 #### Generic command to set the title bar of the console window to
  198 #### show the hostname and current directory.
  199 #### We currently use the switch mechanism above to determine the 
  200 #### correct values for different TERMs.
  201 # Addition by <miklos.quartus@nokia.com>
  202 #alias cwdcmd 'echo -n "\033]2;${HOST}\007\033]1;\007"'
  203 #unalias cwdcmd
  204 
  205 # Every # seconds, do 'command'.
  206 # set tperiod = 2
  207 # alias periodic 'tput bel'
  208 
  209 unset tperiod
  210 unalias periodic
  211 
  212 # After 8 hours, it changes the prompt to the following!
  213 ### sorry for this :)
  214 #sched +8:00 set prompt='Has trabajado mucho. Llama la novia\! :> '
  215 
  216 ## SYSTEM SPECIFIC
  217 
  218 #setenv PRINTER HP4KN
  219 #setenv SGML_CATALOG_FILES /usr/lib/sgml/CATALOG
  220 
  221 ## Language settings 
  222 # FIXME These should have been set by the system.
  223 # FIXME Unless you are greek, these will make your computer ill.
  224 # One should tinker /etc/sysconfig/i18n or similar. Period.
  225 #setenv LANG 	el_GR
  226 #setenv LANGUAGE el_GR
  227 #setenv LC_ALL 	el_GR
  228 
  229 set URLS=(http://www.slashdot.org/ http://www.freshmeat.net/ http://www.lwn.net/ http://linuxtoday.com/ http://www.linux.com/ http://www.sourceforge.net/ http://www.redhat.com/ http://www.suse.com/ http://www.debian.org/ http://www.mandrakelinux.com/ http://www.knoppix.org/ http://www.cryptome.org/ http://www.mirror.ac.uk/ http://www.google.com/ http://www.yahoo.com/)
  230 
  231 ## Version of this package
  232 set tcshrc_version=1.5.0