"Fossies" - the Fresh Open Source Software Archive

Member "scalasca-2.6/build-config/m4/ac_scalasca_zlib.m4" (19 Apr 2021, 2691 Bytes) of package /linux/misc/scalasca-2.6.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the last Fossies "Diffs" side-by-side code changes report for "ac_scalasca_zlib.m4": 2.3.1_vs_2.4.

    1 ##*************************************************************************##
    2 ##  SCALASCA    http://www.scalasca.org/                                   ##
    3 ##*************************************************************************##
    4 ##  Copyright (c) 1998-2017                                                ##
    5 ##  Forschungszentrum Juelich GmbH, Juelich Supercomputing Centre          ##
    6 ##                                                                         ##
    7 ##  Copyright (c) 2009-2013                                                ##
    8 ##  German Research School for Simulation Sciences GmbH,                   ##
    9 ##  Laboratory for Parallel Programming                                    ##
   10 ##                                                                         ##
   11 ##  This software may be modified and distributed under the terms of       ##
   12 ##  a BSD-style license.  See the COPYING file in the package base         ##
   13 ##  directory for details.                                                 ##
   14 ##*************************************************************************##
   15 
   16 
   17 AC_DEFUN([AC_SCALASCA_ZLIB], [
   18     AS_IF([test "x${ac_scorep_platform}" = xk || \
   19            test "x${ac_scorep_platform}" = xfx10 || \
   20            test "x${ac_scorep_platform}" = xfx100],
   21         [AC_DEFINE([HAVE_ZLIB_H])
   22          BYPASS_GENERIC_LIB_CHECK_ON_FUJITSU([libz], [-lz])],
   23         [AC_SCOREP_BACKEND_LIB([libz], [zlib.h], [])])
   24 ])
   25 
   26 
   27 AC_DEFUN([_AC_SCOREP_LIBZ_LIB_CHECK], [
   28     AC_LANG_PUSH([C++])
   29 
   30     # Check function declarations
   31     AC_CHECK_DECLS([gzopen, gzclose, gzread], [],
   32                    [with_libz_lib_checks_successful=no],
   33                    [
   34                        AC_INCLUDES_DEFAULT
   35                        #ifdef HAVE_ZLIB_H
   36                        # include <zlib.h>
   37                        #endif
   38                    ])
   39 
   40     # Link check
   41     AS_IF([test "x${with_libz_lib_checks_successful}" != "xno"],
   42           [LIBS="-lz"
   43            AC_LINK_IFELSE([AC_LANG_PROGRAM([[
   44                               #ifdef HAVE_ZLIB_H
   45                               # include <zlib.h>
   46                               #endif
   47                           ]],
   48                           [[
   49                               int    x  = 42;
   50                               gzFile fp = gzopen("foo", "r");
   51                               gzread(fp, &x, sizeof(x));
   52                               gzclose(fp);
   53                           ]])],
   54                           [with_libz_lib_checks_successful=yes
   55                            with_libz_libs="-lz"],
   56                           [with_libz_lib_checks_successful=no
   57                            with_libz_libs=""])
   58           ])
   59 
   60     AC_LANG_POP([C++])
   61 ])