"Fossies" - the Fresh Open Source Software Archive

Member "qt-creator-opensource-src-5.0.2/docs.pri" (30 Sep 2021, 1876 Bytes) of package /linux/misc/qt-creator-opensource-src-5.0.2.tar.xz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file.

    1 # Creates targets for building Qt Creator documentation
    2 #
    3 # Usage: Include qtcreator.pri and define DOC_FILES to point to a list of qdocconf files,
    4 #        then include this .pri file
    5 
    6 isEmpty(VERSION): error("Include qtcreator.pri before including docs.pri!")
    7 
    8 qtcname.name = IDE_DISPLAY_NAME
    9 qtcname.value = "$$IDE_DISPLAY_NAME"
   10 qtcid.name = IDE_ID
   11 qtcid.value = $$IDE_ID
   12 qtccasedid.name = IDE_CASED_ID
   13 qtccasedid.value = $$IDE_CASED_ID
   14 qtcver.name = QTC_VERSION
   15 qtcver.value = $$QTCREATOR_DISPLAY_VERSION
   16 qtcvertag.name = QTC_VERSION_TAG
   17 qtcvertag.value = $$replace(VERSION, \.,)
   18 qtdocs.name = QT_INSTALL_DOCS
   19 qtdocs.value = $$[QT_INSTALL_DOCS/src]
   20 qdocindex.name = QDOC_INDEX_DIR
   21 qdocindex.value = $$[QT_INSTALL_DOCS]
   22 qtcdocsdir.name = QTC_DOCS_DIR
   23 qtcdocsdir.value = $$IDE_SOURCE_TREE/doc
   24 qtccopyrightyear.name = QTCREATOR_COPYRIGHT_YEAR
   25 qtccopyrightyear.value = $$QTCREATOR_COPYRIGHT_YEAR
   26 qtcsourcedir.name = IDE_SOURCE_TREE
   27 qtcsourcedir.value = $$IDE_SOURCE_TREE
   28 QDOC_ENV += qtcname \
   29             qtcid \
   30             qtccasedid \
   31             qtcver \
   32             qtcvertag \
   33             qtdocs \
   34             qdocindex \
   35             qtcdocsdir \
   36             qtccopyrightyear \
   37             qtcsourcedir
   38 
   39 DOC_INDEX_PATHS += $$IDE_BUILD_TREE/doc
   40 DOC_HTML_INSTALLDIR = $$INSTALL_DOC_PATH
   41 DOC_QCH_OUTDIR = $$IDE_DOC_PATH
   42 DOC_QCH_INSTALLDIR = $$INSTALL_DOC_PATH
   43 
   44 minQtVersion(5, 11, 0) {
   45     for (include_path, INCLUDEPATH): \
   46         DOC_INCLUDES += -I $$shell_quote($$include_path)
   47     for (module, QT) {
   48         MOD_INCLUDES = $$eval(QT.$${module}.includes)
   49         for (include_path, MOD_INCLUDES): \
   50             DOC_INCLUDES += -I $$shell_quote($$include_path)
   51     }
   52     for (include_path, QMAKE_DEFAULT_INCDIRS): \
   53         DOC_INCLUDES += -I $$shell_quote($$include_path)
   54     macos: DOC_INCLUDES += -F $$shell_quote($$[QT_INSTALL_LIBS])
   55 }
   56 
   57 include(doc/doc_targets.pri)