"Fossies" - the Fresh Open Source Software Archive

Member "scalpel-2.0/tre-0.7.5-win32/m4/ac_libtool_tags.m4" (20 Apr 2011, 1661 Bytes) of archive /linux/misc/scalpel-2.0.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file.

    1 # backported from libtool 1.6 by Paolo Bonzini
    2 # When AC_LIBTOOL_TAGS is used, I redefine _LT_AC_TAGCONFIG
    3 # to be more similar to the libtool 1.6 implementation, which
    4 # uses an m4 loop and m4 case instead of a shell loop.  This
    5 # way the CXX/GCJ/F77/RC tests are not always expanded.
    6 
    7 # AC_LIBTOOL_TAGS
    8 # ---------------
    9 # tags to enable
   10 AC_DEFUN([AC_LIBTOOL_TAGS],
   11 [m4_define([_LT_TAGS],[$1])
   12 m4_define([_LT_AC_TAGCONFIG], [
   13   if test -f "$ltmain"; then
   14     if test ! -f "${ofile}"; then
   15       AC_MSG_WARN([output file `$ofile' does not exist])
   16     fi
   17 
   18     if test -z "$LTCC"; then
   19       eval "`$SHELL ${ofile} --config | grep '^LTCC='`"
   20       if test -z "$LTCC"; then
   21         AC_MSG_WARN([output file `$ofile' does not look like a libtool script])
   22       else
   23         AC_MSG_WARN([using `LTCC=$LTCC', extracted from `$ofile'])
   24       fi
   25     fi
   26 
   27     AC_FOREACH([_LT_TAG], _LT_TAGS,
   28       [m4_case(_LT_TAG,
   29       [CXX], [
   30     if test -n "$CXX" && test "X$CXX" != "Xno"; then
   31       AC_LIBTOOL_LANG_CXX_CONFIG
   32       available_tags="$available_tags _LT_TAG"
   33     fi],
   34       [F77], [
   35     if test -n "$F77" && test "X$F77" != "Xno"; then
   36       AC_LIBTOOL_LANG_F77_CONFIG
   37       available_tags="$available_tags _LT_TAG"
   38     fi],
   39       [GCJ], [
   40     if test -n "$GCJ" && test "X$GCJ" != "Xno"; then
   41       AC_LIBTOOL_LANG_GCJ_CONFIG
   42       available_tags="$available_tags _LT_TAG"
   43     fi],
   44       [RC], [
   45     if test -n "$RC" && test "X$RC" != "Xno"; then
   46       AC_LIBTOOL_LANG_RC_CONFIG
   47       available_tags="$available_tags _LT_TAG"
   48     fi],
   49       [m4_errprintn(m4_location[: error: invalid tag name: ]"_LT_TAG")
   50       m4_exit(1)])
   51     ])
   52   fi
   53 
   54 ])dnl _LT_AC_TAG_CONFIG
   55 ])