"Fossies" - the Fresh Open Source Software Archive

Member "xtables-addons-3.13/configure.ac" (20 Nov 2020, 2554 Bytes) of package /linux/privat/xtables-addons-3.13.tar.xz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "configure.ac": 3.12_vs_3.13.

    1 AC_INIT([xtables-addons], [3.13])
    2 AC_CONFIG_AUX_DIR([build-aux])
    3 AC_CONFIG_HEADERS([config.h])
    4 AC_CONFIG_MACRO_DIR([m4])
    5 AC_PROG_INSTALL
    6 AM_INIT_AUTOMAKE([1.10b -Wall foreign subdir-objects])
    7 AC_PROG_CC
    8 AM_PROG_CC_C_O
    9 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
   10 AC_DISABLE_STATIC
   11 AC_PROG_LIBTOOL
   12 
   13 AC_ARG_WITH([kbuild],
   14 	AS_HELP_STRING([--with-kbuild=PATH],
   15 	[Path to kernel build directory [[/lib/modules/CURRENT/build]]])
   16 AS_HELP_STRING([--without-kbuild],
   17 	[Build only userspace tools]),
   18 	[kbuilddir="$withval"],
   19 	[kbuilddir="/lib/modules/$(uname -r)/build"])
   20 #
   21 # check for --without-kbuild
   22 #
   23 if [[ "$kbuilddir" == no ]]; then
   24 	kbuilddir="";
   25 fi
   26 
   27 AC_CHECK_HEADERS([linux/netfilter/x_tables.h], [],
   28 	[AC_MSG_ERROR([You need to have linux/netfilter/x_tables.h, see INSTALL file for details])])
   29 PKG_CHECK_MODULES([libxtables], [xtables >= 1.6.0])
   30 xtlibdir="$($PKG_CONFIG --variable=xtlibdir xtables)"
   31 
   32 AC_ARG_WITH([xtlibdir],
   33 	AS_HELP_STRING([--with-xtlibdir=PATH],
   34 	[Path where to install Xtables extensions [[autodetect]]]),
   35 	[xtlibdir="$withval"])
   36 AC_MSG_CHECKING([Xtables module directory])
   37 AC_MSG_RESULT([$xtlibdir])
   38 
   39 regular_CPPFLAGS="-D_LARGEFILE_SOURCE=1 -D_LARGE_FILES -D_FILE_OFFSET_BITS=64 \
   40 	-D_REENTRANT -I\${XA_TOPSRCDIR}/include"
   41 regular_CFLAGS="-Wall -Waggregate-return -Wmissing-declarations \
   42 	-Wmissing-prototypes -Wredundant-decls -Wshadow -Wstrict-prototypes \
   43 	-Winline -pipe";
   44 
   45 if test -n "$kbuilddir"; then
   46 	AC_MSG_CHECKING([kernel version that we will build against])
   47 	krel="$(make -sC "$kbuilddir" M=$PWD kernelrelease | $AWK -v 'FS=[[^0-9.]]' '{print $1; exit}')"
   48 	save_IFS="$IFS"
   49 	IFS='.'
   50 	set x $krel
   51 	IFS="$save_IFS"
   52 	kmajor="$(($2+0))"
   53 	kminor="$(($3+0))"
   54 	kmicro="$(($4+0))"
   55 	kstable="$(($5+0))"
   56 	if test -z "$kmajor" -o -z "$kminor" -o -z "$kmicro"; then
   57 		echo "WARNING: Version detection did not succeed. Continue at own luck.";
   58 	else
   59 		echo "$kmajor.$kminor.$kmicro.$kstable in $kbuilddir";
   60 		if test "$kmajor" -gt 5 -o "$kmajor" -eq 5 -a "$kminor" -gt 10; then
   61 			echo "WARNING: That kernel version is not officially supported yet. Continue at own luck.";
   62 		elif test "$kmajor" -eq 5 -a "$kminor" -ge 0; then
   63 			:
   64 		elif test "$kmajor" -eq 4 -a "$kminor" -ge 15; then
   65 			:
   66 		else
   67 			echo "WARNING: That kernel version is not officially supported.";
   68 		fi;
   69 	fi;
   70 fi;
   71 
   72 AC_SUBST([regular_CPPFLAGS])
   73 AC_SUBST([regular_CFLAGS])
   74 AC_SUBST([kbuilddir])
   75 AC_SUBST([xtlibdir])
   76 AC_CONFIG_FILES([Makefile Makefile.iptrules Makefile.mans geoip/Makefile
   77 	extensions/Makefile extensions/ACCOUNT/Makefile
   78 	extensions/pknock/Makefile])
   79 AC_OUTPUT