"Fossies" - the Fresh Open Source Software Archive

Member "protobuf-3.21.1/m4/ac_system_extensions.m4" (27 May 2022, 1105 Bytes) of package /linux/misc/protobuf-all-3.21.1.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file.

    1 dnl Provide AC_USE_SYSTEM_EXTENSIONS for old autoconf machines.
    2 AC_DEFUN([ACX_USE_SYSTEM_EXTENSIONS],[
    3   ifdef([AC_USE_SYSTEM_EXTENSIONS],[
    4     AC_USE_SYSTEM_EXTENSIONS
    5   ],[
    6     AC_BEFORE([$0], [AC_COMPILE_IFELSE])
    7     AC_BEFORE([$0], [AC_RUN_IFELSE])
    8 
    9     AC_REQUIRE([AC_GNU_SOURCE])
   10     AC_REQUIRE([AC_AIX])
   11     AC_REQUIRE([AC_MINIX])
   12 
   13     AH_VERBATIM([__EXTENSIONS__],
   14 [/* Enable extensions on Solaris.  */
   15 #ifndef __EXTENSIONS__
   16 # undef __EXTENSIONS__
   17 #endif
   18 #ifndef _POSIX_PTHREAD_SEMANTICS
   19 # undef _POSIX_PTHREAD_SEMANTICS
   20 #endif
   21 #ifndef _TANDEM_SOURCE
   22 # undef _TANDEM_SOURCE
   23 #endif])
   24     AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
   25       [ac_cv_safe_to_define___extensions__],
   26       [AC_COMPILE_IFELSE(
   27          [AC_LANG_PROGRAM([
   28 #           define __EXTENSIONS__ 1
   29             AC_INCLUDES_DEFAULT])],
   30          [ac_cv_safe_to_define___extensions__=yes],
   31          [ac_cv_safe_to_define___extensions__=no])])
   32     test $ac_cv_safe_to_define___extensions__ = yes &&
   33       AC_DEFINE([__EXTENSIONS__])
   34     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
   35     AC_DEFINE([_TANDEM_SOURCE])
   36   ])
   37 ])