"Fossies" - the Fresh Open Source Software Archive

Member "scalasca-2.6/configure.ac" (19 Apr 2021, 9594 Bytes) of package /linux/misc/scalasca-2.6.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the last Fossies "Diffs" side-by-side code changes report for "configure.ac": 2.3.1_vs_2.4.

    1 ##*************************************************************************##
    2 ##  SCALASCA    http://www.scalasca.org/                                   ##
    3 ##*************************************************************************##
    4 ##  Copyright (c) 1998-2021                                                ##
    5 ##  Forschungszentrum Juelich GmbH, Juelich Supercomputing Centre          ##
    6 ##                                                                         ##
    7 ##  Copyright (c) 2009-2013                                                ##
    8 ##  German Research School for Simulation Sciences GmbH,                   ##
    9 ##  Laboratory for Parallel Programming                                    ##
   10 ##                                                                         ##
   11 ##  This software may be modified and distributed under the terms of       ##
   12 ##  a BSD-style license.  See the COPYING file in the package base         ##
   13 ##  directory for details.                                                 ##
   14 ##*************************************************************************##
   15 
   16 
   17 ##--- Setup -----------------------------------------------------------------
   18 
   19 ## Set up Autoconf
   20 AC_PREREQ([2.69])
   21 AC_INIT([Scalasca],
   22         m4_esyscmd([build-config/common/generate-package-version.sh build-config/VERSION]),
   23         [scalasca@fz-juelich.de],,[https://www.scalasca.org])
   24 AFS_PACKAGE_INIT
   25 
   26 ## Save user provided arguments for use by sub-configures
   27 SCALASCA_TOPLEVEL_ARGS
   28 
   29 ## Where to find auxiliary build tools & local macros
   30 AC_CONFIG_AUX_DIR([build-config])
   31 ## See also ACLOCAL_AMFLAGS in Makefile.am.
   32 AC_CONFIG_MACRO_DIRS([build-config/m4 build-config/common/m4])
   33 
   34 ## Set the default installation prefix
   35 AC_PREFIX_DEFAULT([/opt/scalasca])
   36 
   37 ## Set up Automake
   38 AM_INIT_AUTOMAKE([1.13.4 -Wall foreign tar-pax])
   39 AM_SILENT_RULES([yes])
   40 AFS_MAINTAINER_MODE
   41 
   42 ## Initialize configuration summary
   43 AFS_SUMMARY_INIT
   44 
   45 
   46 ##--- Package-specific configuration ----------------------------------------
   47 
   48 ## Working from git? Get revision info
   49 AC_SCOREP_GIT_CONTROLLED
   50 AC_SCOREP_REVISION
   51 
   52 ## Platform detection
   53 AC_SCOREP_DETECT_PLATFORMS
   54 AC_SCOREP_PLATFORM_SETTINGS
   55 AFS_CROSSCOMPILING
   56 
   57 ## Don't detect and load defaults in nested configures
   58 AS_IF([test ! -n "$ac_scorep_platform_data_provided" || \
   59        test "x${ac_scorep_platform_data_provided}" = "xno"],
   60       [AFS_CUSTOM_COMPILERS
   61        AS_IF([test "x${afs_custom_compilers_given}" = "xno"],
   62              [dnl AFS_COMPILER_BACKEND([CC, CXX, F77, FC])
   63               AC_SCOREP_WITH_COMPILER_SUITE
   64               AS_CASE([${afs_custom_compilers_given},${ac_scorep_platform}],
   65                   [no,mac|no,mingw],
   66                       [AC_MSG_ERROR([have no suitable defaults to build Scalasca on $afs_scorep_platform_name yet. Please use --with-custom-compilers and provide settings to <AC_PACKAGE_BUGREPORT> on success. Thanks.])],
   67                   [no,unknown],
   68                       [AC_MSG_ERROR([cannot detect platform to set suitable defaults. Please use --with-custom-compilers and provide settings and platform to <AC_PACKAGE_BUGREPORT> on success. Thanks.])
   69                   ])
   70               AC_SCOREP_WITH_MPI_COMPILER_SUITE
   71              ])
   72        # Determine arguments for subdir configures
   73        args="`$AWK -f $srcdir/build-config/common/process_arguments.awk \
   74               $ac_scorep_compilers_mpi                                         \
   75               $ac_scorep_compilers_frontend                                    \
   76               $ac_scorep_compilers_backend                                     \
   77               user_provided_configure_args`"
   78       ],
   79       [AC_MSG_NOTICE([platform data provided by toplevel configure.])
   80        AFS_SUMMARY([Platform], [$ac_scorep_platform (provided)])
   81        # Determine arguments for subdir configures
   82        args="`$AWK -f $srcdir/build-config/common/process_arguments.awk \
   83               user_provided_configure_args`"
   84       ])
   85 
   86 ## Check for cross-compilation
   87 AM_CONDITIONAL([CROSS_BUILD], [test "x${ac_scorep_cross_compiling}" = "xyes"])
   88 
   89 ## Checks for platform specifics
   90 SCALASCA_DETECT_MIC_BUILD
   91 AM_CONDITIONAL([BUILD_MIC_WRAPPER],
   92     [test "x${ac_scorep_platform}" = "xmic" || \
   93      test "x${scalasca_have_mic_support}" = "xyes"])
   94 
   95 ## Check for programs
   96 AC_PROG_LN_S
   97 AC_PROG_SED
   98 AC_SCOREP_DOXYGEN
   99 AC_SCOREP_UNCRUSTIFY
  100 SCALASCA_CORPORATE_STY
  101 
  102 ## Check for libraries
  103 AC_SCOREP_HAVE_CONFIG_TOOL([otf2], [8], [0])
  104 AS_IF([test -n "${scorep_otf2_config_bin}" && \
  105        test "x${ac_scorep_platform}" = "xmic"],
  106       [scorep_otf2_have_mic=no
  107        for target in `${scorep_otf2_config_bin} --features=targets`
  108        do
  109            AS_CASE([${target}],
  110                [mic], [scorep_otf2_have_mic=yes])
  111        done
  112        AS_IF([test "x${scorep_otf2_have_mic}" = "xno"],
  113              [AC_MSG_ERROR([cannot detect MIC support for external OTF2 installation. Either provide a suitable OTF2 library or reconfigure ]AC_PACKAGE_NAME[ with the '--without-otf2' option to use the included OTF2 copy.])])
  114       ])
  115 AFS_SUMMARY([epilog support], [yes, using internal])
  116 AC_SCOREP_HAVE_CONFIG_TOOL([cubew], [8], [0])
  117 AS_IF([test -n "${scorep_cubew_config_bin}" && \
  118        test "x${ac_scorep_platform}" = "xmic"],
  119       [scorep_cubew_have_mic=no
  120        for target in `${scorep_cubew_config_bin} --features=targets`
  121        do
  122            AS_CASE([${target}],
  123                [mic], [scorep_cubew_have_mic=yes])
  124        done
  125        AS_IF([test "x${scorep_cubew_have_mic}" = "xno"],
  126              [AC_MSG_ERROR([cannot detect MIC support for external Cube installation. Either provide a suitable Cube library or reconfigure ]AC_PACKAGE_NAME[ with the '--without-cubew' option to use the included Cube C writer copy.])])
  127       ])
  128 
  129 ## Handle external package's subdir configures
  130 PROHIBIT_MAKE_DIST=
  131 AS_IF([test "x${scorep_have_otf2_config}" = "xyes"],
  132           [AS_VAR_APPEND([PROHIBIT_MAKE_DIST], [" --without-otf2"])],
  133       [test -x ${srcdir}/vendor/otf2/configure],
  134           [AX_CONFIG_SUBDIR([vendor/otf2], [${args} ac_scorep_platform=${ac_scorep_platform} ac_scorep_platform_data_provided=yes ac_scorep_cross_compiling=${ac_scorep_cross_compiling} ac_scorep_doxygen_distdir=${ac_scorep_doxygen_distdir}/vendor/otf2])],
  135       [AC_MSG_ERROR([No OTF2 component available. Either provide the internal package at 'vendor/otf2' or an external installation with '--with-otf2'.])])
  136 AS_IF([test "x${scorep_have_cubew_config}" = "xyes"],
  137           [AS_VAR_APPEND([PROHIBIT_MAKE_DIST], [" --without-cubew"])],
  138       [test -x ${srcdir}/vendor/cubew/configure],
  139           [AX_CONFIG_SUBDIR([vendor/cubew], [${args} afs_externally_triggered=yes ac_scorep_doxygen_distdir=${ac_scorep_doxygen_distdir}/vendor/cubew])],
  140       [AC_MSG_ERROR([No CubeW component available. Either provide the internal package at 'vendor/cubew' or an external installation with '--with-cubew'.])])
  141 AC_SUBST([PROHIBIT_MAKE_DIST])
  142 
  143 ## Handle own package's subdir configures
  144 AX_CONFIG_SUBDIR([build-backend],
  145                  [${args} ${backend_args} ac_scorep_platform=${ac_scorep_platform} ac_scorep_cross_compiling=${ac_scorep_cross_compiling} ${scorep_otf2_config_arg} ${scorep_cubew_config_arg}])
  146 AS_IF([test "x${with_mpi}" != "xno"],
  147       [AX_CONFIG_SUBDIR([build-mpi],
  148                         [${args} ${backend_args} ac_scorep_platform=${ac_scorep_platform} ac_scorep_cross_compiling=${ac_scorep_cross_compiling} ${scorep_otf2_config_arg} ${scorep_cubew_config_arg}])])
  149 AM_COND_IF([CROSS_BUILD],
  150            [AX_CONFIG_SUBDIR([build-frontend],
  151                              [${args} ac_scorep_platform=${ac_scorep_platform} ac_scorep_cross_compiling=${ac_scorep_cross_compiling}])])
  152 
  153 
  154 ##--- Generate output -------------------------------------------------------
  155 
  156 ## Additional configuration summary output
  157 AS_IF([test "x${with_mpi}" = "xno"],
  158       [AFS_SUMMARY([MPI support], [disabled])])
  159 
  160 ## Generate config files
  161 AC_CONFIG_FILES([Makefile
  162                  src/config-custom.h
  163                  src/config-common.h:build-config/common/config-common.h
  164                  doc/patterns/remap_info.html
  165                  share/scout.spec
  166                  share/scout_pre44.spec])
  167 AM_COND_IF([HAVE_DOXYGEN],
  168            [AC_CONFIG_FILES([doc/doxygen-common/config.tex
  169                              doc/doxygen-common/doxygen-common.cfg
  170                              doc/doxygen-common/doxygen-pearl.cfg
  171                              doc/doxygen-common/doxygen-scout.cfg
  172                              doc/doxygen-common/doxygen-silas.cfg
  173                              doc/doxygen-common/doxygen-utils.cfg
  174                              doc/doxygen-dev/pearl/doxygen-pearl-dev.cfg
  175                              doc/doxygen-dev/scout/doxygen-scout-dev.cfg
  176                              doc/doxygen-dev/silas/doxygen-silas-dev.cfg
  177                              doc/doxygen-dev/utils/doxygen-utils-dev.cfg
  178                              doc/doxygen-user/manual/doxygen-manual.cfg
  179                              doc/doxygen-user/manpages/doxygen-man.cfg
  180                              doc/doxygen-user/pearl/doxygen-pearl-user.cfg])])
  181 
  182 ## Generate Scalasca error codes headers
  183 AC_CONFIG_FILES(
  184     [src/ScalascaErrorCodes.h:common/utils/src/exception/ErrorCodes.tmpl.h],
  185     [$srcdir/common/utils/src/exception/finalize_error_codes.sh \
  186         SCALASCA \
  187         $srcdir/share/scalasca.errors \
  188         src/ScalascaErrorCodes.h \
  189         src/scalasca_error_decls.gen.h])
  190 
  191 AM_EXTRA_RECURSIVE_TARGETS([beautify check-build])
  192 AC_OUTPUT
  193 
  194 ## Print configuration summary
  195 AS_IF([test "x$ac_scorep_platform_data_provided" != "xyes"], [
  196     AFS_SUMMARY_COLLECT
  197 ])