"Fossies" - the Fresh Open Source Software Archive

Member "sssd-2.2.3/configure.ac" (30 Nov 2019, 17532 Bytes) of package /linux/misc/sssd-2.2.3.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "configure.ac": 2.2.2_vs_2.2.3.

    1 AC_PREREQ(2.59)
    2 
    3 m4_include([version.m4])
    4 AC_INIT([sssd],
    5         VERSION_NUMBER,
    6         [sssd-devel@lists.fedorahosted.org])
    7 AC_CONFIG_SRCDIR([BUILD.txt])
    8 AC_CONFIG_AUX_DIR([build])
    9 
   10 m4_ifdef([AC_USE_SYSTEM_EXTENSIONS],
   11     [AC_USE_SYSTEM_EXTENSIONS],
   12     [AC_GNU_SOURCE])
   13 
   14 CFLAGS="$CFLAGS -D_FILE_OFFSET_BITS=64 -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
   15 
   16 
   17 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign subdir-objects tar-pax
   18                   parallel-tests])
   19 AM_PROG_CC_C_O
   20 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
   21 AC_DISABLE_STATIC
   22 AC_PROG_INSTALL
   23 LT_INIT
   24 m4_ifdef([AC_PROG_MKDIR_P],
   25          [AC_PROG_MKDIR_P],
   26          [AC_SUBST([MKDIR_P], "mkdir -p")])
   27 LT_LIB_DLLOAD
   28 AC_CONFIG_MACRO_DIR([m4])
   29 AM_GNU_GETTEXT([external])
   30 AM_GNU_GETTEXT_VERSION([0.14.4])
   31 
   32 AC_SUBST([PRERELEASE_VERSION],
   33          PRERELEASE_VERSION_NUMBER)
   34 
   35 AC_DEFINE([PRERELEASE_VERSION], "PRERELEASE_VERSION_NUMBER",
   36           [Prerelease version number of package])
   37 
   38 AM_CONDITIONAL([GIT_CHECKOUT], [git log -1 >/dev/null 2>&1])
   39 
   40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
   41 
   42 AM_CONDITIONAL([HAVE_GCC], [test "$ac_cv_prog_gcc" = yes])
   43 
   44 AC_CHECK_HEADERS(stdint.h dlfcn.h)
   45 AC_CONFIG_HEADER(config.h)
   46 
   47 AC_CHECK_TYPES([errno_t], [], [], [[#include <errno.h>]])
   48 
   49 m4_include([src/build_macros.m4])
   50 BUILD_WITH_SHARED_BUILD_DIR
   51 
   52 AC_COMPILE_IFELSE(
   53     [AC_LANG_PROGRAM([[#include <pthread.h>]],
   54         [[pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;
   55           (void) m; /* unused */
   56         ]])],
   57     [AC_DEFINE([HAVE_PTHREAD], [1], [Pthread mutexes available.])
   58      HAVE_PTHREAD=1
   59     ],
   60     [AC_MSG_WARN([Pthread library not found! Clients will not be thread safe...])])
   61 
   62 
   63 AM_CONDITIONAL([HAVE_PTHREAD], [test x"$HAVE_PTHREAD" != "x"])
   64 
   65 # Check library for the timer_create function
   66 SAVE_LIBS=$LIBS
   67 LIBS=
   68 LIBADD_TIMER=
   69 AC_SEARCH_LIBS([timer_create], [rt posix4],
   70     [AC_DEFINE([HAVE_LIBRT], [1],
   71          [Define if you have the librt library or equivalent.])
   72      LIBADD_TIMER="$LIBS"],
   73     [AC_MSG_ERROR([unable to find library fot the timer_create() function])])
   74 
   75 AC_SUBST([LIBADD_TIMER])
   76 LIBS=$SAVE_LIBS
   77 
   78 # Check library for the clock_gettime function
   79 SAVE_LIBS=$LIBS
   80 LIBS=
   81 LIBCLOCK_GETTIME=
   82 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
   83     [AC_DEFINE([HAVE_LIBRT], [1],
   84          [Define if you have the librt library or equivalent.])
   85      LIBCLOCK_GETTIME="$LIBS"],
   86     [AC_MSG_ERROR([unable to find library for the clock_gettime() function])])
   87 
   88 AC_SUBST([LIBCLOCK_GETTIME])
   89 LIBS=$SAVE_LIBS
   90 
   91 # Check for presence of modern functions for setting file timestamps
   92 AC_CHECK_FUNCS([ utimensat \
   93                  futimens ])
   94 
   95 AC_CHECK_FUNCS([ explicit_bzero ])
   96 
   97 #Check for endian headers
   98 AC_CHECK_HEADERS([endian.h sys/endian.h byteswap.h])
   99 
  100 AC_C_BIGENDIAN([AC_DEFINE(HAVE_BIG_ENDIAN, [1], [whether platform is big endian])],
  101                [AC_DEFINE(HAVE_LITTLE_ENDIAN, [1], [whether platform is little endian])])
  102 
  103 #Set the NSS library install path
  104 AC_ARG_ENABLE([nsslibdir], [AS_HELP_STRING([--enable-nsslibdir],
  105                                         [Where to install nss libraries ($libdir)])],
  106               [nsslibdir=$enableval],
  107               [nsslibdir=$libdir])
  108 AC_SUBST(nsslibdir)
  109 
  110 #Set the PAM module install path
  111 AC_ARG_ENABLE([pammoddir], [AS_HELP_STRING([--enable-pammoddir],
  112                                         [Where to install pam modules ($libdir/security)])],
  113               [pammoddir=$enableval],
  114               [pammoddir=$libdir/security])
  115 AC_SUBST(pammoddir)
  116 
  117 #Set the NFSv4 idmapd library install path
  118 AC_ARG_ENABLE([nfsidmaplibdir], [AS_HELP_STRING([--enable-nfsidmaplibdir],
  119                                         [Where to install libnfsidmap libraries ($libdir/libnfsidmap)])],
  120               [nfsidmaplibdir=$enableval],
  121               [nfsidmaplibdir=$libdir/libnfsidmap])
  122 AC_SUBST(nfsidmaplibdir)
  123 
  124 #Include here cause WITH_INIT_DIR requires $osname set in platform.m4
  125 m4_include([src/external/platform.m4])
  126 
  127 m4_include(src/conf_macros.m4)
  128 WITH_DB_PATH
  129 WITH_PLUGIN_PATH
  130 WITH_PID_PATH
  131 WITH_LOG_PATH
  132 WITH_PUBCONF_PATH
  133 WITH_PIPE_PATH
  134 WITH_MCACHE_PATH
  135 WITH_DEFAULT_CCACHE_DIR
  136 WITH_DEFAULT_CCNAME_TEMPLATE
  137 WITH_ENVIRONMENT_FILE
  138 WITH_INIT_DIR
  139 WITH_TEST_DIR
  140 WITH_MANPAGES
  141 WITH_XML_CATALOG
  142 WITH_KRB5_PLUGIN_PATH
  143 WITH_KRB5_RCACHE_DIR
  144 WITH_KRB5AUTHDATA_PLUGIN_PATH
  145 WITH_KRB5_CONF
  146 WITH_PYTHON2_BINDINGS
  147 WITH_PYTHON3_BINDINGS
  148 WITH_CIFS_PLUGIN_PATH
  149 WITH_WINBIND_PLUGIN_PATH
  150 WITH_SELINUX
  151 WITH_NSCD
  152 WITH_IPA_GETKEYTAB
  153 WITH_SEMANAGE
  154 WITH_AD_GPO_DEFAULT
  155 WITH_GPO_CACHE_PATH
  156 WITH_NOLOGIN_SHELL
  157 WITH_SESSION_RECORDING_SHELL
  158 WITH_APP_LIBS
  159 WITH_SUDO
  160 WITH_SUDO_LIB_PATH
  161 WITH_AUTOFS
  162 WITH_SSH
  163 WITH_IFP
  164 WITH_CRYPTO
  165 WITH_SYSLOG
  166 WITH_SAMBA
  167 WITH_NFS
  168 WITH_NFS_LIB_PATH
  169 WITH_LIBWBCLIENT
  170 WITH_SSSD_USER
  171 SSSD_RUNSTATEDIR
  172 WITH_SECRETS
  173 WITH_SECRETS_DB_PATH
  174 WITH_KCM
  175 
  176 m4_include([src/external/pkg.m4])
  177 m4_include([src/external/libpopt.m4])
  178 m4_include([src/external/libtalloc.m4])
  179 m4_include([src/external/libtdb.m4])
  180 m4_include([src/external/libtevent.m4])
  181 m4_include([src/external/libldb.m4])
  182 m4_include([src/external/libdhash.m4])
  183 m4_include([src/external/libcollection.m4])
  184 m4_include([src/external/libini_config.m4])
  185 m4_include([src/external/pam.m4])
  186 m4_include([src/external/ldap.m4])
  187 m4_include([src/external/libpcre.m4])
  188 m4_include([src/external/krb5.m4])
  189 m4_include([src/external/libcares.m4])
  190 m4_include([src/external/libcmocka.m4])
  191 m4_include([src/external/docbook.m4])
  192 m4_include([src/external/sizes.m4])
  193 m4_include([src/external/python.m4])
  194 m4_include([src/external/selinux.m4])
  195 m4_include([src/external/crypto.m4])
  196 m4_include([src/external/nscd.m4])
  197 m4_include([src/external/nsupdate.m4])
  198 m4_include([src/external/libkeyutils.m4])
  199 m4_include([src/external/libnl.m4])
  200 m4_include([src/external/systemd.m4])
  201 m4_include([src/external/pac_responder.m4])
  202 m4_include([src/external/cifsidmap.m4])
  203 m4_include([src/external/signal.m4])
  204 m4_include([src/external/inotify.m4])
  205 m4_include([src/external/samba.m4])
  206 m4_include([src/external/sasl.m4])
  207 m4_include([src/external/libnfsidmap.m4])
  208 m4_include([src/external/cwrap.m4])
  209 m4_include([src/external/libresolv.m4])
  210 m4_include([src/external/intgcheck.m4])
  211 m4_include([src/external/systemtap.m4])
  212 m4_include([src/external/service.m4])
  213 m4_include([src/external/test_ca.m4])
  214 m4_include([src/external/ax_valgrind_check.m4])
  215 
  216 if test x$with_secrets = xyes; then
  217     m4_include([src/external/libhttp_parser.m4])
  218     m4_include([src/external/libcurl.m4])
  219 fi
  220 
  221 if test x$with_kcm = xyes; then
  222     m4_include([src/external/libuuid.m4])
  223 fi
  224 
  225 if test x$with_kcm = xyes -o x$with_secrets = xyes; then
  226     BUILD_WITH_LIBSECRET=1
  227     AC_DEFINE_UNQUOTED(BUILD_WITH_LIBSECRET, 1, [libsecret will be built])
  228     m4_include([src/external/libjansson.m4])
  229 fi
  230 
  231 AM_CONDITIONAL([BUILD_WITH_LIBSECRET],
  232                [test x"$BUILD_WITH_LIBSECRET" != "x"])
  233 
  234 # This variable is defined by external/libcurl.m4, but conditionals
  235 # must be always evaluated
  236 AM_CONDITIONAL([BUILD_WITH_LIBCURL],
  237                [test x"$have_curlopt_unix_sockpath" = xyes])
  238 
  239 WITH_UNICODE_LIB
  240 if test x$unicode_lib = xlibunistring; then
  241     m4_include([src/external/libunistring.m4])
  242     AC_DEFINE_UNQUOTED(HAVE_LIBUNISTRING, 1, [Using libunistring for unicode])
  243     UNICODE_LIBS=$UNISTRING_LIBS
  244 else
  245     m4_include([src/external/glib.m4])
  246     AC_DEFINE_UNQUOTED(HAVE_GLIB2, 1, [Using glib2 for unicode])
  247     UNICODE_LIBS=$GLIB2_LIBS
  248 fi
  249 AC_SUBST(UNICODE_LIBS)
  250 
  251 WITH_LIBNL
  252 
  253 if test x$HAVE_NSCD; then
  254     WITH_NSCD_CONF
  255 fi
  256 
  257 WITH_INITSCRIPT
  258 if test x$initscript = xsystemd; then
  259     WITH_SYSTEMD_UNIT_DIR
  260     WITH_SYSTEMD_CONF_DIR
  261 else
  262     CHECK_SERVICE_EXECUTABLE
  263 fi
  264 
  265 PKG_CHECK_MODULES([DBUS],[dbus-1])
  266 dnl if test -n "`$PKG_CONFIG --modversion dbus-1 | grep '^0\.'`" ; then
  267 if ! $PKG_CONFIG --atleast-version 1.0.0 dbus-1; then
  268     DBUS_CFLAGS="$DBUS_CFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
  269     AC_MSG_RESULT([setting -DDBUS_API_SUBJECT_TO_CHANGE])
  270 fi
  271 
  272 if test x$has_dbus != xno; then
  273     SAFE_LIBS="$LIBS"
  274     LIBS="$DBUS_LIBS"
  275     SAFE_CFLAGS=$CFLAGS
  276     CFLAGS="$CFLAGS $DBUS_CFLAGS"
  277 
  278     AC_CHECK_FUNC([dbus_watch_get_unix_fd],
  279                   AC_DEFINE([HAVE_DBUS_WATCH_GET_UNIX_FD], [1],
  280                             [Define if dbus_watch_get_unix_fd exists]))
  281     AC_CHECK_TYPES([DBusBasicValue],
  282                    [],
  283                    [],
  284                    [ #include <dbus/dbus.h> ])
  285 
  286     LIBS="$SAFE_LIBS"
  287     CFLAGS=$SAFE_CFLAGS
  288 fi
  289 
  290 # work around a bug in cov-build from Coverity
  291 test -n "$XML_CATALOG_FILES" || unset XML_CATALOG_FILES
  292 
  293 if test x$HAVE_MANPAGES != x; then
  294     CHECK_XML_TOOLS
  295 
  296     DOCBOOK_XSLT=http://docbook.sourceforge.net/release/xsl/current/manpages/profile-docbook.xsl
  297     CHECK_STYLESHEET([$SGML_CATALOG_FILES],
  298                      [$DOCBOOK_XSLT],
  299                      [Docbook XSL profiling templates],
  300                      [HAVE_PROFILE_CATALOGS=1],
  301                      [AC_MSG_WARN([Man pages might contain documentation for experimental features])])
  302 
  303     if test x$HAVE_PROFILE_CATALOGS = x; then
  304         DOCBOOK_XSLT=http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl
  305         CHECK_STYLESHEET([$SGML_CATALOG_FILES],
  306                          [$DOCBOOK_XSLT],
  307                          [Docbook XSL templates],
  308                          [],
  309                          [AC_MSG_ERROR([could not find the docbook xsl catalog])])
  310     fi
  311 
  312     AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
  313     AC_SUBST(DOCBOOK_XSLT)
  314 fi
  315 AM_CONDITIONAL([HAVE_PROFILE_CATALOGS], [test "x$HAVE_PROFILE_CATALOGS" != "x"])
  316 AM_CONDITIONAL([HAVE_MANPAGES], [test "x$HAVE_MANPAGES" != "x"])
  317 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
  318 
  319 AC_CHECK_PROG(HAVE_PYTHON2, python2, yes, no)
  320 AS_IF([test x$HAVE_PYTHON2 = xyes],
  321       [AC_PATH_PROG(PYTHON2, python2)])
  322 
  323 AC_CHECK_PROG(HAVE_PYTHON3, python3, yes, no)
  324 AS_IF([test x$HAVE_PYTHON3 = xyes],
  325       [AC_PATH_PROG(PYTHON3, python3)])
  326 
  327 if test x$HAVE_PYTHON2_BINDINGS = xyes; then
  328     AS_IF([test x$HAVE_PYTHON2 != xyes],
  329           [AC_MSG_ERROR([
  330 The program python2 was not found in search path.
  331 Please ensure that it is installed and its directory is included in the search
  332 path. It is required for building python2 bindings. If you do not want to build
  333 them please use argument --without-python2-bindings when running configure.])])
  334 
  335     PYTHON=$PYTHON2
  336     AM_PATH_PYTHON([2.6])
  337     AM_PYTHON_CONFIG([python2])
  338     AM_CHECK_PYTHON_HEADERS([],
  339                             AC_MSG_ERROR([Could not find python2 headers]))
  340 
  341     AC_SUBST([py2execdir], [$pyexecdir])
  342     AC_SUBST([python2dir], [$pythondir])
  343     AC_SUBST([PYTHON2_CFLAGS], [$PYTHON_CFLAGS])
  344     AC_SUBST([PYTHON2_LIBS], [$PYTHON_LIBS])
  345     AC_SUBST([PYTHON2_INCLUDES], [$PYTHON_INCLUDES])
  346     AC_SUBST([PYTHON2_VERSION], [$PYTHON_VERSION])
  347     AC_SUBST([PYTHON2_PREFIX], [$PYTHON_PREFIX])
  348     AC_SUBST([PYTHON2_EXEC_PREFIX], [$PYTHON_EXEC_PREFIX])
  349 
  350     SSS_CLEAN_PYTHON_VARIABLES
  351 fi
  352 
  353 if test x$HAVE_PYTHON3_BINDINGS = xyes; then
  354     AS_IF([test x$HAVE_PYTHON3 != xyes],
  355           [AC_MSG_ERROR([
  356 The program python3 was not found in search path.
  357 Please ensure that it is installed and its directory is included in the search
  358 path. It is required for building python3 bindings. If you do not want to build
  359 them please use argument --without-python3-bindings when running configure.])])
  360 
  361     PYTHON=$PYTHON3
  362     AM_PATH_PYTHON([3.3])
  363     AM_PYTHON_CONFIG([python3])
  364     AM_CHECK_PYTHON_HEADERS([],
  365                             AC_MSG_ERROR([Could not find python3 headers]))
  366 
  367     AC_SUBST([py3execdir], [$pyexecdir])
  368     AC_SUBST([python3dir], [$pythondir])
  369     AC_SUBST([PYTHON3_CFLAGS], [$PYTHON_CFLAGS])
  370     AC_SUBST([PYTHON3_LIBS], [$PYTHON_LIBS])
  371     AC_SUBST([PYTHON3_INCLUDES], [$PYTHON_INCLUDES])
  372     AC_SUBST([PYTHON3_VERSION], [$PYTHON_VERSION])
  373     AC_SUBST([PYTHON3_PREFIX], [$PYTHON_PREFIX])
  374     AC_SUBST([PYTHON3_EXEC_PREFIX], [$PYTHON_EXEC_PREFIX])
  375 
  376     SSS_CLEAN_PYTHON_VARIABLES
  377 fi
  378 
  379 if test x$HAVE_PYTHON3_BINDINGS = xyes; then
  380     PYTHON_EXEC=$PYTHON3
  381 else
  382     PYTHON_EXEC=$PYTHON2
  383 fi
  384 AC_SUBST(PYTHON_EXEC)
  385 
  386 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS],
  387                [test x"$with_python2_bindings" = xyes \
  388                      -o x"$with_python3_bindings" = xyes])
  389 
  390 if test x$HAVE_SELINUX != x; then
  391     AM_CHECK_SELINUX
  392 fi
  393 
  394 if test x$HAVE_SEMANAGE != x -a x$HAVE_SELINUX != x; then
  395     AM_CHECK_SEMANAGE
  396 fi
  397 
  398 dnl If journald was selected for logging, configure journald
  399 if test x$syslog = xjournald; then
  400     AM_CHECK_JOURNALD
  401 fi
  402 
  403 if test x$cryptolib = xnss; then
  404     AM_CHECK_NSS
  405 fi
  406 
  407 if test x$cryptolib = xlibcrypto; then
  408     AM_CHECK_LIBCRYPTO
  409     m4_include([src/external/p11-kit.m4])
  410 fi
  411 
  412 AM_CHECK_INOTIFY
  413 
  414 AC_CACHE_CHECK([whether compiler supports __attribute__((destructor))],
  415                sss_client_cv_attribute_destructor,
  416                [AC_COMPILE_IFELSE(
  417                     [AC_LANG_SOURCE([__attribute__((destructor)) static void cleanup(void) { }])],
  418                     sss_client_cv_attribute_destructor=yes)
  419                ])
  420 
  421 if test x"$sss_client_cv_attribute_destructor" = xyes ; then
  422    AC_DEFINE(HAVE_FUNCTION_ATTRIBUTE_DESTRUCTOR, 1,
  423              [whether compiler supports __attribute__((destructor))])
  424 fi
  425 
  426 AC_CACHE_CHECK([whether compiler supports __attribute__((format))],
  427                sss_cv_attribute_format,
  428                [AC_COMPILE_IFELSE(
  429                     [AC_LANG_SOURCE(
  430                         [void debug_fn(const char *format, ...) __attribute__ ((format (printf, 1, 2)));]
  431                     )],
  432                     [sss_cv_attribute_format=yes],
  433                     [
  434                         AC_MSG_RESULT([no])
  435                         AC_MSG_WARN([compiler does NOT support __attribute__((format))])
  436                     ])
  437                ])
  438 
  439 if test x"$sss_cv_attribute_format" = xyes ; then
  440    AC_DEFINE(HAVE_FUNCTION_ATTRIBUTE_FORMAT, 1,
  441              [whether compiler supports __attribute__((format))])
  442 fi
  443 
  444 AC_CACHE_CHECK([whether compiler supports __attribute__((warn_unused_result))],
  445                sss_cv_attribute_warn_unused_result,
  446                [AC_COMPILE_IFELSE(
  447                     [AC_LANG_SOURCE(
  448                         [ char _check_leaks(int bytes) __attribute__ ((warn_unused_result)); ]
  449                     )],
  450                     [sss_cv_attribute_warn_unused_result=yes],
  451                     [
  452                         AC_MSG_RESULT([no])
  453                         AC_MSG_WARN([compiler does NOT support __attribute__((warn_unused_result))])
  454                     ])
  455                ])
  456 if test x"$sss_cv_attribute_warn_unused_result" = xyes ; then
  457    AC_DEFINE(HAVE_FUNCTION_ATTRIBUTE_WARN_UNUSED_RESULT, 1,
  458              [whether compiler supports __attribute__((warn_unused_result))])
  459 fi
  460 
  461 SAFE_CFLAGS=$CFLAGS
  462 CFLAGS="-Werror"
  463 AC_CACHE_CHECK(
  464     [whether compiler supports __attribute__((fallthrough))],
  465     [sss_cv_attribute_fallthrough],
  466     [AC_COMPILE_IFELSE(
  467          [AC_LANG_SOURCE(
  468              [ __attribute__ ((fallthrough)); ])
  469          ],[
  470              sss_cv_attribute_fallthrough=yes
  471              sss_cv_attribute_fallthrough_val="__attribute__ ((fallthrough))"
  472          ],[
  473              sss_cv_attribute_fallthrough=no
  474              sss_cv_attribute_fallthrough_val="((void)0)"
  475          ])
  476     ])
  477 CFLAGS=$SAFE_CFLAGS
  478 
  479 AC_DEFINE_UNQUOTED(
  480     [SSS_ATTRIBUTE_FALLTHROUGH],
  481     [$sss_cv_attribute_fallthrough_val],
  482     [__attribute__((fallthrough)) if supported])
  483 
  484 
  485 PKG_CHECK_MODULES([CHECK], [check >= 0.9.5], [have_check=1], [have_check=])
  486 if test x$have_check = x; then
  487     AC_MSG_WARN([Without the 'CHECK' libraries, you will be unable to run all tests in the 'make check' suite])
  488 else
  489     AC_CHECK_HEADERS([check.h],,AC_MSG_ERROR([Could not find CHECK headers]))
  490 fi
  491 
  492 AC_PATH_PROG([DOXYGEN], [doxygen], [false])
  493 AM_CONDITIONAL([HAVE_DOXYGEN], [test x$DOXYGEN != xfalse ])
  494 
  495 AM_CONDITIONAL([HAVE_CHECK], [test x$have_check != x])
  496 AM_CHECK_CMOCKA
  497 AM_CHECK_UID_WRAPPER
  498 AM_CHECK_NSS_WRAPPER
  499 AM_CHECK_PAM_WRAPPER
  500 AM_CHECK_TEST_CA
  501 AX_VALGRIND_CHECK
  502 
  503 # Check if the user wants SSSD to be compiled with systemtap probes
  504 AM_CHECK_SYSTEMTAP
  505 
  506 SSS_ENABLE_INTGCHECK_REQS
  507 
  508 AM_CONDITIONAL([HAVE_DEVSHM], [test -d /dev/shm])
  509 
  510 # Check if we should install polkit rules
  511 ENABLE_POLKIT_RULES_PATH
  512 AM_CONDITIONAL([HAVE_POLKIT_RULES_D], [test x$HAVE_POLKIT_RULES_D != x])
  513 
  514 abs_build_dir=`pwd`
  515 AC_DEFINE_UNQUOTED([ABS_BUILD_DIR], ["$abs_build_dir"], [Absolute path to the build directory])
  516 AC_SUBST([abs_builddir], $abs_build_dir)
  517 
  518 my_srcdir=`readlink -f $srcdir`
  519 AC_DEFINE_UNQUOTED([ABS_SRC_DIR], ["$my_srcdir"], [Absolute path to the source directory])
  520 
  521 AC_CONFIG_FILES([Makefile contrib/sssd.spec src/examples/rwtab src/doxy.config
  522                  contrib/sssd-pcsc.rules
  523                  src/sysv/sssd src/sysv/gentoo/sssd src/sysv/SUSE/sssd
  524                  po/Makefile.in src/man/Makefile src/tests/cwrap/Makefile
  525                  src/tests/intg/Makefile src/tests/test_CA/Makefile
  526                  src/tests/test_ECC_CA/Makefile
  527                  src/lib/ipa_hbac/ipa_hbac.pc src/lib/ipa_hbac/ipa_hbac.doxy
  528                  src/lib/idmap/sss_idmap.pc src/lib/idmap/sss_idmap.doxy
  529                  src/lib/certmap/sss_certmap.pc src/lib/certmap/sss_certmap.doxy
  530                  src/sss_client/idmap/sss_nss_idmap.pc
  531                  src/sss_client/idmap/sss_nss_idmap.doxy
  532                  src/sss_client/libwbclient/wbclient_sssd.pc
  533                  src/lib/sifp/sss_simpleifp.pc
  534                  src/lib/sifp/sss_simpleifp.doxy
  535                  src/config/setup.py
  536                  src/systemtap/sssd.stp
  537                  src/config/SSSDConfig/__init__.py])
  538 AC_CONFIG_FILES([sbus_generate.sh], [chmod +x sbus_generate.sh])
  539 AC_OUTPUT