"Fossies" - the Fresh Open Source Software Archive

Member "zsync-0.6.2/configure.ac" (19 Sep 2010, 1949 Bytes) of package /linux/privat/old/zsync-0.6.2.tar.gz:

    1 # Process this file with autoconf to produce a configure script.
    2 
    3 AC_INIT([zsync],[0.6.2],[http://zsync.moria.org.uk/])
    4 
    5 AC_CONFIG_SRCDIR([client.c])
    6 AC_CONFIG_AUX_DIR([autotools])
    7 AC_CONFIG_MACRO_DIR([autotools])
    8 
    9 AC_CANONICAL_HOST
   10 
   11 AM_INIT_AUTOMAKE([dist-bzip2 no-dist-gzip foreign check-news -Woverride -Wobsolete -Wportability -Wsyntax -Wunsupported])
   12 AM_MAINTAINER_MODE
   13 
   14 dnl --- Check for programs
   15 AC_PROG_CC
   16 AC_PROG_LN_S
   17 AC_PROG_RANLIB
   18 
   19 AC_ARG_ENABLE([profile],
   20    AS_HELP_STRING([--enable-profile],[Turns on profiling]))
   21 
   22 AS_IF([test "x$enable_profile" = "xyes"], [
   23    ZS_CFLAGS="${ZS_CFLAGS} -pg" ])
   24 
   25 dnl --- Header files, typedefs, structures, libraries
   26 AC_C_CONST
   27 AC_HEADER_STDC
   28 # string.h, memory.h, stdlib.h both included in the default header checks
   29 # but we do need to give at least one .h to test, or Solaris sh errors
   30 AC_CHECK_HEADERS([string.h])
   31 AC_TYPE_SIZE_T
   32 AC_CHECK_FUNCS(memcpy pwrite pread mkstemp)
   33 
   34 X_TYPE_SOCKLEN_T
   35 X_TYPE_IN_PORT_T
   36 X_DECL_H_ERRNO
   37 
   38 dnl Solaris needs -lsocket - and we need this for the getaddrinfo test
   39 AC_CHECK_LIB(socket,socket)
   40 
   41 AC_REPLACE_FUNCS(getaddrinfo)
   42 
   43 dnl - Large file support if available
   44 AC_SYS_LARGEFILE
   45 AC_FUNC_FSEEKO
   46 AC_CHECK_SIZEOF(size_t)
   47 AC_CHECK_SIZEOF(off_t)
   48 
   49 AM_WITH_DMALLOC
   50 
   51 case $host_os in
   52    mingw32)
   53        host_os_mingw32=yes
   54        LIBS="${LIBS} -lwsock32"
   55        ;;
   56    *)
   57        AC_DEFINE([_XOPEN_SOURCE], 600, [Enable POSIX extensions if present])
   58        AC_DEFINE([_BSD_SOURCE],1, [Enable BSD extensions if present])
   59        ;;
   60 esac
   61 AM_CONDITIONAL([MINGW32], test "x$host_os_mingw32" = "xyes")
   62 
   63 X_C_COMPILE_FLAGS($ZS_CFLAGS -g -Wall -Wwrite-strings -Winline -Wextra -Winline -Wmissing-noreturn -Wredundant-decls -Wnested-externs -Wundef -Wbad-function-cast -Wcast-align -Wvolatile-register-var -ffast-math)
   64 
   65 dnl --- output
   66 AC_SUBST(ac_aux_dir)
   67 AC_CONFIG_HEADERS([config.h])
   68 AC_CONFIG_FILES([Makefile librcksum/Makefile zlib/Makefile libzsync/Makefile doc/Makefile])
   69 AC_OUTPUT
   70