"Fossies" - the Fresh Open Source Software Archive

Member "jpilot-2_0_1/configure.in" (3 Apr 2021, 19254 Bytes) of package /linux/privat/jpilot-2_0_1.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "configure.in": 1.8.2_vs_2_0_1.

    1 dnl ############################################################################
    2 dnl Process this file with autoconf to produce a configure script.
    3 dnl ############################################################################
    4 
    5 dnl boilerplate to initialize autoconf(AC) and automake(AM)
    6 AC_PREREQ([2.58])
    7 AC_INIT(jpilot, 2.0.1)
    8 AM_INIT_AUTOMAKE([1.8])
    9 
   10 dnl use a config.h file rather than string of -DXXX args to compiler
   11 dnl run autoheader before autoconf to create config.h.in from configure.in
   12 AM_CONFIG_HEADER(config.h)
   13 dnl enable maintainer mode in Makefiles (make dist, distclean)
   14 AM_MAINTAINER_MODE
   15 
   16 dnl ############################################################################
   17 dnl Check for programs needed during configure or build
   18 dnl ############################################################################
   19 AC_CANONICAL_HOST # determine build host
   20 AC_PROG_CC
   21 dnl AC_ISC_POSIX only needed for Interacive Systems UNIX which Sun
   22 dnl is discontinuing support on as of 7/23/2006.
   23 dnl This obsolete macro should probably be removed.
   24 AC_ISC_POSIX
   25 dnl Need intltool for i18n support
   26 AC_PROG_INTLTOOL()
   27 AC_PROG_INSTALL
   28 AC_PATH_PROG([SED], [sed], [ AC_MSG_ERROR([sed is required for configure script]) ])
   29 AC_PATH_PROG([GREP], [grep], [ AC_MSG_ERROR([grep is required for configure script]) ])
   30 AC_PATH_PROG([CUT], [cut], [ AC_MSG_ERROR([cut is required for configure script]) ])
   31 
   32 dnl ******************************
   33 dnl Libtool setup
   34 dnl ******************************
   35 dnl enable shared library building, turn off static libraries
   36 AC_DISABLE_STATIC
   37 AC_LIBTOOL_DLOPEN
   38 AC_PROG_LIBTOOL
   39 AC_SUBST(LIBTOOL_DEPS)
   40 
   41 dnl ******************************
   42 dnl Gettext setup
   43 dnl ******************************
   44 dnl Set of available languages
   45 ALL_LINGUAS="ca cs da de es fr it ja ko nl nb pt_BR ru rw sv tr uk vi zh_CN zh_TW"
   46 
   47 dnl Name of language files
   48 GETTEXT_PACKAGE=jpilot
   49 AC_SUBST(GETTEXT_PACKAGE)
   50 dnl 9/29/2006: Work around a bug in current versions of gettext/intltool
   51 dnl            which leave this macro undefined.
   52 DATADIRNAME=share
   53 AC_SUBST(DATADIRNAME)
   54 
   55 dnl Setup gettext using version available on host
   56 dnl The intl/ directory is not exported with the distribution
   57 AM_GNU_GETTEXT([external])
   58 AM_GNU_GETTEXT_VERSION([0.16.1])
   59 
   60 if test "x$MSGFMT" = "xno"; then
   61    if test "x$GMSGFMT" = "xno"; then
   62       AC_MSG_RESULT(No gettext found)
   63       AC_MSG_ERROR(Either install gettext or use 'configure --disable-nls')
   64    fi
   65 fi
   66 
   67 dnl gettext macros for context-sensitive messages depend on locale.h
   68 AC_CHECK_HEADER(locale.h,,
   69                 AC_MSG_ERROR(gettext requires locale.h.  Install locale.h or disable language support with 'configure --disable-nls'))
   70 
   71 dnl ############################################################################
   72 dnl Process Enable/Disable configure arguments
   73 dnl ############################################################################
   74 
   75 AC_ARG_ENABLE(plugins,
   76    AC_HELP_STRING([--disable-plugins],[Do not compile plugin support]),
   77    enable_plugins=$enableval,
   78    enable_plugins=yes)
   79 
   80 plugin_support=no
   81 
   82 if test "x$enable_plugins" = "xyes"; then
   83    AC_CHECK_FUNCS(dlopen)
   84    if test "x$ac_cv_func_dlopen" = "xyes"; then
   85       have_dlopen=yes
   86    else
   87       for lib in dl; do
   88          AC_CHECK_LIB($lib, dlopen, [LIBS="$LIBS -ldl";
   89           have_dlopen=yes; break])
   90       done
   91    fi
   92 
   93    if test "x$have_dlopen" = "xyes"; then
   94       AC_DEFINE(ENABLE_PLUGINS, 1, [ plugin support ])
   95       plugin_support="yes"
   96 ##      AC_SUBST(plugin_support) ## %RW: not apparently used anywhere
   97    else
   98       AC_MSG_RESULT(Could not find dlopen - plugin support disabled)
   99    fi
  100 else
  101    AC_MSG_RESULT(Plugin support disabled by configure options)
  102 fi
  103 
  104 dnl ************************************************************
  105 
  106 AC_ARG_ENABLE(private,
  107    AC_HELP_STRING([--disable-private],[Do not use private records feature (password not needed to see private records)]),
  108    enable_private=$enableval,
  109    enable_private=yes)
  110 
  111 if test "$enable_private" = "yes"; then
  112    AC_DEFINE(ENABLE_PRIVATE, 1, [ Private record support ])
  113 else
  114    AC_MSG_RESULT(Private record support disabled by configure options)
  115 fi
  116 
  117 dnl ************************************************************
  118 
  119 AC_ARG_ENABLE(datebk,
  120    AC_HELP_STRING([--disable-datebk],[Disable Datebk support]),
  121    enable_datebk=$enableval,
  122    enable_datebk=yes)
  123 
  124 if test "$enable_datebk" = "yes"; then
  125    AC_DEFINE(ENABLE_DATEBK, 1, [ DateBk support ])
  126 else
  127    AC_MSG_RESULT(Datebk support disabled by configure options)
  128 fi
  129 
  130 dnl ************************************************************
  131 
  132 AC_ARG_ENABLE(manana,
  133    AC_HELP_STRING([--disable-manana],[Disable Manana support]),
  134    enable_manana=$enableval,
  135    enable_manana=yes)
  136 
  137 if test "$enable_manana" = "yes"; then
  138    AC_DEFINE(ENABLE_MANANA, 1, [ Manana support ])
  139 else
  140    AC_MSG_RESULT(Manana support disabled by configure options)
  141 fi
  142 
  143 dnl ************************************************************
  144 
  145 AC_ARG_ENABLE(prometheon,
  146    AC_HELP_STRING([--enable-prometheon],[For use with Prometheon: http://www.prometheon.net]),
  147    enable_prometheon=$enableval,
  148    enable_prometheon=no)
  149 
  150 if test "$enable_prometheon" = "yes"; then
  151    AC_DEFINE(ENABLE_PROMETHEON, 1, [ Prometheon support ])
  152    AC_DEFINE_UNQUOTED(PROGNAME, "copilot", [ program name ])
  153    AC_MSG_RESULT(Prometheon support enabled)
  154 else
  155    AC_DEFINE_UNQUOTED(PROGNAME, "jpilot", [ program name ])
  156 fi
  157 
  158 AC_SUBST(PROGNAME)
  159 
  160 dnl ************************************************************
  161 
  162 AC_ARG_ENABLE(alarm-shell-danger,
  163    AC_HELP_STRING([--enable-alarm-shell-danger],[Allow alarm descriptions and notes to be used in alarm shell commands]),
  164    enable_alarm_shell_danger=$enableval,
  165    enable_alarm_shell_danger=no;
  166    )
  167 
  168 if test "$enable_alarm_shell_danger" = "yes"; then
  169    AC_DEFINE(ENABLE_ALARM_SHELL_DANGER, 1, [ Datebook description and note allowed  in shell commands ])
  170 fi
  171 
  172 dnl ************************************************************
  173 
  174 AC_ARG_ENABLE(stock_buttons,
  175    AC_HELP_STRING([--disable-stock-buttons],[Disable stock buttons (icons on GUI buttons)]),
  176    enable_stock_buttons=$enableval,
  177    enable_stock_buttons=yes)
  178 
  179 if test "x$enable_stock_buttons" = "xyes"; then
  180     AC_DEFINE(ENABLE_STOCK_BUTTONS, 1, [ Use GTK2 stock buttons ])
  181     AC_MSG_RESULT(stock buttons enabled by configure options)
  182 else
  183     AC_MSG_RESULT(stock buttons disabled by configure options)
  184 fi
  185 
  186 dnl ############################################################################
  187 dnl Check for libraries needed
  188 dnl ############################################################################
  189 dnl ******************************
  190 dnl * GTK3 libraries
  191 dnl ******************************
  192 AM_PATH_GTK_3_0(3.24.12, ,
  193   AC_MSG_ERROR([*** GTK >= 3.24.12 not found ***]))
  194 
  195 dnl ******************************
  196 dnl * pilot-link libs
  197 dnl ******************************
  198 pilot_prefix=""
  199 AC_ARG_WITH(pilot_prefix,
  200             AC_HELP_STRING([--with-pilot-prefix=PFX],[Prefix to top level of pilot-link files (e.g., = /usr/local if the pilot-link includes are in /usr/local/include and libs are in /usr/local/lib)]))
  201 
  202 if test "x$with_pilot_prefix" != "x"; then
  203    pilot_prefix=$with_pilot_prefix
  204 fi
  205 
  206 dnl Make sure that the pilot-link stuff actually exists
  207 
  208 AC_MSG_CHECKING(for pilot-link header files)
  209 pilotinclude=${FORCE_PILOT_INCLUDES:-no}
  210 if test "$pilotinclude" = "no" ; then
  211 for pilot_incl in $pilot_prefix/include /usr/include /usr/local/include \
  212                   /usr/extra/pilot/include /usr/include/libpisock; do
  213    if test -r "$pilot_incl/pi-version.h" ; then
  214       pilotinclude=yes
  215       PILOT_FLAGS="$PILOT_FLAGS -I$pilot_incl"
  216       break
  217    fi
  218 done
  219 fi
  220 
  221 if test "$pilotinclude" = "no" ; then
  222    AC_MSG_RESULT(no)
  223    AC_MSG_ERROR(Could not find the pilot-link header files)
  224 else
  225    AC_MSG_RESULT(found at $pilot_incl)
  226 fi
  227 
  228 dnl pilot-link headers are installed.  Now check for libraries
  229 
  230 AC_MSG_CHECKING(for pilot library files)
  231 pilotlibs=${FORCE_PILOT_LIBS:-no}
  232 PILOT_LIBS="-lpisock"
  233 
  234 if test "$pilotlibs" = "no" ; then
  235 for pilot_libs in $pilot_prefix/lib /usr/lib /usr/local/lib/ /usr/local/lib64 \
  236    /usr/extra/pilot/lib $pilot_prefix/lib64 /usr/lib64 ; do
  237    if test -r $pilot_libs/libpisock.so >/dev/null 2>&1 ; then
  238       pilotlibs=yes
  239       PILOT_LIBS="-L$pilot_libs $PILOT_LIBS"
  240       break
  241    fi
  242    if test -r "$pilot_libs/libpisock.a" ; then
  243       pilotlibs=yes
  244       PILOT_LIBS="-L$pilot_libs $PILOT_LIBS"
  245       break
  246    fi
  247    if test -r "$pilot_libs/libpisock.sl" ; then
  248       pilotlibs=yes
  249       PILOT_LIBS="-L$pilot_libs $PILOT_LIBS"
  250       break
  251    fi
  252 done
  253 fi
  254 
  255 if test "$pilotlibs" = "no" ; then
  256    AC_MSG_RESULT(no)
  257    AC_MSG_ERROR(Could not find the pilot-link libraries)
  258 else
  259    AC_MSG_RESULT(found at $pilot_libs)
  260 fi
  261 
  262 dnl Solaris needs the socket library
  263 AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
  264 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
  265 
  266 dnl Substitute macros now that LIB & FLAG detection is done
  267 AC_SUBST(PILOT_LIBS)
  268 AC_SUBST(PILOT_FLAGS)
  269 
  270 dnl ************************************************************
  271 
  272 AC_ARG_ENABLE(pl-test,
  273    AC_HELP_STRING([--disable-pl-test],[Do not try to compile a test pilot-link program]),
  274    enable_pl_test=$enableval,
  275    enable_pl_test=yes)
  276 
  277 dnl run some simple tests to verify pilot-link environment
  278 
  279 if test "x$enable_pl_test" = "xyes"; then
  280 
  281    pilotcompile=no
  282 
  283    dnl Check to make sure pilot-link library can be linked
  284 
  285    AC_MSG_CHECKING(to see if I can compile a pilot link program)
  286    save_CFLAGS="$CFLAGS"
  287    CFLAGS="$CFLAGS $PILOT_FLAGS"
  288    save_LIBS="$LIBS"
  289    LIBS="$LIBS $PILOT_LIBS"
  290 
  291    AC_TRY_LINK([#include "pi-version.h"
  292 #include "pi-socket.h"], [pi_close (0);] , pilotcompile=yes, , )
  293 
  294    if test "$pilotcompile" = "no" ; then
  295       AC_MSG_RESULT(no)
  296       AC_MSG_ERROR(Could not compile a test pilot-link program)
  297    else
  298       AC_MSG_RESULT(ok)
  299    fi
  300 
  301    dnl Try to run a pilot-link program (tests dynamic linking)
  302 
  303    AC_MSG_CHECKING(if I can run a pilot-link program)
  304    AC_TRY_RUN([
  305 #include <pi-version.h>
  306 int main()
  307 {
  308    return 0;
  309 }
  310 ],
  311    AC_MSG_RESULT([ok]),
  312    AC_MSG_ERROR([
  313 * Can not run a pilot-link test program
  314 * Make sure libpisock can be found by ld
  315 * Check /etc/ld.so.conf and run ldconfig
  316 * This test can be disabled by the --disable-pl-test option])
  317    , [ error ])
  318 
  319    dnl restore variables after pilot-link testing
  320    CFLAGS="$save_CFLAGS"
  321    LIBS="$save_LIBS"
  322 
  323 fi
  324 
  325 dnl * Check pilot-link pi-version.h
  326 
  327 AC_MSG_CHECKING(pilot-link version)
  328 
  329 save_CFLAGS="$CFLAGS"
  330 CFLAGS="$CFLAGS $PILOT_FLAGS"
  331 save_LIBS="$LIBS"
  332 LIBS="$LIBS $PILOT_LIBS"
  333 
  334 AC_TRY_COMPILE([#include <pi-version.h>], [
  335    exit(0);
  336 ], ,
  337  AC_MSG_ERROR([pilot-link header pi-version.h not found])
  338 )
  339 
  340 dnl * Pilot-link version variations, USB support, 12.0, etc.
  341 
  342 pl_version_check_done=no;
  343 
  344 pl_version=`$GREP "define PILOT_LINK_VERSION" "$pilot_incl/pi-version.h" | \
  345 $CUT -d " " -f 3`
  346 pl_major=`$GREP "define PILOT_LINK_MAJOR" "$pilot_incl/pi-version.h" | \
  347 $CUT -d " " -f 3`
  348 pl_minor=`$GREP "define PILOT_LINK_MINOR" "$pilot_incl/pi-version.h" | \
  349 $CUT -d " " -f 3`
  350 pl_patch=`$GREP "define PILOT_LINK_PATCH" "$pilot_incl/pi-version.h" | \
  351 $CUT -d " " -f 3 | $SED -e 's/"//g'`
  352 AC_MSG_RESULT([pi-version indicates $pl_version.$pl_major.$pl_minor])
  353 
  354 dnl *** check for pilot-link 0.12.5 and up
  355 
  356 if test $pl_version -eq 0 ; then
  357    if test $pl_major -ge 12 ; then
  358       if test $pl_minor -ge 0 ; then
  359          pl_version_check_done=yes;
  360          AC_MSG_RESULT([pilot-link has USB])
  361          AC_MSG_RESULT([pilot-link has card support (>12.0)])
  362          AC_MSG_RESULT([pilot-link has Calendar support (>12.5)])
  363       fi
  364    fi
  365 fi
  366 if test $pl_version_check_done != yes; then
  367    AC_MSG_ERROR([pilot-link version >= 0.12.5 is required])
  368 fi
  369 
  370 dnl restore variables after pilot-link testing
  371 CFLAGS="$save_CFLAGS"
  372 LIBS="$save_LIBS"
  373 
  374 dnl ******************************
  375 dnl * End pilot-links tests
  376 dnl ******************************
  377 
  378 dnl Check for gnu crypt lib necessary for Keyring
  379 crypto_lib="none"
  380 AM_PATH_LIBGCRYPT
  381 AC_CHECK_LIB([gcrypt], [gcry_md_hash_buffer], have_libgcrypt=1, have_libgcrypt=0)
  382 AC_ARG_WITH(openssl,
  383    AC_HELP_STRING([--with-openssl],[Use OpenSSL instead of GNU libgcrypt]),
  384    have_libgcrypt="0")
  385 if test "$have_libgcrypt" = "0"; then
  386 dnl Check for OpenSSL libs necessary for Keyring
  387    AC_CHECK_LIB([crypto], [SSLeay_version], have_libcrypto=1, have_libcrypto=0)
  388 else
  389 	AC_DEFINE(HAVE_LIBGCRYPT, 1, [ Use GNU libgcrypt instead of OpenSSL ])
  390 	crypto_lib="libgcrypt"
  391 fi
  392 
  393 dnl ############################################################################
  394 dnl Check for headers needed
  395 dnl ############################################################################
  396 dnl 10/2/06: only headers used for true code portability right now are locale.h, langinfo.h
  397 AC_CHECK_HEADERS([fcntl.h langinfo.h locale.h stdlib.h string.h sys/socket.h sys/time.h sys/wait.h unistd.h utime.h])
  398 
  399 # Headers required for plugins
  400 AC_CHECK_HEADERS(netinet/in.h, have_netinet=1, have_netinet=0)
  401 if test "$plugin_support" = "yes" -a "$have_netinet" = "0"; then
  402    plugin_support = "no"
  403 fi
  404 
  405 # jpilot-dial required headers
  406 AC_CHECK_HEADERS(termio.h, have_termio=1, have_termio=0)
  407 
  408 dnl Headers needed to build keyring
  409 AC_CHECK_HEADERS(openssl/md5.h, have_openssl_md5=1, have_openssl_md5=0)
  410 AC_CHECK_HEADERS(openssl/des.h, have_openssl_des=1, have_openssl_des=0)
  411 
  412 dnl ############################################################################
  413 dnl Check for typedefs and structures needed
  414 dnl ############################################################################
  415 dnl Checks for typedefs, structures, and compiler characteristics.
  416 AC_C_INLINE
  417 AC_TYPE_PID_T
  418 AC_TYPE_SIZE_T
  419 AC_TYPE_UID_T
  420 AC_HEADER_TIME
  421 dnl 10/2/06: This is obsolescent on most systems now as the tm struct is in time.h
  422 AC_STRUCT_TM
  423 
  424 dnl ******************************
  425 dnl Check whether nl_langinfo can provide start of week to GTK
  426 dnl ******************************
  427 
  428 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
  429 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
  430 AC_TRY_LINK([#include <langinfo.h>], [
  431 char c;
  432 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
  433 ],
  434 nl_ok=yes, nl_ok=no)
  435 AC_MSG_RESULT($nl_ok)
  436 
  437 if test "$nl_ok" = "yes"; then
  438   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
  439        [Define if _NL_TIME_FIRST_WEEKDAY is available])
  440 fi
  441 
  442 dnl ############################################################################
  443 dnl Check for individual functions needed
  444 dnl ############################################################################
  445 dnl Checks for library functions.
  446 AC_TYPE_SIGNAL
  447 AC_FUNC_STRCOLL
  448 #AC_FUNC_MALLOC
  449 #AC_FUNC_REALLOC
  450 
  451 AC_CHECK_FUNCS(setenv)
  452 
  453 AC_ARG_WITH(with_flock,
  454    AC_HELP_STRING([--with-flock],[Substitute flock instead of fnctl for file locking (for NFS)]),
  455    with_flock=yes)
  456 
  457 if test "x$with_flock" = "xyes"; then
  458    AC_CHECK_HEADERS(sys/file.h,
  459      [AC_DEFINE(USE_FLOCK, 1, [ Using flock instead of fnctl ])
  460       AC_MSG_RESULT(Using flock instead of fnctl)],
  461      [AC_MSG_FAILURE([--with-flock was given, but sys/file.h was not found])])
  462 fi
  463 
  464 dnl ############################################################################
  465 dnl Figure which programs can be built on this particular host with the
  466 dnl libraries available.
  467 dnl ############################################################################
  468 
  469 dnl * Work out which plugins to make
  470 
  471 make_keyring=no
  472 if test "$have_libgcrypt" = "1"; then
  473    make_keyring=yes
  474 fi
  475 if test "$have_libcrypto" = "1"; then
  476    if test "$have_openssl_md5" = "1" -a "$have_openssl_des" = "1"; then
  477       make_keyring=yes
  478 	  OPENSSL_LIBS=-lcrypto
  479 	  crypto_lib="OpenSSL"
  480    fi
  481 fi
  482 AC_SUBST(OPENSSL_LIBS)
  483 if test "$make_keyring" != "yes"; then
  484    AC_MSG_WARN([OpenSSL library not found, Keyring will not be built])
  485 fi
  486 
  487 keyring_plugin=no;
  488 if test "x$make_keyring" = "xyes" -a "x$plugin_support" = "xyes"; then
  489    keyring_plugin=yes;
  490 fi
  491 
  492 AM_CONDITIONAL(MAKE_KEYRING, test "x$keyring_plugin" = "xyes")
  493 AM_CONDITIONAL(MAKE_EXPENSE, test "x$plugin_support" = "xyes")
  494 AM_CONDITIONAL(MAKE_SYNCTIME, test "x$plugin_support" = "xyes")
  495 
  496 dnl * Work out whether dialer can be built
  497 
  498 dnl check operating system for jpilot-dialer
  499 dialer=no
  500 if test "$have_termio" = "1"; then
  501    case "${build_os}" in
  502       linux-gnu)     dialer=yes  ;;
  503 
  504       *) AC_MSG_WARN(
  505 		   [Operating system ${build_os} not supported by jpilot-dialer]) ;
  506 			dialer=no ;;
  507 
  508    esac
  509 fi
  510 
  511 AM_CONDITIONAL(JPILOT_DIALER, test "x$dialer" = "xyes")
  512 
  513 dnl ############################################################################
  514 dnl Miscellaneous definitions
  515 dnl ############################################################################
  516 
  517 dnl Define BASE_DIR in which is passed on to users in Jpilot help window
  518 if test "x$prefix" = "xNONE"; then
  519    AC_DEFINE_UNQUOTED(BASE_DIR, "$ac_default_prefix", [ BASE_DIR ])
  520 else
  521    AC_DEFINE_UNQUOTED(BASE_DIR, "$prefix", [ BASE_DIR ])
  522 fi
  523 
  524 dnl For Irix Systems
  525 abilib=$ABILIB
  526 if test "x$abilib" = "x"; then
  527    AC_DEFINE_UNQUOTED(ABILIB, "lib", [ ABILIB ])
  528 else
  529    AC_DEFINE_UNQUOTED(ABILIB, "$abilib", [ ABILIB ])
  530 fi
  531 AC_SUBST(ABILIB)
  532 
  533 dnl ############################################################################
  534 dnl Setup complete.  Create the specified files
  535 dnl ############################################################################
  536 AC_CONFIG_FILES([Makefile
  537                  Expense/Makefile
  538                  SyncTime/Makefile
  539                  KeyRing/Makefile
  540                  dialer/Makefile
  541                  m4/Makefile
  542                  po/Makefile.in
  543                  icons/Makefile
  544                  docs/Makefile
  545                  empty/Makefile
  546                  jpilot.spec
  547                  SlackBuild ])
  548 
  549 AC_OUTPUT
  550 
  551 dnl Make SlackBuild executable
  552 chmod +x SlackBuild
  553 
  554 dnl ******************************
  555 dnl Configuration messages
  556 dnl ******************************
  557 AC_MSG_RESULT()
  558 AC_MSG_RESULT(This package is configured for the following features:)
  559 AC_MSG_RESULT(------------------------------------------------------)
  560 AC_MSG_RESULT(Compiling with plugin support..........   $enable_plugins)
  561 AC_MSG_RESULT(Compiling with private record support..   $enable_private)
  562 AC_MSG_RESULT(Compiling with Datebk support..........   $enable_datebk)
  563 AC_MSG_RESULT(Compiling with Manana support..........   $enable_manana)
  564 AC_MSG_RESULT(Compiling with Prometheon support......   $enable_prometheon)
  565 AC_MSG_RESULT(Compiling Expense plugin...............   $plugin_support)
  566 AC_MSG_RESULT(Compiling SyncTime plugin..............   $plugin_support)
  567 AC_MSG_RESULT(Compiling KeyRing plugin...............   $keyring_plugin)
  568 AC_MSG_RESULT(Compiling dialer add-on................   $dialer)
  569 AC_MSG_RESULT(Cryptographic library..................   $crypto_lib)
  570 AC_MSG_RESULT(GTK-3 support..........................   yes)
  571 AC_MSG_RESULT(Stock buttons (icons on buttons in GUI)   $enable_stock_buttons)
  572 AC_MSG_RESULT(NLS support (foreign languages)........   $USE_NLS)
  573 AC_MSG_RESULT(Compiler Options.......................   $CFLAGS)
  574 AC_MSG_RESULT(Prefix directory.......................   $prefix)
  575 AC_MSG_RESULT(pilot-link headers.....................   $pilot_incl)
  576 AC_MSG_RESULT(USB support enabled....................   yes)
  577 AC_MSG_RESULT(pilot-link version found...............   $pl_version.$pl_major.$pl_minor$pl_patch)
  578 AC_MSG_RESULT()
  579 AC_MSG_RESULT(Now type make to compile)
  580 AC_MSG_RESULT()
  581