"Fossies" - the Fresh Open Source Software Archive

Member "mvapich2-2.3.2/osu_benchmarks/configure.ac" (8 Aug 2019, 5815 Bytes) of package /linux/misc/mvapich2-2.3.2.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "configure.ac": 2.3.1_vs_2.3.2.

    1 #                                               -*- Autoconf -*-
    2 # Process this file with autoconf to produce a configure script.
    3 
    4 AC_PREREQ([2.59])
    5 AC_INIT([OSU-Micro-Benchmarks], [5.6.2], [mvapich-discuss@cse.ohio-state.edu])
    6 AC_CONFIG_SRCDIR([mpi/pt2pt/osu_latency.c])
    7 
    8 AM_INIT_AUTOMAKE([foreign])
    9 LT_INIT
   10 
   11 AC_ARG_ENABLE([openacc],
   12               [AS_HELP_STRING([--enable-openacc],
   13                               [Enable OpenACC benchmarks])
   14               ],
   15               [],
   16               [enable_openacc=no])
   17 
   18 AC_ARG_ENABLE([cuda],
   19               [AS_HELP_STRING([--enable-cuda],
   20 			      [Enable CUDA benchmarks (default is no).  Specify
   21 			       --enable-cuda=basic to enable basic cuda support
   22 			       without using cuda kernel support for
   23 			       non-blocking collectives])
   24               ],
   25               [],
   26               [enable_cuda=no])
   27 
   28 AC_ARG_WITH([cuda],
   29             [AS_HELP_STRING([--with-cuda=@<:@CUDA installation path@:>@],
   30                             [Provide path to CUDA installation])
   31             ],
   32             [AS_CASE([$with_cuda],
   33                      [yes|no], [],
   34                      [CPPFLAGS="-I$with_cuda/include $CPPFLAGS"
   35                       LDFLAGS="-L$with_cuda/lib64 -Wl,-rpath=$with_cuda/lib64 -L$with_cuda/lib -Wl,-rpath=$with_cuda/lib $LDFLAGS"])
   36             ])
   37 
   38 AC_ARG_WITH([cuda-include],
   39             [AS_HELP_STRING([--with-cuda-include=@<:@CUDA include path@:>@],
   40                             [Provide path to CUDA include files])
   41             ],
   42             [AS_CASE([$with_cuda_include],
   43                      [yes|no], [],
   44                      [CPPFLAGS="-I$with_cuda_include $CPPFLAGS"])
   45             ])
   46 
   47 AC_ARG_WITH([cuda-libpath],
   48             [AS_HELP_STRING([--with-cuda-libpath=@<:@CUDA library path@:>@],
   49                             [Provide path to CUDA library files])
   50             ],
   51             [AS_CASE([$with_cuda_libpath],
   52                      [yes|no], [],
   53                      [LDFLAGS="-L$with_cuda_libpath -Wl,-rpath=$with_cuda_libpath $LDFLAGS"])
   54             ])
   55 
   56 # Checks for programs.
   57 AC_PROG_CC([mpicc oshcc upcc upc++])
   58 
   59 # Checks for mpicxx used for compiling kernel.cu in nbc benchmarks and/or the
   60 # upc++ compiler for upcxx benchmarks
   61 AC_PROG_CXX([mpicxx upc++])
   62 
   63 # Checks for libraries.
   64 AC_SEARCH_LIBS([sqrt], [m])
   65 AC_SEARCH_LIBS([pthread_join], [pthread])
   66 AC_SEARCH_LIBS([clock_gettime], [rt])
   67 
   68 # Checks for header files.
   69 AC_CHECK_HEADERS([stdlib.h string.h sys/time.h unistd.h])
   70 
   71 # Checks for typedefs, structures, and compiler characteristics.
   72 AC_C_INLINE
   73 
   74 # Checks for library functions.
   75 AC_CHECK_FUNCS([getpagesize gettimeofday memset sqrt])
   76 
   77 AS_IF([test "x$enable_embedded" = xyes], [
   78        AS_IF([test x"$enable_mpi3" = xyes], [mpi3_library=true])
   79        AS_IF([test x"$enable_mpi2" = xyes], [mpi2_library=true])
   80        AS_IF([test x"$enable_mpi" = xyes], [mpi_library=true])
   81        AS_IF([test x"$enable_oshm" = xyes], [oshm_library=true])
   82        AS_IF([test x"$enable_upc" = xyes], [upc_compiler=true])
   83        AS_IF([test x"$enable_upcxx" = xyes], [upcxx_compiler=true])
   84        AS_IF([test x"$enable_oshm_13" = xyes], [oshm_13_library=true])
   85       ], [
   86        AC_CHECK_FUNC([MPI_Init], [mpi_library=true])
   87        AC_CHECK_FUNC([MPI_Accumulate], [mpi2_library=true])
   88        AC_CHECK_FUNC([MPI_Get_accumulate], [mpi3_library=true])
   89        AC_CHECK_FUNC([shmem_barrier_all], [oshm_library=true])
   90        AC_CHECK_FUNC([upc_memput], [upc_compiler=true])
   91        AC_CHECK_DECL([upcxx_alltoall], [upcxx_compiler=true], [],
   92                      [#include <upcxx.h>])
   93        AC_CHECK_FUNC([shmem_finalize], [oshm_13_library=true])
   94       ])
   95 
   96 AM_CONDITIONAL([EMBEDDED_BUILD], [test x"$enable_embedded" = xyes])
   97 AM_CONDITIONAL([BUILD_PROFILING_LIB], [test x"$with_plib" = xyes])
   98 AC_SUBST([PMPILIBNAME], [$PMILIBNAME])
   99 AC_SUBST([MPILIBNAME], [$MPILIBNAME])
  100 
  101 AS_IF([test "x$enable_openacc" = xyes], [
  102        AC_CHECK_HEADERS([openacc.h], [],
  103                         [AC_MSG_ERROR([cannot include openacc.h])])
  104        AC_DEFINE([_ENABLE_OPENACC_], [1], [Enable OpenACC])
  105        ])
  106 
  107 AS_CASE([$enable_cuda],
  108         [yes], [build_cuda_kernels=yes; build_cuda=yes],
  109         [basic], [build_cuda=yes])
  110 
  111 AS_IF([test "x$build_cuda" = xyes], [
  112        AC_SEARCH_LIBS([cuPointerGetAttribute], [cuda], [],
  113                       [AC_MSG_ERROR([cannot link with -lcuda])])
  114        AC_SEARCH_LIBS([cudaFree], [cudart], [],
  115                       [AC_MSG_ERROR([cannot link with -lcudart])])
  116        AC_CHECK_HEADERS([cuda.h], [],
  117                         [AC_MSG_ERROR([cannot include cuda.h])])
  118        AC_DEFINE([_ENABLE_CUDA_], [1], [Enable CUDA])
  119        ])
  120 
  121 AS_IF([test "x$build_cuda_kernels" = xyes], [
  122        AC_DEFINE([_ENABLE_CUDA_KERNEL_], [1], [Enable CUDA Kernel])
  123        ])
  124 
  125 AS_IF([test "x$oshm_13_library" = xtrue], [
  126        AC_DEFINE([OSHM_1_3], [1], [Enable OpenSHMEM 1.3 features])
  127        ])
  128 AM_CONDITIONAL([MPI2_LIBRARY], [test x$mpi2_library = xtrue])
  129 AM_CONDITIONAL([MPI3_LIBRARY], [test x$mpi3_library = xtrue])
  130 AM_CONDITIONAL([CUDA], [test x$build_cuda = xyes])
  131 AM_CONDITIONAL([CUDA_KERNELS], [test x$build_cuda_kernels = xyes])
  132 AM_CONDITIONAL([OPENACC], [test x$enable_openacc = xyes])
  133 AM_CONDITIONAL([OSHM], [test x$oshm_library = xtrue])
  134 AM_CONDITIONAL([MPI], [test x$mpi_library = xtrue])
  135 AM_CONDITIONAL([UPC], [test x$upc_compiler = xtrue])
  136 AM_CONDITIONAL([UPCXX], [test x$upcxx_compiler = xtrue])
  137 AM_CONDITIONAL([BUILD_USE_PGI], [`$CXX -V 2>&1 | grep pgc++ > /dev/null 2>&1`])
  138 
  139 AC_DEFINE([FIELD_WIDTH], [18], [Width of field used to report numbers])
  140 AC_DEFINE([FLOAT_PRECISION], [2], [Precision of reported numbers])
  141 
  142 AC_CONFIG_FILES([Makefile mpi/Makefile mpi/pt2pt/Makefile mpi/startup/Makefile
  143                  mpi/one-sided/Makefile mpi/collective/Makefile
  144                  openshmem/Makefile upc/Makefile upcxx/Makefile])
  145 AC_OUTPUT