"Fossies" - the Fresh Open Source Software Archive

Member "rush-1.9/m4/stdbool.m4" (19 Apr 2019, 3534 Bytes) of package /linux/privat/rush-1.9.tar.xz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "stdbool.m4": 1.8_vs_1.9.

    1 # Check for stdbool.h that conforms to C99.
    2 
    3 dnl Copyright (C) 2002-2006, 2009-2019 Free Software Foundation, Inc.
    4 dnl This file is free software; the Free Software Foundation
    5 dnl gives unlimited permission to copy and/or distribute it,
    6 dnl with or without modifications, as long as this notice is preserved.
    7 
    8 #serial 7
    9 
   10 # Prepare for substituting <stdbool.h> if it is not supported.
   11 
   12 AC_DEFUN([AM_STDBOOL_H],
   13 [
   14   AC_REQUIRE([AC_CHECK_HEADER_STDBOOL])
   15 
   16   # Define two additional variables used in the Makefile substitution.
   17 
   18   if test "$ac_cv_header_stdbool_h" = yes; then
   19     STDBOOL_H=''
   20   else
   21     STDBOOL_H='stdbool.h'
   22   fi
   23   AC_SUBST([STDBOOL_H])
   24   AM_CONDITIONAL([GL_GENERATE_STDBOOL_H], [test -n "$STDBOOL_H"])
   25 
   26   if test "$ac_cv_type__Bool" = yes; then
   27     HAVE__BOOL=1
   28   else
   29     HAVE__BOOL=0
   30   fi
   31   AC_SUBST([HAVE__BOOL])
   32 ])
   33 
   34 # AM_STDBOOL_H will be renamed to gl_STDBOOL_H in the future.
   35 AC_DEFUN([gl_STDBOOL_H], [AM_STDBOOL_H])
   36 
   37 # This version of the macro is needed in autoconf <= 2.68.
   38 
   39 AC_DEFUN([AC_CHECK_HEADER_STDBOOL],
   40   [AC_CACHE_CHECK([for stdbool.h that conforms to C99],
   41      [ac_cv_header_stdbool_h],
   42      [AC_COMPILE_IFELSE(
   43         [AC_LANG_PROGRAM(
   44            [[
   45              #include <stdbool.h>
   46 
   47              #ifdef __cplusplus
   48               typedef bool Bool;
   49              #else
   50               typedef _Bool Bool;
   51               #ifndef bool
   52                "error: bool is not defined"
   53               #endif
   54               #ifndef false
   55                "error: false is not defined"
   56               #endif
   57               #if false
   58                "error: false is not 0"
   59               #endif
   60               #ifndef true
   61                "error: true is not defined"
   62               #endif
   63               #if true != 1
   64                "error: true is not 1"
   65               #endif
   66              #endif
   67 
   68              #ifndef __bool_true_false_are_defined
   69               "error: __bool_true_false_are_defined is not defined"
   70              #endif
   71 
   72              struct s { Bool s: 1; Bool t; bool u: 1; bool v; } s;
   73 
   74              char a[true == 1 ? 1 : -1];
   75              char b[false == 0 ? 1 : -1];
   76              char c[__bool_true_false_are_defined == 1 ? 1 : -1];
   77              char d[(bool) 0.5 == true ? 1 : -1];
   78              /* See body of main program for 'e'.  */
   79              char f[(Bool) 0.0 == false ? 1 : -1];
   80              char g[true];
   81              char h[sizeof (Bool)];
   82              char i[sizeof s.t];
   83              enum { j = false, k = true, l = false * true, m = true * 256 };
   84              /* The following fails for
   85                 HP aC++/ANSI C B3910B A.05.55 [Dec 04 2003]. */
   86              Bool n[m];
   87              char o[sizeof n == m * sizeof n[0] ? 1 : -1];
   88              char p[-1 - (Bool) 0 < 0 && -1 - (bool) 0 < 0 ? 1 : -1];
   89              /* Catch a bug in an HP-UX C compiler.  See
   90                 https://gcc.gnu.org/ml/gcc-patches/2003-12/msg02303.html
   91                 https://lists.gnu.org/r/bug-coreutils/2005-11/msg00161.html
   92               */
   93              Bool q = true;
   94              Bool *pq = &q;
   95              bool *qq = &q;
   96            ]],
   97            [[
   98              bool e = &s;
   99              *pq |= q; *pq |= ! q;
  100              *qq |= q; *qq |= ! q;
  101              /* Refer to every declared value, to avoid compiler optimizations.  */
  102              return (!a + !b + !c + !d + !e + !f + !g + !h + !i + !!j + !k + !!l
  103                      + !m + !n + !o + !p + !q + !pq + !qq);
  104            ]])],
  105         [ac_cv_header_stdbool_h=yes],
  106         [ac_cv_header_stdbool_h=no])])
  107    AC_CHECK_TYPES([_Bool])
  108 ])