"Fossies" - the Fresh Open Source Software Archive

Member "mod_auth_gssapi-1.6.3/configure.ac" (14 May 2020, 4629 Bytes) of package /linux/www/apache_httpd_modules/mod_auth_gssapi-1.6.3.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the last Fossies "Diffs" side-by-side code changes report for "configure.ac": 1.6.1_vs_1.6.2.

    1 AC_PREREQ([2.69])
    2 m4_include([version.m4])
    3 AC_INIT([mod_auth_gssapi],[VERSION_NUMBER],[simo@redhat.com])
    4 AC_CONFIG_SRCDIR([src/mod_auth_gssapi.c])
    5 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects tar-pax])
    6 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
    7 AC_CONFIG_MACRO_DIR([m4])
    8 AC_CONFIG_HEADERS([src/config.h])
    9 
   10 # Checks for programs.
   11 AC_PROG_CC_STDC
   12 
   13 AC_CHECK_PROG(PKG_CONFIG_CHECK,pkg-config,yes)
   14 if test x$PKG_CONFIG_CHECK != xyes; then
   15 	AC_MSG_ERROR([Cannot find pkg-config. Please install pkg-config.])
   16 fi
   17 
   18 AC_PROG_YACC
   19 AC_CHECK_PROG(YACC_CHECK,$YACC,yes)
   20 if test x"$YACC_CHECK" != x"yes"; then
   21 	AC_MSG_ERROR([Cannot find a yacc-compatible parser generator. Please install bison, byacc, or yacc.])
   22 fi
   23 AC_PROG_LEX
   24 AC_CHECK_PROG(LEX_CHECK,$LEX,yes)
   25 if test x"$LEX_CHECK" != x"yes"; then
   26 	AC_MSG_ERROR([Cannot find a lex-compatible lexer. Please install lex, or flex.])
   27 fi
   28 AC_DECL_YYTEXT
   29 
   30 LT_INIT
   31 AC_SUBST(INCLTDL)
   32 AC_SUBST(LIBLTDL)
   33 
   34 AM_CONDITIONAL([HAVE_GCC], [test "$ac_cv_c_compiler_gnu" = yes])
   35 
   36 AC_CHECK_HEADERS([stdint.h])
   37 
   38 # Checks for typedefs, structures, and compiler characteristics.
   39 AC_CHECK_HEADER_STDBOOL
   40 AC_TYPE_SIZE_T
   41 AC_TYPE_UINT32_T
   42 
   43 # Checks for library functions.
   44 AC_CHECK_FUNCS([strcasecmp])
   45 
   46 AC_PATH_PROGS(APACHE, [apache2 httpd apache])
   47 if test x"$APACHE" == x; then
   48 	AC_MSG_ERROR([Can't find the apache2/httpd executable!])
   49 fi
   50 chk="$(objdump -d "$APACHE" | grep ap_log_rdata)"
   51 if test x"$chk" != x; then
   52 	AC_DEFINE([HAVE_AP_LOG_RDATA], [1], [ap_log_rdata() is present])
   53 else
   54 	AC_MSG_WARN([Apache/httpd is missing ap_log_rdata; some logging will be disabled])
   55 fi
   56 
   57 AC_ARG_WITH([installpath],
   58             [AS_HELP_STRING([--with-installpath=PATH],
   59                             [alternative install path])],
   60             [AC_SUBST(INSTALLPATH, $with_installpath)])
   61 
   62 AC_ARG_WITH([apxs],
   63             [AS_HELP_STRING([--with-apxs=PATH/NAME],[path to the apxs binary [[apxs]]])],
   64             [AC_SUBST(APXS, $with_apxs)],
   65             [AC_PATH_PROGS(APXS, [apxs2 apxs])])
   66 
   67 AS_IF([test "x${APXS}" != "x" -a -x "${APXS}"],
   68       [AC_MSG_NOTICE([apxs found at $APXS])
   69        AS_IF([test "x${INSTALLPATH}" != "x"],
   70        [AC_MSG_NOTICE([installpath set at $INSTALLPATH])
   71         APXS_LIBEXECDIR=`echo ${INSTALLPATH}`],
   72         [APXS_LIBEXECDIR=`${APXS} -q LIBEXECDIR`])
   73        AC_SUBST(APXS_LIBEXECDIR)],
   74       [AC_MSG_FAILURE(["apxs not found. Use --with-apxs"])])
   75 
   76 AC_ARG_WITH([apr],
   77             [AS_HELP_STRING([--with-apr=PATH/NAME],[path to the apr binary [[apr]]])],
   78             [AC_SUBST(APR, $with_apr)],
   79             [AC_PATH_PROGS(APR, [apr-1-config])])
   80 AS_IF([test "x${APR}" != "x" -a -x "${APR}"],
   81       [AC_MSG_NOTICE([apr found at $APR])
   82        APR_CPPFLAGS=`${APR} --cppflags`
   83        AC_SUBST(APR_CPPFLAGS)
   84        APR_INCLUDES=`${APR} --includes`
   85        AC_SUBST(APR_INCLUDES)
   86        APR_LDFLAGS=`${APR} --link-libtool --libs`
   87        AC_SUBST(APR_LDFLAGS)],
   88       [AC_MSG_FAILURE(["apr-1-config not found. Use --with-apr"])])
   89 
   90 # OpenSSL availability and presence of specific functions
   91 PKG_CHECK_MODULES([OPENSSL], [openssl])
   92 AC_SUBST([OPENSSL_CFLAGS])
   93 AC_SUBST([OPENSSL_LIBS])
   94 save_LIBS=$LIBS
   95 LIBS="$LIBS $OPENSSL_LIBS"
   96 AC_CHECK_FUNCS(EVP_CIPHER_CTX_new HMAC_CTX_new)
   97 LIBS=$save_LIBS
   98 
   99 # GSSAPI availability and presence of specific functions
  100 AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_ext.h gssapi/gssapi_krb5.h],
  101                  ,[AC_MSG_ERROR([Could not find GSSAPI headers])])
  102 AC_CHECK_HEADERS([gssapi/gssapi_ntlmssp.h])
  103 AC_PATH_PROG(KRB5_CONFIG, krb5-config, failed)
  104 if test x$KRB5_CONFIG = xfailed; then
  105     AC_MSG_ERROR([Could not find GSSAPI development libraries])
  106 else
  107     GSSAPI_CFLAGS="`$KRB5_CONFIG --cflags gssapi`"
  108     GSSAPI_LIBS="`$KRB5_CONFIG --libs gssapi`"
  109 fi
  110 AC_CHECK_LIB([gssapi_krb5], [gss_accept_sec_context], [],
  111              [AC_MSG_ERROR([GSSAPI library check failed])])
  112 AC_CHECK_FUNCS(gss_krb5_ccache_name, [],
  113                [AC_MSG_ERROR([gss_krb5_ccache_name() not found])])
  114 AC_CHECK_FUNCS(gss_acquire_cred_with_password, [],
  115                [AC_MSG_ERROR([gss_acquire_with_password() not found])])
  116 AC_CHECK_FUNCS(gss_acquire_cred_from)
  117 AC_CHECK_FUNCS(gss_store_cred_into)
  118 
  119 AC_SUBST([GSSAPI_CFLAGS])
  120 AC_SUBST([GSSAPI_LIBS])
  121 
  122 MAG_CFLAGS="`${APXS} -q CFLAGS` `${APXS} -q EXTRA_CPPFLAGS` `${APR} --cflags` ${GSSAPI_CFLAGS} ${OPENSSL_CFLAGS} -I`${APXS} -q INCLUDEDIR` `${APR} --includes` -fPIC"
  123 MAG_LIBS="`${APR} --libs` ${GSSAPI_LIBS} ${OPENSSL_LIBS}"
  124 LIBTOOL="`${APXS} -q LIBTOOL`"
  125 
  126 AC_SUBST([MAG_CFLAGS])
  127 AC_SUBST([MAG_LIBS])
  128 AC_SUBST([LIBTOOL])
  129 
  130 AC_CONFIG_FILES([Makefile src/Makefile src/asn1c/Makefile tests/Makefile
  131                  contrib/mod_auth_gssapi.spec])
  132 
  133 AC_OUTPUT