"Fossies" - the Fresh Open Source Software Archive

Member "recoll-1.26.3/qtgui/recoll.pro.in" (18 Oct 2019, 5145 Bytes) of package /linux/privat/recoll-1.26.3.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file.

    1 TEMPLATE        = app
    2 LANGUAGE        = C++
    3 
    4 VPATH = @srcdir@
    5 DEFINES += BUILDING_RECOLL
    6 
    7 @QMAKE_ENABLE_WEBKIT@ QT += webkit
    8 @QMAKE_ENABLE_WEBKIT@ DEFINES += USING_WEBKIT
    9 
   10 @QMAKE_ENABLE_WEBENGINE@ QT += webengine
   11 @QMAKE_ENABLE_WEBENGINE@ DEFINES += USING_WEBENGINE
   12 
   13 QMAKE_CXXFLAGS += -std=c++11
   14 
   15 @QMAKE_ENABLE_ZEITGEIST@ QT += dbus
   16 @QMAKE_ENABLE_ZEITGEIST@ QMAKE_CXXFLAGS += -DUSE_ZEITGEIST
   17 
   18 QT += xml
   19 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport
   20 
   21 @QMAKE_ENABLE_WEBKIT@ greaterThan(QT_MAJOR_VERSION, 4): QT += webkitwidgets
   22 @QMAKE_ENABLE_WEBENGINE@ greaterThan(QT_MAJOR_VERSION, 4): QT += webenginewidgets
   23 
   24 CONFIG  += qt warn_on thread release 
   25 
   26 HEADERS += \
   27         advsearch_w.h \
   28         advshist.h \
   29         confgui/confgui.h \
   30         confgui/confguiindex.h \
   31         crontool.h \
   32         firstidx.h \
   33         fragbuts.h \
   34         idxsched.h \
   35         preview_load.h \
   36         preview_plaintorich.h \
   37         preview_w.h \
   38         ptrans_w.h \
   39         rclhelp.h \
   40         rclmain_w.h \
   41         reslist.h \
   42         restable.h \
   43         rtitool.h \
   44         searchclause_w.h \
   45         snippets_w.h \
   46         specialindex.h \
   47         spell_w.h \
   48         ssearch_w.h \
   49         systray.h \
   50         uiprefs_w.h \
   51         viewaction_w.h \
   52         webcache.h \
   53         widgets/editdialog.h \
   54         widgets/listdialog.h \
   55         widgets/qxtconfirmationmessage.h
   56 
   57 SOURCES += \
   58         advsearch_w.cpp \
   59         advshist.cpp \
   60         confgui/confgui.cpp \
   61         confgui/confguiindex.cpp \
   62         crontool.cpp \
   63         fragbuts.cpp \
   64         guiutils.cpp \
   65         main.cpp \
   66         multisave.cpp \
   67         preview_load.cpp \
   68         preview_plaintorich.cpp \
   69         preview_w.cpp \
   70         ptrans_w.cpp \
   71         rclhelp.cpp \
   72         rclm_idx.cpp \
   73         rclm_preview.cpp \
   74         rclm_saveload.cpp \
   75         rclm_view.cpp \
   76         rclm_wins.cpp \
   77         rclmain_w.cpp \
   78         rclzg.cpp \
   79         reslist.cpp \
   80         respopup.cpp \
   81         restable.cpp \
   82         rtitool.cpp \
   83         searchclause_w.cpp \
   84         snippets_w.cpp \
   85         spell_w.cpp \
   86         ssearch_w.cpp \
   87         systray.cpp \
   88         uiprefs_w.cpp \
   89         viewaction_w.cpp \
   90         webcache.cpp \
   91         widgets/qxtconfirmationmessage.cpp \
   92         xmltosd.cpp
   93 
   94 FORMS   = \
   95         advsearch.ui \
   96         crontool.ui \
   97         firstidx.ui \
   98         idxsched.ui \
   99         preview.ui \
  100         ptrans.ui \
  101         rclmain.ui \
  102         restable.ui \
  103         rtitool.ui \
  104         snippets.ui \
  105         specialindex.ui \
  106         spell.ui \
  107         ssearchb.ui \
  108         uiprefs.ui \
  109         viewaction.ui \
  110         webcache.ui \
  111         widgets/editdialog.ui \
  112         widgets/listdialog.ui 
  113         
  114 RESOURCES = recoll.qrc
  115 
  116 unix {
  117   UI_DIR = .ui
  118   MOC_DIR = .moc
  119   OBJECTS_DIR = .obj
  120   LIBS += -L../.libs -lrecoll
  121 
  122   !macx {
  123     # Note: libdir may be substituted with sthing like $(exec_prefix)/lib
  124     # at this point and will go as such in the Makefile. Expansion will be
  125     # completed at make time.
  126     LIBS += -Wl,-rpath=@libdir@/recoll
  127   }
  128 
  129   LIBS +=  @LIBXAPIAN@ $(LIBXAPIANSTATICEXTRA) \
  130        @LIBICONV@ $(BDYNAMIC) @LIBQZEITGEIST@ -lz
  131 
  132   INCLUDEPATH += ../common @srcdir@/../common @srcdir@/../index \
  133               @srcdir@/../internfile @srcdir@/../query @srcdir@/../unac \
  134               @srcdir@/../utils @srcdir@/../aspell @srcdir@/../rcldb \
  135               @srcdir@/../qtgui @srcdir@/../xaposix @srcdir@/confgui \
  136               @srcdir@/widgets
  137   DEPENDPATH += $$INCLUDEPATH
  138 }
  139 
  140 UNAME = $$system(uname -s)
  141 contains( UNAME, [lL]inux ) {
  142 	  LIBS += -ldl -lX11
  143 }
  144 
  145 contains( UNAME, SunOS ) {
  146           LIBS += -ldl
  147 }
  148 
  149 macx {
  150     ICON = images/recoll.icns
  151 }
  152 
  153 TRANSLATIONS = \
  154 	     i18n/recoll_cs.ts \
  155 	     i18n/recoll_da.ts \
  156 	     i18n/recoll_de.ts \
  157 	     i18n/recoll_el.ts \
  158 	     i18n/recoll_es.ts \
  159              i18n/recoll_fr.ts \
  160              i18n/recoll_it.ts \
  161              i18n/recoll_lt.ts \
  162              i18n/recoll_ru.ts \
  163              i18n/recoll_tr.ts \
  164              i18n/recoll_uk.ts \
  165              i18n/recoll_xx.ts \
  166              i18n/recoll_zh_CN.ts \
  167              i18n/recoll_zh.ts \
  168 
  169 unix {
  170   isEmpty(PREFIX) {
  171     PREFIX = /usr/local
  172   }
  173   message("Prefix is $$PREFIX")
  174   DEFINES += PREFIX=\\\"$$PREFIX\\\"
  175 
  176  # Installation stuff
  177   target.path = "$$PREFIX/bin"
  178 
  179   imdata.files = @srcdir@/mtpics/*.png
  180   imdata.path = $$PREFIX/share/recoll/images
  181   trdata.files = @srcdir@/i18n/*.qm
  182   trdata.path = $$PREFIX/share/recoll/translations
  183   desktop.files += @srcdir@/../desktop/recoll-searchgui.desktop
  184   desktop.path = $$PREFIX/share/applications/
  185   icona.files += @srcdir@/../desktop/recoll.png
  186   icona.path = $$PREFIX/share/icons/hicolor/48x48/apps/
  187   iconb.files += @srcdir@/../desktop/recoll.png
  188   iconb.path = $$PREFIX/share/pixmaps/
  189   appdata.files = @srcdir@/../desktop/recoll.appdata.xml
  190   appdata.path = $$PREFIX/share/appdata/
  191   INSTALLS += target imdata trdata desktop icona iconb appdata
  192 
  193   # The recollinstall script used to do the following to install zh_CN as
  194   # zh. Is this still needed?
  195   #${INSTALL} -m 0444 ${I18N}/recoll_zh_CN.qm \
  196   #  ${datadir}/recoll/translations/recoll_zh.qm || exit 1
  197 }