"Fossies" - the Fresh Open Source Software Archive

Member "qt-creator-opensource-src-4.15.1/tests/unit/unittest/unittest.pro" (8 Jun 2021, 10422 Bytes) of package /linux/misc/qt-creator-opensource-src-4.15.1.tar.xz:


As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) Prolog source code syntax highlighting (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "unittest.pro": opensource-src-4.15.0_vs_opensource-src-4.15.1.

    1 INCLUDEPATH += ../mockup
    2 INCLUDEPATH += ../mockup/qmldesigner/designercore/include
    3 
    4 QT += core network testlib widgets
    5 CONFIG += console c++17 testcase
    6 CONFIG -= app_bundle shared
    7 
    8 QTC_UNITTEST_BUILD_CPP_PARSER = $$(QTC_UNITTEST_BUILD_CPP_PARSER)
    9 
   10 include(gmock_dependency.pri)
   11 include(clang_dependency.pri)
   12 include(creator_dependency.pri)
   13 include(benchmark_dependency.pri)
   14 
   15 requires(isEmpty(QTC_CLANG_BUILDMODE_MISMATCH))
   16 
   17 !msvc:force_debug_info:QMAKE_CXXFLAGS += -fno-omit-frame-pointer
   18 
   19 DEFINES += \
   20     QT_NO_CAST_TO_ASCII \
   21     QT_RESTRICTED_CAST_FROM_ASCII \
   22     QT_USE_QSTRINGBUILDER \
   23     UNIT_TESTS \
   24     DONT_CHECK_MESSAGE_COUNTER \
   25     QTC_RESOURCE_DIR=\"R\\\"xxx($$PWD/../../../share/qtcreator)xxx\\\"\" \
   26     TESTDATA_DIR=\"R\\\"xxx($$PWD/data)xxx\\\"\"
   27 msvc: QMAKE_CXXFLAGS_WARN_ON -= -w34100 # 'unreferenced formal parameter' in MATCHER_* functions
   28 win32:DEFINES += ECHOSERVER=\"R\\\"xxx($$OUT_PWD/../echo)xxx\\\"\"
   29 unix: DEFINES += ECHOSERVER=\"R\\\"xxx($$OUT_PWD/../echoserver/echo)xxx\\\"\"
   30 
   31 RELATIVE_DATA_PATH = ../../../share/qtcreator
   32 DEFINES += $$shell_quote(RELATIVE_DATA_PATH=\"$$RELATIVE_DATA_PATH\")
   33 
   34 linux {
   35 QMAKE_LFLAGS_RELEASE = #disable optimization
   36 QMAKE_LFLAGS += -fno-merge-debug-strings -fuse-ld=gold
   37 CONFIG(release, debug|release):QMAKE_LFLAGS += -Wl,--strip-debug
   38 }
   39 
   40 CONFIG(debug, debug|release): DEFINES += SQLITE_DEBUG
   41 
   42 
   43 gcc:!clang: QMAKE_CXXFLAGS += -Wno-noexcept-type
   44 msvc{
   45 QMAKE_CXXFLAGS += /bigobj /wd4267 /wd4141 /wd4146 /wd4624
   46 QMAKE_LFLAGS += /INCREMENTAL
   47 
   48 }
   49 # create fake CppTools.json for the mime type definitions
   50 dependencyList = "\"Dependencies\" : []"
   51 cpptoolsjson.input = $$PWD/../../../src/plugins/cpptools/CppTools.json.in
   52 cpptoolsjson.output = $$OUT_PWD/CppTools.json
   53 QMAKE_SUBSTITUTES += cpptoolsjson
   54 DEFINES += CPPTOOLS_JSON=\"R\\\"xxx($${cpptoolsjson.output})xxx\\\"\"
   55 
   56 SOURCES += \
   57     clangindexingsettingsmanager-test.cpp \
   58     clangpathwatcher-test.cpp \
   59     clangqueryexamplehighlightmarker-test.cpp \
   60     clangqueryhighlightmarker-test.cpp \
   61     clientserverinprocess-test.cpp \
   62     clientserveroutsideprocess-test.cpp \
   63     cppprojectfilecategorizer-test.cpp \
   64     cppprojectinfogenerator-test.cpp \
   65     cppprojectpartchooser-test.cpp \
   66     directorypathcompressor-test.cpp \
   67     fakeprocess.cpp \
   68     filepath-test.cpp \
   69     filepathview-test.cpp \
   70     gtest-creator-printing.cpp \
   71     gtest-qt-printing.cpp \
   72     asynchronousimagecache-test.cpp \
   73     synchronousimagecache-test.cpp \
   74     imagecachegenerator-test.cpp \
   75     imagecachestorage-test.cpp \
   76     lastchangedrowid-test.cpp \
   77     lineprefixer-test.cpp \
   78     listmodeleditor-test.cpp \
   79     locatorfilter-test.cpp \
   80     mimedatabase-utilities.cpp \
   81     pchmanagerclientserverinprocess-test.cpp \
   82     pchmanagerclient-test.cpp \
   83     pchmanagerserver-test.cpp \
   84     preprocessormacrocollector-test.cpp \
   85     processevents-utilities.cpp \
   86     projectpartsmanager-test.cpp \
   87     projectpartsstorage-test.cpp \
   88     projectupdater-test.cpp \
   89     readandwritemessageblock-test.cpp \
   90     sizedarray-test.cpp \
   91     smallstring-test.cpp \
   92     sourcerangefilter-test.cpp \
   93     spydummy.cpp \
   94     sqlitesessions-test.cpp \
   95     sqlitevalue-test.cpp \
   96     symbolindexer-test.cpp \
   97     symbolsfindfilter-test.cpp \
   98     stringcache-test.cpp \
   99     eventspy.cpp \
  100     unittests-main.cpp \
  101     utf8-test.cpp \
  102     symbolstorage-test.cpp \
  103     symbolquery-test.cpp \
  104     sqliteindex-test.cpp \
  105     sqlitetransaction-test.cpp \
  106     refactoringdatabaseinitializer-test.cpp \
  107     filepathcache-test.cpp \
  108     filepathstorage-test.cpp \
  109     filepathstoragesqlitestatementfactory-test.cpp \
  110     processcreator-test.cpp \
  111     nativefilepath-test.cpp \
  112     nativefilepathview-test.cpp \
  113     mocktimer.cpp \
  114     projectpartartefact-test.cpp \
  115     filestatuscache-test.cpp \
  116     precompiledheaderstorage-test.cpp \
  117     generatedfiles-test.cpp \
  118     sourcesmanager-test.cpp \
  119     symbolindexertaskqueue-test.cpp \
  120     refactoringprojectupdater-test.cpp \
  121     processormanager-test.cpp \
  122     task.cpp \
  123     taskscheduler-test.cpp \
  124     compileroptionsbuilder-test.cpp \
  125     progresscounter-test.cpp \
  126     pchtaskgenerator-test.cpp \
  127     compilationdatabaseutils-test.cpp \
  128     builddependenciesprovider-test.cpp \
  129     builddependenciesstorage-test.cpp \
  130     usedmacrofilter-test.cpp \
  131     pchtasksmerger-test.cpp \
  132     pchtaskqueue-test.cpp \
  133     commandlinebuilder-test.cpp \
  134     headerpathfilter-test.cpp \
  135     toolchainargumentscache-test.cpp \
  136     modifiedtimechecker-test.cpp \
  137     sqlitecolumn-test.cpp \
  138     sqlitedatabasebackend-test.cpp \
  139     sqlitedatabase-test.cpp \
  140     sqlitestatement-test.cpp \
  141     sqlitetable-test.cpp \
  142     sqlstatementbuilder-test.cpp \
  143     createtablesqlstatementbuilder-test.cpp \
  144     sqlitereadstatementmock.cpp \
  145     sqlitewritestatementmock.cpp
  146 
  147 !isEmpty(QTC_UNITTEST_BUILD_CPP_PARSER):SOURCES += matchingtext-test.cpp
  148 
  149 !isEmpty(LIBCLANG_LIBS) {
  150 SOURCES += \
  151     chunksreportedmonitor.cpp \
  152     clangasyncjob-base.cpp \
  153     clangcodecompleteresults-test.cpp \
  154     clangcodemodelserver-test.cpp \
  155     clangcompletecodejob-test.cpp \
  156     clangdiagnosticfilter-test.cpp \
  157     clangdocumentprocessors-test.cpp \
  158     clangdocumentprocessor-test.cpp \
  159     clangdocuments-test.cpp \
  160     clangdocument-test.cpp \
  161     clangfixitoperation-test.cpp \
  162     clangfollowsymbol-test.cpp \
  163     clangisdiagnosticrelatedtolocation-test.cpp \
  164     clangjobqueue-test.cpp \
  165     clangjobs-test.cpp \
  166     clangparsesupportivetranslationunitjob-test.cpp \
  167     clangrequestannotationsjob-test.cpp \
  168     clangrequestreferencesjob-test.cpp \
  169     clangresumedocumentjob-test.cpp \
  170     clangstring-test.cpp \
  171     clangsupportivetranslationunitinitializer-test.cpp \
  172     clangsuspenddocumentjob-test.cpp \
  173     clangtooltipinfo-test.cpp \
  174     clangtranslationunits-test.cpp \
  175     clangtranslationunit-test.cpp \
  176     clangupdateannotationsjob-test.cpp \
  177     codecompleter-test.cpp \
  178     codecompletionsextractor-test.cpp \
  179     completionchunkstotextconverter-test.cpp \
  180     cursor-test.cpp \
  181     diagnosticset-test.cpp \
  182     diagnostic-test.cpp \
  183     fixit-test.cpp \
  184     gtest-clang-printing.cpp \
  185     highlightingresultreporter-test.cpp \
  186     senddocumenttracker-test.cpp \
  187     skippedsourceranges-test.cpp \
  188     sourcelocation-test.cpp \
  189     sourcerange-test.cpp \
  190     token-test.cpp \
  191     tokenprocessor-test.cpp \
  192     translationunitupdater-test.cpp \
  193     unsavedfiles-test.cpp \
  194     unsavedfile-test.cpp \
  195     utf8positionfromlinecolumn-test.cpp \
  196     clangreferencescollector-test.cpp \
  197     clangdocumentsuspenderresumer-test.cpp \
  198     readexporteddiagnostics-test.cpp
  199 
  200 !isEmpty(QTC_UNITTEST_BUILD_CPP_PARSER):SOURCE += \
  201     clangcompletioncontextanalyzer-test.cpp \
  202     activationsequencecontextprocessor-test.cpp \
  203     activationsequenceprocessor-test.cpp
  204 
  205 }
  206 
  207 !isEmpty(LIBTOOLING_LIBS) {
  208 SOURCES += \
  209     gtest-llvm-printing.cpp \
  210     clangquerygatherer-test.cpp \
  211     clangqueryprojectfindfilter-test.cpp \
  212     clangquery-test.cpp \
  213     pchcreator-test.cpp \
  214     refactoringclientserverinprocess-test.cpp \
  215     refactoringclient-test.cpp \
  216     refactoringcompilationdatabase-test.cpp \
  217     refactoringserver-test.cpp \
  218     sourcerangeextractor-test.cpp \
  219     symbolindexing-test.cpp \
  220     symbolscollector-test.cpp \
  221     testclangtool.cpp \
  222     usedmacrocollector-test.cpp \
  223     builddependencycollector-test.cpp
  224 
  225 !isEmpty(QTC_UNITTEST_BUILD_CPP_PARSER):SOURCES += refactoringengine-test.cpp
  226 
  227 }
  228 
  229 !isEmpty(CLANGFORMAT_LIBS) {
  230     SOURCES += clangformat-test.cpp
  231 }
  232 
  233 !isEmpty(GOOGLEBENCHMARK_DIR):exists($$GOOGLEBENCHMARK_DIR) {
  234 SOURCES += \
  235     smallstring-benchmark.cpp
  236 }
  237 
  238 HEADERS += \
  239     compare-operators.h \
  240     conditionally-disabled-tests.h \
  241     dummyclangipcclient.h \
  242     dynamicastmatcherdiagnosticcontainer-matcher.h \
  243     eventspy.h \
  244     fakeprocess.h \
  245     filesystem-utilities.h \
  246     googletest.h \
  247     gtest-creator-printing.h \
  248     gtest-llvm-printing.h \
  249     gtest-qt-printing.h \
  250     gtest-std-printing.h \
  251     imagecachecollectormock.h \
  252     mimedatabase-utilities.h \
  253     mockclangcodemodelclient.h \
  254     mockclangcodemodelserver.h \
  255     mockclangpathwatcher.h \
  256     mockclangpathwatchernotifier.h \
  257     mockfilesystem.h \
  258     mockimagecachegenerator.h \
  259     mockimagecachestorage.h \
  260     mocklistmodeleditorview.h \
  261     mockpchcreator.h \
  262     mockpchmanagerclient.h \
  263     mockpchmanagernotifier.h \
  264     mockpchmanagerserver.h \
  265     mockprojectpartsmanager.h \
  266     mockprojectpartsstorage.h \
  267     mockqfilesystemwatcher.h \
  268     mocksearch.h \
  269     mocksearchhandle.h \
  270     mocksearchresult.h \
  271     mocksyntaxhighligher.h \
  272     mocktimestampprovider.h \
  273     notification.h \
  274     processevents-utilities.h \
  275     sourcerangecontainer-matcher.h \
  276     spydummy.h \
  277     testenvironment.h \
  278     mocksymbolscollector.h \
  279     mocksymbolstorage.h \
  280     google-using-declarations.h \
  281     mocksymbolindexing.h \
  282     sqliteteststatement.h \
  283     mockmutex.h \
  284     mockfilepathstorage.h \
  285     mockfilepathcaching.h \
  286     mocksqlitestatement.h \
  287     unittest-utility-functions.h \
  288     mocksymbolquery.h \
  289     rundocumentparse-utility.h \
  290     mocktimer.h \
  291     mocksqlitetransactionbackend.h \
  292     mockprojectpartprovider.h \
  293     mockprecompiledheaderstorage.h \
  294     mockeditormanager.h \
  295     mocksymbolindexertaskqueue.h \
  296     mockcppmodelmanager.h \
  297     mockgeneratedfiles.h \
  298     mockqueue.h \
  299     mockprojectpartqueue.h \
  300     mockprocessor.h \
  301     mockprocessormanager.h \
  302     mocktaskscheduler.h \
  303     mockprogressmanager.h \
  304     mockfutureinterface.h \
  305     mockbuilddependenciesprovider.h \
  306     mockmodifiedtimechecker.h \
  307     mockbuilddependenciesstorage.h \
  308     mockbuilddependencygenerator.h \
  309     mockpchtasksmerger.h \
  310     mockpchtaskqueue.h \
  311     mockpchtaskgenerator.h \
  312     ../mockup/qmldesigner/designercore/include/nodeinstanceview.h \
  313     ../mockup/qmldesigner/designercore/include/rewriterview.h \
  314     ../mockup/qmldesigner/designercore/include/itemlibraryitem.h\
  315     sqlitedatabasemock.h \
  316     sqlitereadstatementmock.h \
  317     sqlitestatementmock.h \
  318     sqlitetransactionbackendmock.h \
  319     sqlitewritestatementmock.h
  320 
  321 
  322 !isEmpty(LIBCLANG_LIBS) {
  323 HEADERS += \
  324     chunksreportedmonitor.h \
  325     clangasyncjob-base.h \
  326     clangcompareoperators.h \
  327     diagnosticcontainer-matcher.h \
  328     gtest-clang-printing.h
  329 }
  330 
  331 !isEmpty(LIBTOOLING_LIBS) {
  332 HEADERS += \
  333     mockrefactoringclient.h \
  334     mockrefactoringserver.h \
  335     testclangtool.h
  336 }
  337 
  338 OTHER_FILES += $$files(data/*) $$files(data/include/*)