"Fossies" - the Fresh Open Source Software Archive

Member "labplot-2.8.2/CMakeLists.txt" (24 Feb 2021, 14715 Bytes) of package /linux/privat/labplot-2.8.2.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "CMakeLists.txt": 2.8.1_vs_2.8.2.

    1 project(labplot2)
    2 
    3 # minimum 3.2.0 for FindGSL.cmake
    4 cmake_minimum_required (VERSION 3.2.0 FATAL_ERROR)
    5 set(CMAKE_C_STANDARD 99)
    6 set(CMAKE_C_STANDARD_REQUIRED ON)
    7 set(CMAKE_CXX_STANDARD 11)
    8 set(CMAKE_CXX_STANDARD_REQUIRED ON)
    9 set(CMAKE_CXX_EXTENSIONS OFF)
   10 
   11 set(QT_MINIMUM_VERSION 5.6.0)
   12 set(KF5_MIN_VERSION "5.16.0")
   13 
   14 set(APPLE_SUPPRESS_X11_WARNING ON)
   15 
   16 find_package(ECM REQUIRED NO_MODULE)
   17 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake/ ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR})
   18 # build type: "release", "debug", "debugfull"
   19 string (TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE)
   20 find_package(Qt5 ${QT_MIN_VERSION} NO_MODULE REQUIRED COMPONENTS
   21 	Concurrent
   22 	Gui
   23 # 	Qml
   24 # 	Quick
   25 # 	QuickWidgets
   26 	PrintSupport
   27 	Sql
   28 	Svg
   29 	Widgets
   30 	Test
   31 )
   32 
   33 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
   34 	Archive
   35 	Completion
   36 	Config
   37 	ConfigWidgets
   38 	CoreAddons
   39 	Crash
   40 	DocTools
   41 	I18n
   42 	IconThemes
   43 	KIO
   44 	TextWidgets
   45 	WidgetsAddons
   46 	XmlGui
   47 	NewStuffCore
   48 	NewStuff
   49 OPTIONAL_COMPONENTS
   50 	Service
   51 	Parts
   52 	SyntaxHighlighting
   53 )
   54 # TODO: make NewStuff optional?
   55 IF (KF5NewStuff_FOUND)
   56 	add_definitions (-DHAVE_KF5_NEW_STUFF)
   57 ELSE ()
   58         MESSAGE (STATUS "KF5 new stuff not found")
   59 ENDIF ()
   60 # TODO: service not used?
   61 IF (NOT KF5Service_FOUND)
   62 	MESSAGE (STATUS "KF5 service not found")
   63 ENDIF ()
   64 # TODO: parts not used?
   65 IF (NOT KF5Parts_FOUND)
   66 	MESSAGE (STATUS "KF5 parts not found")
   67 ENDIF ()
   68 IF (KF5SyntaxHighlighting_FOUND)
   69 	add_definitions (-DHAVE_KF5_SYNTAX_HIGHLIGHTING)
   70 ELSE ()
   71 	MESSAGE (STATUS "KF5 syntax highlighting not found")
   72 ENDIF ()
   73 
   74 find_package(KUserFeedback)
   75 IF (KUserFeedback_FOUND)
   76 	MESSAGE (STATUS "Found KUserFeedback")
   77 	add_definitions (-DHAVE_KUSERFEEDBACK)
   78 ELSE ()
   79 	MESSAGE (STATUS "KUserFeedback not found")
   80 ENDIF ()
   81 
   82 find_package(BISON REQUIRED)
   83 
   84 include(FeatureSummary)
   85 include(ECMAddAppIcon)
   86 include(ECMInstallIcons)
   87 include(KDEInstallDirs)
   88 include(KDECompilerSettings)
   89 include(KDECMakeSettings)
   90 
   91 ### compiler flags ######################################
   92 set (GENERIC_FLAGS "-Wall -Wextra -Wundef -Wpointer-arith -Wunreachable-code -Wunused -Wdeprecated-declarations -fno-omit-frame-pointer -fstack-protector")
   93 set (GENERIC_GNU_FLAGS "-O2 -Wcast-align -Wswitch-enum -fvisibility=default")
   94 set (GENERIC_C_FLAGS "${GENERIC_FLAGS} -fno-exceptions")
   95 # liborigin needs exceptions
   96 set (GENERIC_CXX_FLAGS "${GENERIC_FLAGS} -fexceptions")
   97 
   98 if ("${CMAKE_C_COMPILER_ID}" MATCHES "GNU")
   99 	message(STATUS "GNU C compiler detected, adding compile flags")
  100 	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${GENERIC_C_FLAGS} ${GENERIC_GNU_FLAGS}")
  101 elseif ("${CMAKE_C_COMPILER_ID}" MATCHES "Clang")
  102 	message(STATUS "Clang C compiler detected, adding compile flags")
  103 	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_GNU_SOURCE ${GENERIC_C_FLAGS} ${GENERIC_GNU_FLAGS}")
  104 elseif ("${CMAKE_C_COMPILER_ID}" MATCHES "Intel")
  105 	message(STATUS "Intel C compiler detected, adding compile flags")
  106 	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_GNU_SOURCE -O3 ${GENERIC_C_FLAGS}")
  107 elseif ("${CMAKE_C_COMPILER_ID}" MATCHES "PGI")
  108 	message(STATUS "PGI C compiler detected, adding compile flags")
  109 	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_GNU_SOURCE -O3 -D__GCC_ATOMIC_TEST_AND_SET_TRUEVAL=1 -Minform=inform -Mbounds -Mchkstk")
  110 # " x" postfix to work around a bug in CMake that causes "MSVC" to translate to something completely different
  111 elseif (("${CMAKE_C_COMPILER_ID} x" MATCHES "MSVC") OR MSVC)
  112 	message(STATUS "MSVC C compiler detected, adding compile flags")
  113 	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O2 -W3")
  114 	set(MSVC_FOUND TRUE)
  115 else ()
  116 	message(STATUS "UNKNOWN C compiler, adding compile flags")
  117 	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${GENERIC_C_FLAGS}")
  118 endif()
  119 
  120 if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "GNU")
  121 	message(STATUS "GNU C++ compiler detected, adding compile flags")
  122 	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GENERIC_CXX_FLAGS} ${GENERIC_GNU_FLAGS}")
  123 elseif ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
  124 	message(STATUS "Clang C++ compiler detected, adding compile flags")
  125 	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_GNU_SOURCE ${GENERIC_CXX_FLAGS} ${GENERIC_GNU_FLAGS}")
  126 elseif ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Intel")
  127 	message(STATUS "Intel C++ compiler detected, adding compile flags")
  128 	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_GNU_SOURCE -std=c++11 ${GENERIC_CXX_FLAGS}")
  129 	#-std=c++0x comes with cmake's general flags, deprecated in icc, remove it
  130 	string(REPLACE "-std=c++0x" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
  131 elseif ("${CMAKE_CXX_COMPILER_ID}" MATCHES "PGI")
  132 	message(STATUS "PGI C++ compiler detected, adding compile flags")
  133 	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_GNU_SOURCE -O3 -std=c++11 -D__GCC_ATOMIC_TEST_AND_SET_TRUEVAL=1 -Minform=inform -Mbounds -Mchkstk")
  134 # " x" postfix to work around a bug in CMake that causes "MSVC" to translate to something completely different
  135 elseif (("${CMAKE_CXX_COMPILER_ID} x" MATCHES "MSVC") OR MSVC)
  136 	message(STATUS "MSVC C++ compiler detected, adding compile flags")
  137 	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O2 -W3 -DPSAPI_VERSION=1")
  138 	set(MSVC_FOUND TRUE)
  139 else ()
  140 	message(STATUS "UNKNOWN C++ compiler, adding compile flags")
  141 	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GENERIC_CXX_FLAGS}")
  142 endif ()
  143 
  144 ##########################################################ESC[m
  145 
  146 
  147 add_definitions (${QT_DEFINITIONS} ${QT_QTDBUS_DEFINITIONS})
  148 include_directories (${QDBUS_INCLUDE_DIRS} ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR})
  149 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake ${CMAKE_MODULE_PATH})
  150 add_definitions (-DLVERSION=\"2.8.2\")
  151 add_definitions (-DCXX_COMPILER=\"${CMAKE_CXX_COMPILER_ID}\ ${CMAKE_CXX_COMPILER_VERSION}\")
  152 add_definitions (-DCXX_COMPILER_FLAGS=\"${CMAKE_CXX_FLAGS}\")
  153 set(BUILD_SHARED_LIBS true)
  154 
  155 #cmake_policy(SET CMP0002 OLD)
  156 IF (CMAKE_VERSION VERSION_EQUAL "3.3" OR CMAKE_VERSION VERSION_GREATER "3.3")
  157 	cmake_policy(SET CMP0063 NEW)
  158 ENDIF()
  159 
  160 if (CMAKE_VERSION VERSION_GREATER "3.5")
  161   set(ENABLE_CLANG_TIDY OFF CACHE BOOL "Add clang-tidy automatically to builds")
  162   if (ENABLE_CLANG_TIDY)
  163     find_program (CLANG_TIDY_EXE NAMES "clang-tidy" PATHS /usr/bin)
  164     if (CLANG_TIDY_EXE)
  165       message(STATUS "Clang-tidy supported, found and enabled: ${CLANG_TIDY_EXE}")
  166       set(CLANG_TIDY_CHECKS "modernize-*,-modernize-use-trailing-return-type,clang-analyzer-*,-clang-analyzer-cplusplus*")
  167       #set(CLANG_TIDY_CHECKS "-*,modernize-*,clang-analyzer-*")
  168       # -extra-arg=--std=c++11
  169       set(CMAKE_CXX_CLANG_TIDY "${CLANG_TIDY_EXE};-checks=${CLANG_TIDY_CHECKS};-header-filter='${CMAKE_SOURCE_DIR}/*'"
  170         CACHE STRING "" FORCE)
  171     else()
  172       message(AUTHOR_WARNING "clang-tidy not found!")
  173       set(CMAKE_CXX_CLANG_TIDY "" CACHE STRING "" FORCE) # delete it
  174     endif()
  175    else()
  176     message(STATUS "Clang-tidy supported but disabled")
  177   endif()
  178 endif()
  179 
  180 ### Options ######################################
  181 option(ENABLE_CANTOR "Build with Cantor support" ON)
  182 option(ENABLE_FFTW "Build with FFTW support" ON)
  183 option(ENABLE_HDF5 "Build with HDF5 support" ON)
  184 option(ENABLE_NETCDF "Build with NetCDF support" ON)
  185 option(ENABLE_FITS "Build with FITS support" ON)
  186 option(ENABLE_LIBCERF "Build with libcerf support" ON)
  187 option(ENABLE_LIBORIGIN "Build with liborigin support" ON)
  188 option(ENABLE_ROOT "Build with ROOT (CERN) support" ON)
  189 option(ENABLE_READSTAT "Build with ReadStat support" OFF)
  190 option(ENABLE_TESTS "Build with tests" ON)
  191 option(ENABLE_MQTT "Build with MQTT support" ON)
  192 option(ENABLE_QTSERIALPORT "Build with QtSerialPort support" ON)
  193 option(ENABLE_REPRODUCIBLE "Enable reproducible builds" OFF)
  194 
  195 ### OS macros ####################################
  196 IF (WIN32)
  197 	add_definitions (-DHAVE_WINDOWS)
  198 	find_library (PSAPI Psapi)
  199 	message (STATUS "PSAPI: ${PSAPI}")
  200 ENDIF ()
  201 
  202 ### GSL (required) ###############################
  203 FIND_PACKAGE(GSL REQUIRED)
  204 
  205 ### liborigin (included) ###############################
  206 IF (ENABLE_LIBORIGIN)
  207 	add_definitions (-DHAVE_LIBORIGIN)
  208 
  209 	IF (CMAKE_BUILD_TYPE STREQUAL "debug" OR CMAKE_BUILD_TYPE STREQUAL "debugfull")
  210 		MESSAGE (STATUS "Origin project import (through internal liborigin) enabled (parser logging enabled)")
  211 		SET (ENABLE_ORIGIN_PARSER_LOG TRUE)
  212 	ELSE ()
  213 		MESSAGE (STATUS "Origin project import (through internal liborigin) enabled (parser logging disabled)")
  214 	ENDIF ()
  215 ELSE ()
  216 	MESSAGE (STATUS "Origin project import DISABLED")
  217 ENDIF ()
  218 
  219 ### Cantorlibs (optional) ###############################
  220 IF (ENABLE_CANTOR)
  221 FIND_PACKAGE (Cantor)
  222 SET_PACKAGE_PROPERTIES(Cantor PROPERTIES
  223 	URL "https://edu.kde.org/cantor/"
  224 )
  225 IF (Cantor_FOUND)
  226 	MESSAGE (STATUS "Found Cantor Library ${Cantor_VERSION}")
  227 
  228 	IF (${Cantor_VERSION} VERSION_GREATER "19.11")
  229 		add_definitions (-DHAVE_CANTOR_LIBS)
  230 		set(RECENT_CANTOR TRUE)
  231 		FIND_PACKAGE(Poppler "0.62.0" REQUIRED COMPONENTS Qt5)
  232 	ELSE ()
  233 		MESSAGE (STATUS "Cantor Library ${Cantor_VERSION} TOO OLD. Minimum usable version is 19.12")
  234 	ENDIF ()
  235 	IF (${Cantor_VERSION} VERSION_GREATER "20.08.9")
  236 		add_definitions (-DHAVE_NEW_CANTOR_LIBS)
  237 	ENDIF ()
  238 ELSE ()
  239 	MESSAGE (STATUS "Cantor Library NOT FOUND")
  240 ENDIF ()
  241 ELSE ()
  242 	MESSAGE (STATUS "Cantor Library DISABLED")
  243 ENDIF ()
  244 
  245 ### FFTW (optional) #####################################
  246 IF (ENABLE_FFTW)
  247 	FIND_PACKAGE (FFTW3)
  248 	IF (FFTW3_FOUND)
  249 		add_definitions (-DHAVE_FFTW3)
  250 	ELSE ()
  251 		MESSAGE (STATUS "FFTW 3 Library NOT FOUND")
  252 	ENDIF ()
  253 ELSE ()
  254 	MESSAGE (STATUS "FFTW 3 Library DISABLED")
  255 ENDIF ()
  256 
  257 ### HDF5 (optional) ##############################
  258 IF (ENABLE_HDF5)
  259 FIND_PACKAGE(HDF5 COMPONENTS C)
  260 SET_PACKAGE_PROPERTIES (HDF5 PROPERTIES
  261 	DESCRIPTION "Reading and writing self describing array data"
  262 	URL "https://www.hdfgroup.org/solutions/hdf5/"
  263 )
  264 IF (HDF5_FOUND)
  265 	add_definitions (-DHAVE_HDF5)
  266 	IF (MSVC_FOUND)
  267 		set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DH5_BUILT_AS_DYNAMIC_LIB")
  268 	ENDIF ()
  269 	IF (HDF5_VERSION VERSION_GREATER "1.9")
  270 		add_definitions (-DHAVE_AT_LEAST_HDF5_1_10_0)
  271 	ENDIF ()
  272 	IF (HDF5_VERSION VERSION_GREATER "1.10.0.1")
  273 		add_definitions (-DHAVE_AT_LEAST_HDF5_1_10_0)
  274 		add_definitions (-DHAVE_AT_LEAST_HDF5_1_10_1)
  275 	ENDIF ()
  276 	include_directories (${HDF5_INCLUDE_DIRS})
  277 ELSE ()
  278 	MESSAGE (STATUS "Hierarchical Data Format (HDF5) Library NOT FOUND")
  279 ENDIF ()
  280 ELSE ()
  281 	MESSAGE (STATUS "Hierarchical Data Format (HDF5) Library DISABLED")
  282 ENDIF ()
  283 
  284 ### NETCDF (optional) #############################
  285 IF (ENABLE_NETCDF)
  286 	FIND_PACKAGE(netCDF)
  287 	SET_PACKAGE_PROPERTIES(netCDF PROPERTIES
  288 	    DESCRIPTION "Interfaces for array-oriented data access"
  289 	    URL "https://www.unidata.ucar.edu/software/netcdf/"
  290 	)
  291 	IF (netCDF_FOUND)
  292 		add_definitions (-DHAVE_NETCDF)
  293 	ELSE ()
  294 		MESSAGE (STATUS "Network Common Data Format (NetCDF) Library NOT FOUND")
  295 	ENDIF ()
  296 ELSE ()
  297 	MESSAGE (STATUS "Network Common Data Format (NetCDF) Library DISABLED")
  298 ENDIF ()
  299 
  300 ### MQTT (optional) ###############################
  301 IF (ENABLE_MQTT)
  302 # ATTENTION: unit test uses qWaitFor() which needs Qt >= 5.10
  303 # avoid warning for the moment using QUIET
  304 	find_package(Qt5Mqtt ${QT_MIN_VERSION} NO_MODULE)
  305 	IF (Qt5Mqtt_FOUND)
  306 		MESSAGE (STATUS "Found MQTT Library")
  307 		add_definitions (-DHAVE_MQTT)
  308 	ELSE ()
  309 		MESSAGE (STATUS "MQTT Library NOT FOUND")
  310 	ENDIF ()
  311 ELSE ()
  312 	MESSAGE (STATUS "MQTT Library DISABLED")
  313 ENDIF ()
  314 
  315 ### QtSerialPort (optional) ###############################
  316 IF (ENABLE_QTSERIALPORT)
  317 	find_package(Qt5SerialPort ${QT_MIN_VERSION} NO_MODULE)
  318 	SET_PACKAGE_PROPERTIES (Qt5SerialPort PROPERTIES
  319 		DESCRIPTION "Qt Serial Port library"
  320 		URL "https://doc.qt.io/qt-5/qtserialport-index.html"
  321 		PURPOSE "Support basic functionality of serial ports.")
  322 	IF (Qt5SerialPort_FOUND)
  323 		MESSAGE (STATUS "Found Qt5SerialPort Library")
  324 		add_definitions (-DHAVE_QTSERIALPORT)
  325 	ELSE ()
  326 		MESSAGE (STATUS "Qt5SerialPort Library NOT FOUND")
  327 	ENDIF ()
  328 ELSE ()
  329         MESSAGE (STATUS "Qt5SerialPort Library DISABLED")
  330 ENDIF ()
  331 
  332 ### FITS (optional) ###############################
  333 IF (ENABLE_FITS)
  334 	FIND_PACKAGE (CFitsio)
  335 	SET_PACKAGE_PROPERTIES (CFitsio PROPERTIES
  336 		DESCRIPTION "FITS IO Library"
  337 		URL "https://heasarc.gsfc.nasa.gov/fitsio/fitsio.html"
  338 		PURPOSE "Support for the FITS (Flexible Image Transport System) data format.")
  339 	IF (CFITSIO_FOUND)
  340 		add_definitions (-DHAVE_FITS)
  341 		include_directories (${CFITSIO_INCLUDE_DIR})
  342 	ELSE ()
  343 		MESSAGE (STATUS "Flexible Image Transport System Data Format (FITS) Library NOT FOUND")
  344 	ENDIF ()
  345 ELSE ()
  346 	MESSAGE (STATUS "Flexible Image Transport System Data Format (FITS) Library DISABLED")
  347 ENDIF ()
  348 
  349 ### LIBCERF (optional) #############################
  350 IF (ENABLE_LIBCERF)
  351 	FIND_PACKAGE (LIBCERF)
  352 	IF (LIBCERF_FOUND)
  353 		add_definitions (-DHAVE_LIBCERF)
  354 	ELSE ()
  355 		MESSAGE (STATUS "libcerf library NOT FOUND")
  356 	ENDIF ()
  357 ELSE ()
  358 	MESSAGE (STATUS "libcerf library DISABLED")
  359 ENDIF ()
  360 
  361 ### ROOT (optional) #############################
  362 IF (ENABLE_ROOT)
  363 	FIND_PACKAGE(ZLIB)
  364 	SET_PACKAGE_PROPERTIES (ZLIB PROPERTIES
  365 		DESCRIPTION "General purpose compression library"
  366 		URL "https://www.zlib.net/"
  367 	)
  368 	FIND_PACKAGE(LZ4)
  369 	IF (ZLIB_FOUND AND LZ4_FOUND)
  370 		MESSAGE (STATUS "Found ZIP libraries ZLIB and LZ4 (needed for ROOT importer)")
  371 		add_definitions (-DHAVE_ZIP)
  372 	ELSE ()
  373 		MESSAGE (STATUS "ZIP libraries ZLIB and LZ4 (needed for ROOT importer) NOT FOUND")
  374 	ENDIF ()
  375 ELSE ()
  376 	MESSAGE (STATUS "ROOT (CERN) importer DISABLED")
  377 ENDIF ()
  378 
  379 ### ReadStat (optional) #############################
  380 # TODO: disabled on Windows until tested
  381 IF (ENABLE_READSTAT AND NOT WIN32)
  382 	FIND_PACKAGE (ReadStat)
  383 	IF (NOT READSTAT_FOUND)
  384 		MESSAGE (STATUS "ReadStat library NOT FOUND. Building own version")
  385 		set(BUILD_READSTAT TRUE)
  386 		set(READSTAT_LIBRARY ${CMAKE_BINARY_DIR}/src/3rdparty/install/lib/libreadstat.a)
  387 	ENDIF ()
  388 	add_definitions (-DHAVE_READSTAT)
  389 ELSE ()
  390 	MESSAGE (STATUS "ReadStat support DISABLED")
  391 ENDIF ()
  392 #################################################
  393 IF (ENABLE_REPRODUCIBLE)
  394 	add_definitions (-DREPRODUCIBLE_BUILD)
  395 	message(STATUS "Reproducable build ENABLED")
  396 ELSE ()
  397 	message(STATUS "Reproducable build DISABLED")
  398 ENDIF ()
  399 #################################################
  400 #################################################
  401 include(CheckFunctionExists)
  402 
  403 CHECK_FUNCTION_EXISTS(random HAVE_RANDOM_FUNCTION)
  404 #################################################
  405 FIND_PATH (XLOCALE_INCLUDE_DIR xlocale.h
  406 	/usr/include
  407 	/usr/local/include
  408 )
  409 IF (XLOCALE_INCLUDE_DIR)
  410 	add_definitions (-DHAVE_XLOCALE)
  411 	include_directories (${XLOCALE_INCLUDE_DIR})
  412 ENDIF()
  413 
  414 add_subdirectory(data)
  415 add_subdirectory(icons)
  416 add_subdirectory(src)
  417 add_subdirectory(doc)
  418 
  419 IF (ENABLE_LIBORIGIN)
  420 	add_subdirectory(liborigin)
  421 ENDIF ()
  422 
  423 if (ENABLE_TESTS)
  424     enable_testing(true)
  425     add_subdirectory(tests)
  426 endif()
  427 
  428 install(FILES org.kde.labplot2.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
  429 feature_summary(WHAT ALL)
  430 
  431 find_package(KF5I18n CONFIG REQUIRED)
  432 ki18n_install(po)
  433 find_package(KF5DocTools CONFIG REQUIRED)
  434 kdoctools_install(po)