"Fossies" - the Fresh Open Source Software Archive

Member "smbnetfs-0.6.3/configure.ac" (31 Jan 2021, 3291 Bytes) of package /linux/misc/smbnetfs-0.6.3.tar.bz2:

As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "configure.ac": 0.6.2_vs_0.6.3.

    1 AC_INIT([SMBNetFS],[0.6.3])
    2 AM_INIT_AUTOMAKE
    3 AC_CONFIG_HEADERS([src/config.h])
    4 AC_PROG_CC
    5 
    6 AC_CHECK_FUNC(backtrace_symbols_fd,
    7     [AC_DEFINE([HAVE_BACKTRACE], [], [Linux])]
    8 )
    9 AC_CHECK_FUNC(setlocale, [found_setlocale=yes])
   10 if test "x$found_setlocale" != "xyes" ; then
   11     AC_MSG_ERROR([*** No setlocale() implementation found in C library])
   12 fi
   13 
   14 
   15 export PKG_CONFIG_PATH=/usr/local/lib/pkgconfig:$PKG_CONFIG_PATH
   16 CFLAGS="$CFLAGS -Wall -W"
   17 LDFLAGS="$LDFLAGS -rdynamic"
   18 
   19 
   20 dnl ***********************
   21 dnl *** Tests for iconv ***
   22 dnl ***********************
   23 AC_ARG_WITH(libiconv,
   24     [AS_HELP_STRING(--with-libiconv=@<:@no/gnu/native@:>@,
   25 	use the libiconv library)],
   26     ,
   27     [with_libiconv=maybe])
   28 
   29 found_iconv=no
   30 case $with_libiconv in
   31     maybe)
   32 	# Check in the C library first
   33 	AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
   34 
   35 	# Check if we have GNU libiconv
   36 	if test $found_iconv = "no"; then
   37 	    AC_CHECK_LIB(iconv, libiconv_open, 
   38 		[with_libiconv=gnu; found_iconv=yes])
   39 	fi
   40 
   41 	# Check if we have a iconv in -liconv, possibly from vendor
   42 	if test $found_iconv = "no"; then
   43 	    AC_CHECK_LIB(iconv, iconv_open, 
   44 		[with_libiconv=native; found_iconv=yes])
   45 	fi
   46 	;;
   47     no)
   48 	AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
   49         ;;
   50     gnu|yes)
   51 	AC_CHECK_LIB(iconv, libiconv_open, 
   52 	    [with_libiconv=gnu; found_iconv=yes])
   53 	;;
   54     native)
   55 	AC_CHECK_LIB(iconv, iconv_open, 
   56 	    [with_libiconv=native; found_iconv=yes])
   57 	;;
   58 esac
   59 
   60 if test "x$found_iconv" = "xno" ; then
   61     AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
   62 fi
   63 
   64 case $with_libiconv in
   65     gnu)
   66 	AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
   67 	;;
   68     native)
   69 	AC_DEFINE(USE_LIBICONV_NATIVE, 1, 
   70 	    [Using a native implementation of iconv in a separate library])
   71 	;;
   72 esac
   73 
   74 
   75 dnl **********************
   76 dnl *** Tests for fuse ***
   77 dnl **********************
   78 PKG_CHECK_MODULES(FUSE, [fuse >= 2.6])
   79 LIBS="$LIBS $FUSE_LIBS"
   80 CFLAGS="$CFLAGS -D_REENTRANT -D_GNU_SOURCE -DFUSE_USE_VERSION=26 $FUSE_CFLAGS"
   81 
   82 dnl **************************
   83 dnl *** Tests for glib-2.0 ***
   84 dnl **************************
   85 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.30])
   86 LIBS="$LIBS $GLIB_LIBS"
   87 CFLAGS="$CFLAGS $GLIB_CFLAGS"
   88 
   89 dnl ***************************
   90 dnl *** Tests for libsecret ***
   91 dnl ***************************
   92 AC_ARG_WITH(libsecret,
   93 	[AS_HELP_STRING(--with-libsecret=@<:@no/yes@:>@,
   94 		use libsecret as password storage @<:@default=auto@:>@)],
   95 	,
   96 	[with_libsecret=maybe])
   97 
   98 if test x"$with_libsecret" != xno; then
   99 	PKG_CHECK_MODULES(LIBSECRET, [libsecret-1 >= 0.18.5],
  100 		[AC_DEFINE([HAVE_LIBSECRET], [],
  101 			[use libsecret as password storage])],
  102 		[# mandatory depend
  103 		if test x"$with_libsecret" = xyes; then
  104 			AC_MSG_ERROR([unable to find usable libsecret])
  105 		fi])
  106 	LIBS="$LIBS $LIBSECRET_LIBS"
  107 	CFLAGS="$CFLAGS $LIBSECRET_CFLAGS"
  108 fi
  109 
  110 dnl ******************************
  111 dnl *** Tests for libsmbclient ***
  112 dnl ******************************
  113 PKG_CHECK_MODULES(SMBCLIENT, [smbclient])
  114 AC_CHECK_LIB(smbclient, smbc_setOptionUseCCache, [], [
  115 	echo "Error!!! libsmbclient >= 3.5 required."
  116 	exit 1
  117 ])
  118 
  119 LIBS="$LIBS $SMBCLIENT_LIBS"
  120 CFLAGS="$CFLAGS $SMBCLIENT_CFLAGS"
  121 
  122 dnl ******************
  123 dnl *** Final step ***
  124 dnl ******************
  125 
  126 AC_CONFIG_FILES([Makefile src/Makefile])
  127 AC_OUTPUT