"Fossies" - the Fresh Open Source Software Archive

Member "sqlite-autoconf-3320300/configure.ac" (18 Jun 2020, 7998 Bytes) of package /linux/misc/sqlite-autoconf-3320300.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the last Fossies "Diffs" side-by-side code changes report for "configure.ac": autoconf3250300_vs_3260000.

    1 
    2 #-----------------------------------------------------------------------
    3 # Supports the following non-standard switches.
    4 #
    5 #   --enable-threadsafe
    6 #   --enable-readline
    7 #   --enable-editline
    8 #   --enable-static-shell
    9 #   --enable-dynamic-extensions
   10 #
   11 
   12 AC_PREREQ(2.61)
   13 AC_INIT(sqlite, 3.32.3, http://www.sqlite.org)
   14 AC_CONFIG_SRCDIR([sqlite3.c])
   15 AC_CONFIG_AUX_DIR([.])
   16 
   17 # Use automake.
   18 AM_INIT_AUTOMAKE([foreign])
   19 
   20 AC_SYS_LARGEFILE
   21 
   22 # Check for required programs.
   23 AC_PROG_CC
   24 AC_PROG_LIBTOOL
   25 AC_PROG_MKDIR_P
   26 
   27 # Check for library functions that SQLite can optionally use.
   28 AC_CHECK_FUNCS([fdatasync usleep fullfsync localtime_r gmtime_r])
   29 AC_FUNC_STRERROR_R
   30 
   31 AC_CONFIG_FILES([Makefile sqlite3.pc])
   32 BUILD_CFLAGS=
   33 AC_SUBST(BUILD_CFLAGS)
   34 
   35 #-------------------------------------------------------------------------
   36 # Two options to enable readline compatible libraries: 
   37 #
   38 #   --enable-editline
   39 #   --enable-readline
   40 #
   41 # Both are enabled by default. If, after command line processing both are
   42 # still enabled, the script searches for editline first and automatically
   43 # disables readline if it is found. So, to use readline explicitly, the
   44 # user must pass "--disable-editline". To disable command line editing
   45 # support altogether, "--disable-editline --disable-readline".
   46 #
   47 # When searching for either library, check for headers before libraries 
   48 # as some distros supply packages that contain libraries but not header
   49 # files, which come as a separate development package.
   50 #
   51 AC_ARG_ENABLE(editline, [AS_HELP_STRING([--enable-editline],[use BSD libedit])])
   52 AC_ARG_ENABLE(readline, [AS_HELP_STRING([--enable-readline],[use readline])])
   53 
   54 AS_IF([ test x"$enable_editline" != xno ],[
   55   AC_CHECK_HEADERS([editline/readline.h],[
   56     sLIBS=$LIBS
   57     LIBS=""
   58     AC_SEARCH_LIBS([readline],[edit],[
   59       AC_DEFINE([HAVE_EDITLINE],1,Define to use BSD editline)
   60       READLINE_LIBS="$LIBS -ltinfo"
   61       enable_readline=no
   62     ],[],[-ltinfo])
   63     AS_UNSET(ac_cv_search_readline)
   64     LIBS=$sLIBS
   65   ])
   66 ])
   67 
   68 AS_IF([ test x"$enable_readline" != xno ],[
   69   AC_CHECK_HEADERS([readline/readline.h],[
   70     sLIBS=$LIBS
   71     LIBS=""
   72     AC_SEARCH_LIBS(tgetent, termcap curses ncurses ncursesw, [], [])
   73     AC_SEARCH_LIBS(readline,[readline edit], [
   74       AC_DEFINE([HAVE_READLINE],1,Define to use readline or wrapper)
   75       READLINE_LIBS=$LIBS
   76     ])
   77     LIBS=$sLIBS
   78   ])
   79 ])
   80 
   81 AC_SUBST(READLINE_LIBS)
   82 #-----------------------------------------------------------------------
   83 
   84 #-----------------------------------------------------------------------
   85 #   --enable-threadsafe
   86 #
   87 AC_ARG_ENABLE(threadsafe, [AS_HELP_STRING(
   88   [--enable-threadsafe], [build a thread-safe library [default=yes]])], 
   89   [], [enable_threadsafe=yes])
   90 if test x"$enable_threadsafe" != "xno"; then
   91   BUILD_CFLAGS="$BUILD_CFLAGS -D_REENTRANT=1 -DSQLITE_THREADSAFE=1"
   92   AC_SEARCH_LIBS(pthread_create, pthread)
   93   AC_SEARCH_LIBS(pthread_mutexattr_init, pthread)
   94 fi
   95 #-----------------------------------------------------------------------
   96 
   97 #-----------------------------------------------------------------------
   98 #   --enable-dynamic-extensions
   99 #
  100 AC_ARG_ENABLE(dynamic-extensions, [AS_HELP_STRING(
  101   [--enable-dynamic-extensions], [support loadable extensions [default=yes]])], 
  102   [], [enable_dynamic_extensions=yes])
  103 if test x"$enable_dynamic_extensions" != "xno"; then
  104   AC_SEARCH_LIBS(dlopen, dl)
  105 else
  106   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_OMIT_LOAD_EXTENSION=1"
  107 fi
  108 AC_MSG_CHECKING([for whether to support dynamic extensions])
  109 AC_MSG_RESULT($enable_dynamic_extensions)
  110 #-----------------------------------------------------------------------
  111 
  112 #-----------------------------------------------------------------------
  113 #   --enable-fts4
  114 #
  115 AC_ARG_ENABLE(fts4, [AS_HELP_STRING(
  116   [--enable-fts4], [include fts4 support [default=yes]])], 
  117   [], [enable_fts4=yes])
  118 if test x"$enable_fts4" = "xyes"; then
  119   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_FTS4"
  120 fi
  121 #-----------------------------------------------------------------------
  122 
  123 #-----------------------------------------------------------------------
  124 #   --enable-fts3
  125 #
  126 AC_ARG_ENABLE(fts3, [AS_HELP_STRING(
  127   [--enable-fts3], [include fts3 support [default=no]])], 
  128   [], [])
  129 if test x"$enable_fts3" = "xyes" -a x"$enable_fts4" = "xno"; then
  130   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_FTS3"
  131 fi
  132 #-----------------------------------------------------------------------
  133 
  134 #-----------------------------------------------------------------------
  135 #   --enable-fts5
  136 #
  137 AC_ARG_ENABLE(fts5, [AS_HELP_STRING(
  138   [--enable-fts5], [include fts5 support [default=yes]])], 
  139   [], [enable_fts5=yes])
  140 if test x"$enable_fts5" = "xyes"; then
  141   AC_SEARCH_LIBS(log, m)
  142   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_FTS5"
  143 fi
  144 #-----------------------------------------------------------------------
  145 
  146 #-----------------------------------------------------------------------
  147 #   --enable-json1
  148 #
  149 AC_ARG_ENABLE(json1, [AS_HELP_STRING(
  150   [--enable-json1], [include json1 support [default=yes]])], 
  151   [],[enable_json1=yes])
  152 if test x"$enable_json1" = "xyes"; then
  153   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_JSON1"
  154 fi
  155 #-----------------------------------------------------------------------
  156 
  157 #-----------------------------------------------------------------------
  158 #   --enable-rtree
  159 #
  160 AC_ARG_ENABLE(rtree, [AS_HELP_STRING(
  161   [--enable-rtree], [include rtree support [default=yes]])], 
  162   [], [enable_rtree=yes])
  163 if test x"$enable_rtree" = "xyes"; then
  164   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_RTREE -DSQLITE_ENABLE_GEOPOLY"
  165 fi
  166 #-----------------------------------------------------------------------
  167 
  168 #-----------------------------------------------------------------------
  169 #   --enable-session
  170 #
  171 AC_ARG_ENABLE(session, [AS_HELP_STRING(
  172   [--enable-session], [enable the session extension [default=no]])], 
  173   [], [])
  174 if test x"$enable_session" = "xyes"; then
  175   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_SESSION -DSQLITE_ENABLE_PREUPDATE_HOOK"
  176 fi
  177 #-----------------------------------------------------------------------
  178 
  179 #-----------------------------------------------------------------------
  180 #   --enable-debug
  181 #
  182 AC_ARG_ENABLE(debug, [AS_HELP_STRING(
  183   [--enable-debug], [build with debugging features enabled [default=no]])], 
  184   [], [])
  185 if test x"$enable_debug" = "xyes"; then
  186   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_DEBUG -DSQLITE_ENABLE_SELECTTRACE -DSQLITE_ENABLE_WHERETRACE"
  187   CFLAGS="-g -O0"
  188 fi
  189 #-----------------------------------------------------------------------
  190 
  191 #-----------------------------------------------------------------------
  192 #   --enable-static-shell
  193 #
  194 AC_ARG_ENABLE(static-shell, [AS_HELP_STRING(
  195   [--enable-static-shell], 
  196   [statically link libsqlite3 into shell tool [default=yes]])], 
  197   [], [enable_static_shell=yes])
  198 if test x"$enable_static_shell" = "xyes"; then
  199   EXTRA_SHELL_OBJ=sqlite3-sqlite3.$OBJEXT
  200 else
  201   EXTRA_SHELL_OBJ=libsqlite3.la
  202 fi
  203 AC_SUBST(EXTRA_SHELL_OBJ)
  204 #-----------------------------------------------------------------------
  205 
  206 AC_CHECK_FUNCS(posix_fallocate)
  207 AC_CHECK_HEADERS(zlib.h,[
  208   AC_SEARCH_LIBS(deflate,z,[BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_HAVE_ZLIB"])
  209 ])
  210 
  211 AC_SEARCH_LIBS(system,,,[SHELL_CFLAGS="-DSQLITE_NOHAVE_SYSTEM"])
  212 AC_SUBST(SHELL_CFLAGS)
  213 
  214 #-----------------------------------------------------------------------
  215 # UPDATE: Maybe it's better if users just set CFLAGS before invoking
  216 # configure. This option doesn't really add much...
  217 #
  218 #   --enable-tempstore
  219 #
  220 # AC_ARG_ENABLE(tempstore, [AS_HELP_STRING(
  221 #   [--enable-tempstore], 
  222 #   [in-memory temporary tables (never, no, yes, always) [default=no]])], 
  223 #   [], [enable_tempstore=no])
  224 # AC_MSG_CHECKING([for whether or not to store temp tables in-memory])
  225 # case "$enable_tempstore" in
  226 #   never )  TEMP_STORE=0 ;;
  227 #   no )     TEMP_STORE=1 ;;
  228 #   always ) TEMP_STORE=3 ;;
  229 #   yes )    TEMP_STORE=3 ;;
  230 #   * )
  231 #     TEMP_STORE=1
  232 #     enable_tempstore=yes
  233 #   ;;
  234 # esac
  235 # AC_MSG_RESULT($enable_tempstore)
  236 # AC_SUBST(TEMP_STORE)
  237 #-----------------------------------------------------------------------
  238 
  239 AC_OUTPUT