"Fossies" - the Fresh Open Source Software Archive

Member "motion-Release-4.3.0/configure.ac" (14 Jan 2020, 17448 Bytes) of package /linux/misc/motion-Release-4.3.0.tar.gz:


As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) C and C++ source code syntax highlighting (style: standard) with prefixed line numbers and code folding option. Alternatively you can here view or download the uninterpreted source code file.

    1 AC_INIT(motion, esyscmd(['./scripts/version.sh']))
    2 AM_INIT_AUTOMAKE([subdir-objects foreign])
    3 AC_PROG_CC
    4 AC_PROG_CXX
    5 AC_GNU_SOURCE
    6 AC_CONFIG_HEADERS([config.h])
    7 AC_CONFIG_SRCDIR([src/motion.c])
    8 AC_CANONICAL_HOST
    9 AC_CONFIG_MACRO_DIR([m4])
   10 
   11 AM_GNU_GETTEXT([external])
   12 AM_GNU_GETTEXT_VERSION([0.19])
   13 
   14 ##############################################################################
   15 ###  Check additional system headers
   16 ##############################################################################
   17 AC_CHECK_HEADERS(stdio.h stdlib.h sys/time.h sys/wait.h \
   18     sys/ioctl.h sys/mman.h sys/param.h sys/socket.h stdarg.h \
   19     fcntl.h time.h signal.h limits.h errno.h assert.h netdb.h \
   20     ctype.h regex.h math.h locale.h dirent.h ctype.h \
   21     arpa/inet.h netinet/in.h termios.h,,[
   22     AC_MSG_ERROR([Required system headers do not exist.])
   23   ]
   24 )
   25 
   26 ##############################################################################
   27 ###  Check pkg-config  - Required.  Needed to get lib paths/info
   28 ##############################################################################
   29 AC_CHECK_PROG([PKGCONFIG],[pkg-config],[yes],[no])
   30 AS_IF([test "${PKGCONFIG}" = "no" ],[
   31     AC_MSG_ERROR([Required package 'pkg-config' not found, please check motion_guide.html and install necessary dependencies.])
   32   ]
   33 )
   34 
   35 ##############################################################################
   36 ###  Check pthread
   37 ##############################################################################
   38 AC_CHECK_HEADERS(pthread.h,,AC_MSG_ERROR([pthread is required.]))
   39 CFLAGS="${CFLAGS} -D_THREAD_SAFE "
   40 LIBS="$LIBS -pthread "
   41 
   42 ##############################################################################
   43 ###  Check JPG - Required.  Needed for image processing
   44 ##############################################################################
   45 AC_CHECK_HEADERS(setjmp.h jerror.h jpeglib.h,[JPGS="yes"],[JPGS="no"])
   46 AC_MSG_CHECKING(jpg libraries)
   47 AC_MSG_RESULT($JPGS)
   48 AS_IF([test "${JPGS}" = "yes" ], [
   49     AS_IF([pkg-config libjpeg ], [
   50         TEMP_CFLAGS="$TEMP_CFLAGS "`pkg-config --cflags libjpeg`
   51         TEMP_LIBS="$TEMP_LIBS "`pkg-config --libs libjpeg`
   52       ],[
   53         TEMP_LIBS="$TEMP_LIBS -ljpeg"
   54       ]
   55     )
   56   ],[
   57     AC_MSG_ERROR([Required package libjpeg-dev not found, please check motion_guide.html and install necessary dependencies])
   58   ]
   59 )
   60 ##############################################################################
   61 ###  Check libmicrohttpd - Required.  Needed for stream/webcontrol
   62 ##############################################################################
   63 AC_CHECK_HEADERS(microhttpd.h,[MHTTP="yes"],[MHTTP="no"])
   64 AC_MSG_CHECKING(libmicrohttpd libraries)
   65 AC_MSG_RESULT($MHTTP)
   66 AS_IF([test "${MHTTP}" = "yes" ], [
   67     TEMP_CFLAGS="$TEMP_CFLAGS "`pkg-config --cflags libmicrohttpd`
   68     TEMP_LIBS="$TEMP_LIBS "`pkg-config --libs libmicrohttpd`
   69   ],[
   70     AC_MSG_ERROR([Required package libmicrohttpd-dev not found, please check motion_guide.html and install necessary dependencies])
   71   ]
   72 )
   73 
   74 ##############################################################################
   75 ###  Check setting/getting thread names
   76 ##############################################################################
   77 AC_CHECK_HEADERS(pthread_np.h,[PTHREAD_NP="yes"],[PTHREAD_NP="no"])
   78 
   79 AC_MSG_CHECKING([for pthread_setname_np])
   80 AC_LINK_IFELSE(
   81   [AC_LANG_PROGRAM([#include <pthread.h>], [pthread_setname_np(pthread_self(), "name")])
   82   ],[
   83     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define if you have pthread_setname_np function.])
   84     PTHREAD_SETNAME_NP="yes"
   85     AC_MSG_RESULT([yes])
   86   ],[
   87     PTHREAD_SETNAME_NP="no"
   88     AC_MSG_RESULT([no])
   89   ]
   90 )
   91 
   92 AC_MSG_CHECKING([for pthread_getname_np])
   93 AC_LINK_IFELSE(
   94   [AC_LANG_PROGRAM([#include <pthread.h>], [pthread_getname_np(pthread_self(), NULL, 0)])
   95   ],[
   96     AC_DEFINE([HAVE_PTHREAD_GETNAME_NP], [1], [Define if you have pthread_getname_np function.])
   97     PTHREAD_GETNAME_NP="yes"
   98     AC_MSG_RESULT([yes])
   99   ],[
  100     PTHREAD_GETNAME_NP="no"
  101     AC_MSG_RESULT([no])
  102   ]
  103 )
  104 
  105 ##############################################################################
  106 ###  Check XSI strerror_r.  Check for Linux/*BSD/Apple/MUSL variations
  107 ##############################################################################
  108 AC_MSG_CHECKING([for XSI strerror_r])
  109 HOLD_CFLAGS="$CFLAGS"
  110 CFLAGS="$CFLAGS -Werror"
  111 AC_LINK_IFELSE(
  112   [AC_LANG_SOURCE[
  113     #include <string.h>
  114     #include <errno.h>
  115     int main(int argc, char** argv) {
  116       char buf[1024];
  117       int ret = strerror_r(ENOMEM, buf, sizeof(buf));
  118       return ret;
  119     }]
  120   ],[
  121     AC_DEFINE([XSI_STRERROR_R], [1], [Define if you have XSI strerror_r function.])
  122     XSI_STRERROR="yes"
  123     AC_MSG_RESULT([yes])
  124   ],[
  125     XSI_STRERROR="no"
  126     AC_MSG_RESULT([no])
  127   ]
  128 )
  129 CFLAGS="$HOLD_CFLAGS"
  130 
  131 ###############################################################################
  132 ###  BKTR Video System - Optional
  133 ###############################################################################
  134 AC_ARG_WITH(bktr,
  135   AS_HELP_STRING([--without-bktr],[Disable bktr devices]),
  136   [BKTR="$withval"],
  137   [BKTR="yes"]
  138 )
  139 AS_IF([test "${BKTR}" = "yes" ], [
  140     AC_CHECK_HEADERS(dev/bktr/ioctl_meteor.h dev/bktr/ioctl_bt848.h,[BKTR="yes"],[BKTR="no"])
  141     AS_IF([test "${BKTR}" = "no" ], [
  142         AC_CHECK_HEADERS(dev/ic/bt8xx.h,[BKTR="yes"],[BKTR="no"])
  143       ]
  144     )
  145     AS_IF([test "${BKTR}" = "yes" ], [
  146         AC_DEFINE([HAVE_BKTR], [1], [Define to 1 if BKTR is around])
  147       ]
  148     )
  149   ]
  150 )
  151 
  152 ###############################################################################
  153 ###  V4L2 Video System - Optional
  154 ###############################################################################
  155 AC_ARG_WITH(v4l2,
  156   AS_HELP_STRING([--without-v4l2],[Disable V4L2 devices]),
  157   [V4L2="$withval"],
  158   [V4L2="yes"]
  159 )
  160 AS_IF([test "${V4L2}" = "yes" ], [
  161   AC_CHECK_HEADERS(linux/videodev2.h sys/videoio.h,[V4L2="yes";break],[V4L2="no"])
  162     AS_IF([test "${V4L2}" = "yes" ], [
  163         AC_DEFINE([HAVE_V4L2], [1], [Define to 1 if V4L2 is around])
  164       ]
  165     )
  166   ]
  167 )
  168 
  169 ##############################################################################
  170 ###  Webp Image Format - Optional.
  171 ##############################################################################
  172 AC_ARG_WITH([webp],
  173   AS_HELP_STRING([--with-webp],[Compile with Webp image support]),
  174   [WEBP="$withval"],
  175   [WEBP="yes]"
  176 )
  177 
  178 AS_IF([test "${WEBP}" = "yes" ], [
  179     AC_MSG_CHECKING(for webp)
  180     AS_IF([pkg-config libwebpmux ], [
  181         AC_MSG_RESULT(yes)
  182         AC_DEFINE([HAVE_WEBP], [1], [Define to 1 if WEBP is around])
  183         TEMP_CFLAGS="$TEMP_CFLAGS "`pkg-config --cflags libwebpmux`
  184         TEMP_LIBS="$TEMP_LIBS "`pkg-config --libs libwebpmux`
  185       ],[
  186         AC_MSG_RESULT(no)
  187       ]
  188     )
  189   ]
  190 )
  191 
  192 ##############################################################################
  193 ###  raspberry pi mmal - Optional.
  194 ##############################################################################
  195 AC_ARG_WITH([mmal],
  196   AS_HELP_STRING([--with-mmal[=DIR]],[Compile with RasperryPi mmal camera support]),
  197   [MMAL="$withval"],
  198   [MMAL="yes"]
  199 )
  200 
  201 AS_IF([test "${MMAL}" = "no"], [
  202     AC_MSG_CHECKING(for MMAL)
  203     AC_MSG_RESULT(skipped)
  204   ],[
  205     AC_MSG_CHECKING(MMAL pkg-config path)
  206     TEMP_PATH=$PKG_CONFIG_PATH
  207     AS_IF([test "${MMAL}" != "yes"], [
  208         PKG_CONFIG_PATH=${MMAL}/lib/pkgconfig:$PKG_CONFIG_PATH
  209         MMAL="yes"
  210       ],[
  211         PKG_CONFIG_PATH=.:/opt/vc/lib/pkgconfig
  212       ]
  213     )
  214     export PKG_CONFIG_PATH
  215     AC_MSG_RESULT($PKG_CONFIG_PATH)
  216 
  217     AC_MSG_CHECKING(for MMAL)
  218     AS_IF([pkg-config mmal], [
  219         TEMP_CFLAGS="$TEMP_CFLAGS -Irasppicam "`pkg-config --cflags mmal`
  220         TEMP_LIBS="$TEMP_LIBS "`pkg-config --libs mmal`
  221         #pkg config parm does not provide -lvchostif that buildroot requires
  222         TEMP_LIBS="$TEMP_LIBS -lvchostif "
  223         AC_MSG_RESULT([yes])
  224         AC_DEFINE([HAVE_MMAL], [1], [Define to 1 if MMAL is around])
  225       ],[
  226         AC_MSG_RESULT([no])
  227         MMAL="no"
  228       ]
  229     )
  230     PKG_CONFIG_PATH=$TEMP_PATH
  231     export PKG_CONFIG_PATH
  232   ]
  233 )
  234 AM_CONDITIONAL([INC_MMAL_SRC],[test x${MMAL} = xyes])
  235 
  236 ##############################################################################
  237 ###  Check for ffmpeg - Optional.
  238 ##############################################################################
  239 FFMPEG_VER="--"
  240 AC_ARG_WITH([ffmpeg],
  241   AS_HELP_STRING([--with-ffmpeg[=DIR]],[Build with FFMPEG support]),
  242   [FFMPEG=$withval],
  243   [FFMPEG="yes"]
  244 )
  245 
  246 AS_IF([test "${FFMPEG}" = "no"], [
  247     AC_MSG_CHECKING(for FFmpeg)
  248     AC_MSG_RESULT(skipped)
  249   ],[
  250     AC_MSG_CHECKING(FFmpeg pkg-config path)
  251     TEMP_PATH=$PKG_CONFIG_PATH
  252     AS_IF([test "${FFMPEG}" != "yes"], [
  253         PKG_CONFIG_PATH=${FFMPEG}/lib/pkgconfig:$PKG_CONFIG_PATH
  254         FFMPEG="yes"
  255       ]
  256     )
  257     export PKG_CONFIG_PATH
  258     AC_MSG_RESULT($PKG_CONFIG_PATH)
  259 
  260     FFMPEG_DEPS="libavutil libavformat libavcodec libswscale libavdevice"
  261     AC_MSG_CHECKING(for FFmpeg)
  262     AS_IF([pkg-config $FFMPEG_DEPS], [
  263         FFMPEG_VER=`pkg-config --modversion libavformat`
  264         TEMP_CFLAGS="$TEMP_CFLAGS "`pkg-config --cflags $FFMPEG_DEPS`
  265         TEMP_LIBS="$TEMP_LIBS "`pkg-config --libs $FFMPEG_DEPS`
  266         AC_DEFINE([HAVE_FFMPEG], [1], [Define to 1 if FFMPEG is around])
  267         AC_MSG_RESULT(yes)
  268       ],[
  269         AC_MSG_RESULT(no)
  270         AC_MSG_ERROR([Required ffmpeg packages 'libavutil-dev libavformat-dev libavcodec-dev libswscale-dev libavdevice-dev' were not found.  Please check motion_guide.html and install necessary dependencies or use the '--without-ffmpeg' configuration option.])
  271       ]
  272     )
  273     PKG_CONFIG_PATH=$TEMP_PATH
  274     export PKG_CONFIG_PATH
  275   ]
  276 )
  277 
  278 ##############################################################################
  279 ###  Check for MariaDB - Optional
  280 ##############################################################################
  281 AC_ARG_WITH(mariadb,
  282   AS_HELP_STRING([--with-mariadb[=DIR]],[Build with MariaDB support]),
  283   [MARIADB="$withval"],
  284   [MARIADB="yes"]
  285 )
  286 
  287 AS_IF([test "${MARIADB}" = "no"], [
  288     AC_MSG_CHECKING(for MariaDB)
  289     AC_MSG_RESULT(skipped)
  290   ],[
  291     TEMP_PATH=$PKG_CONFIG_PATH
  292     AC_MSG_CHECKING(MariaDB pkg-config path)
  293     AS_IF([test "${MARIADB}" != "yes"], [
  294         PKG_CONFIG_PATH=${MARIADB}/lib/pkgconfig:$PKG_CONFIG_PATH
  295         MARIADB="yes"
  296       ]
  297     )
  298     export PKG_CONFIG_PATH
  299     AC_MSG_RESULT($PKG_CONFIG_PATH)
  300 
  301     AC_MSG_CHECKING(for MariaDB)
  302     AS_IF([pkg-config mariadb], [
  303         TEMP_CFLAGS="$TEMP_CFLAGS "`pkg-config --cflags mariadb`
  304         TEMP_LIBS="$TEMP_LIBS "`pkg-config --libs mariadb`
  305         AC_DEFINE([HAVE_MARIADB], [1], [Define to 1 if you have MariaDB support])
  306       ],[
  307         MARIADB="no"
  308       ]
  309     )
  310     AC_MSG_RESULT([$MARIADB])
  311     PKG_CONFIG_PATH=$TEMP_PATH
  312     export PKG_CONFIG_PATH
  313   ]
  314 )
  315 
  316 ##############################################################################
  317 ###  Check for MySQL - Optional
  318 ##############################################################################
  319 AC_ARG_WITH(mysql,
  320   AS_HELP_STRING([--with-mysql[=DIR]],[Build with MySQL support]),
  321   [MYSQL="$withval"],
  322   [MYSQL="yes"]
  323 )
  324 
  325 AS_IF([test "${MYSQL}" = "no"], [
  326     AC_MSG_CHECKING(for MySQL)
  327     AC_MSG_RESULT(skipped)
  328   ],[
  329     TEMP_PATH=$PKG_CONFIG_PATH
  330     AC_MSG_CHECKING(MySQL pkg-config path)
  331     AS_IF([test "${MYSQL}" != "yes"], [
  332         PKG_CONFIG_PATH=${MYSQL}/lib/pkgconfig:$PKG_CONFIG_PATH
  333         MYSQL="yes"
  334       ]
  335     )
  336     export PKG_CONFIG_PATH
  337     AC_MSG_RESULT($PKG_CONFIG_PATH)
  338 
  339     AC_MSG_CHECKING(for MySQL)
  340     AS_IF([pkg-config mysqlclient], [
  341         TEMP_CFLAGS="$TEMP_CFLAGS "`pkg-config --cflags mysqlclient`
  342         TEMP_LIBS="$TEMP_LIBS "`pkg-config --libs mysqlclient`
  343         AC_DEFINE([HAVE_MYSQL], [1], [Define to 1 if you have MySQL support])
  344       ],[
  345         MYSQL="no"
  346       ]
  347     )
  348     AC_MSG_RESULT([$MYSQL])
  349     PKG_CONFIG_PATH=$TEMP_PATH
  350     export PKG_CONFIG_PATH
  351   ]
  352 )
  353 
  354 ##############################################################################
  355 ###  Check for PostgreSQL - Optional
  356 ##############################################################################
  357 AC_ARG_WITH(pgsql,
  358   AS_HELP_STRING([--with-pgsql[=DIR]],[Build with PostgreSQL support]),
  359   [PGSQL="$withval"],
  360   [PGSQL="yes"]
  361 )
  362 
  363 AS_IF([test "${PGSQL}" = "no"], [
  364     AC_MSG_CHECKING(for PostgreSQL)
  365     AC_MSG_RESULT(skipped)
  366   ],[
  367     TEMP_PATH=$PKG_CONFIG_PATH
  368     AC_MSG_CHECKING(PostgreSQL pkg-config path)
  369     AS_IF([test "${PGSQL}" != "yes"], [
  370         PKG_CONFIG_PATH=${PGSQL}/lib/pkgconfig:$PKG_CONFIG_PATH
  371         PGSQL="yes"
  372       ]
  373     )
  374     export PKG_CONFIG_PATH
  375     AC_MSG_RESULT($PKG_CONFIG_PATH)
  376 
  377     AC_MSG_CHECKING(for PostgreSQL)
  378     AS_IF([pkg-config libpq], [
  379         TEMP_CFLAGS="$TEMP_CFLAGS "`pkg-config --cflags libpq`
  380         TEMP_LIBS="$TEMP_LIBS "`pkg-config --libs libpq`
  381         AC_DEFINE([HAVE_PGSQL], [1], [Define to 1 if you have PostgreSQL support])
  382       ],[
  383         PGSQL="no"
  384       ]
  385     )
  386     AC_MSG_RESULT([$PGSQL])
  387     PKG_CONFIG_PATH=$TEMP_PATH
  388     export PKG_CONFIG_PATH
  389   ]
  390 )
  391 
  392 ##############################################################################
  393 ###  Check for SQLITE3 - Optional
  394 ##############################################################################
  395 AC_ARG_WITH(sqlite3,
  396   AS_HELP_STRING([--without-sqlite3],[Disable sqlite3 support.]),
  397   [SQLITE3="$withval"],
  398   [SQLITE3="yes"]
  399 )
  400 AS_IF([test "${SQLITE3}" = "no"], [
  401     AC_MSG_CHECKING(for sqlite3)
  402     AC_MSG_RESULT(skipping)
  403   ],[
  404     AC_CHECK_HEADERS(sqlite3.h, [
  405         TEMP_CFLAGS="$TEMP_CFLAGS "`pkg-config --cflags sqlite3`
  406         TEMP_LIBS="$TEMP_LIBS "`pkg-config --libs sqlite3`
  407         AC_DEFINE([HAVE_SQLITE3], [1], [Define to 1 if you have SQLITE3 support])
  408       ],[
  409         SQLITE3="no"
  410       ]
  411     )
  412   ]
  413 )
  414 
  415 ##############################################################################
  416 ###  Optimize compiler
  417 ##############################################################################
  418 AC_ARG_WITH([optimizecpu],
  419   AS_HELP_STRING([--without-optimizecpu],
  420     [Exclude autodetecting platform and cpu type. This will disable the compilation of gcc optimizing code by platform and cpu.]),
  421   [OPTIMIZECPU=$withval],
  422   [OPTIMIZECPU=no]
  423 )
  424 
  425 AS_IF([test "${OPTIMIZECPU}" = "yes"], [
  426     AS_IF([test -e "/proc/device-tree/model"], [
  427         # explicit test for RPI3 as /proc/cpuinfo reports armv7 even though it is armv8
  428         RPI3=`grep "Raspberry Pi 3 Model" /proc/device-tree/model`
  429         AS_IF([test "x${RPI3}" != "x"], [
  430             TEMP_CFLAGS="$TEMP_CFLAGS -mcpu=cortex-a53 -mfpu=neon-fp-armv8"
  431           ]
  432         )
  433       ]
  434     )
  435   ]
  436 )
  437 
  438 ##############################################################################
  439 ###  Developer Flags
  440 ##############################################################################
  441 AC_ARG_WITH([developer-flags],
  442     AS_HELP_STRING([--with-developer-flags],
  443     [Causes practically all of the possible gcc warning flags to be set.  This may produce a large amount of warnings.]),
  444     [DEVELOPER_FLAGS=$withval],
  445     [DEVELOPER_FLAGS=no])
  446 
  447 AS_IF([test "${DEVELOPER_FLAGS}" = "yes"], [
  448     TEMP_CFLAGS="$TEMP_CFLAGS -W -Werror -Wall -Wextra -Wformat -Wshadow -Wpointer-arith -Wwrite-strings -Waggregate-return -Wstrict-prototypes -Wmissing-prototypes -Wnested-externs -Winline -Wredundant-decls -Wno-long-long -ggdb -g3"
  449   ]
  450 )
  451 ##############################################################################
  452 ###  Prototype Flags
  453 ###  mysql and mariadb have upstream prototype errors so remove that check
  454 ##############################################################################
  455 AC_ARG_WITH([prototype-flags],
  456     AS_HELP_STRING([--with-prototype-flags],
  457     [Causes practically all of the possible gcc warning flags to be set except missing prototypes.]),
  458     [PROTOTYPE_FLAGS=$withval],
  459     [PROTOTYPE_FLAGS=no])
  460 
  461 AS_IF([test "${PROTOTYPE_FLAGS}" = "yes"], [
  462     TEMP_CFLAGS="$TEMP_CFLAGS -W -Werror -Wall -Wextra -Wformat -Wshadow -Wpointer-arith -Wwrite-strings -Waggregate-return -Wnested-externs -Winline -Wredundant-decls -Wno-long-long -ggdb -g3"
  463   ]
  464 )
  465 
  466 
  467 CFLAGS="$CFLAGS $TEMP_CFLAGS"
  468 LIBS="$LIBS $TEMP_LIBS"
  469 LDFLAGS="$TEMP_LDFLAGS"
  470 
  471 AC_CONFIG_FILES([
  472     Makefile
  473     src/Makefile
  474   po/Makefile.in
  475   man/Makefile
  476   data/camera1-dist.conf
  477   data/camera2-dist.conf
  478   data/camera3-dist.conf
  479   data/camera4-dist.conf
  480   data/motion-dist.conf
  481   data/motion.service
  482 ])
  483 
  484 AC_ARG_VAR([KILL],[the 'kill' program to use to send signals to motion])
  485 AC_PATH_PROG([KILL],[kill],['/bin/kill'])
  486 AC_OUTPUT
  487 
  488 ##############################################################################
  489 ###  Report results to user
  490 ##############################################################################
  491 echo ""
  492 echo "   **************************"
  493 echo "      Configure status       "
  494 echo "      ${PACKAGE_NAME} ${PACKAGE_VERSION}"
  495 echo "   **************************"
  496 echo
  497 echo "CFLAGS: $CFLAGS"
  498 echo
  499 echo "LIBS: $LIBS"
  500 echo
  501 echo "LDFLAGS: $LDFLAGS"
  502 echo
  503 echo
  504 echo "OS                  : $host_os"
  505 echo "pthread_np          : $PTHREAD_NP"
  506 echo "pthread_setname_np  : $PTHREAD_SETNAME_NP"
  507 echo "pthread_getname_np  : $PTHREAD_GETNAME_NP"
  508 echo "XSI error           : $XSI_STRERROR"
  509 echo "webp support        : $WEBP"
  510 echo "V4L2 support        : $V4L2"
  511 echo "BKTR support        : $BKTR"
  512 echo "MMAL support        : $MMAL"
  513 echo "FFmpeg support      : $FFMPEG"
  514 echo "libavformat version : $FFMPEG_VER"
  515 echo "SQLite3 support     : $SQLITE3"
  516 echo "MYSQL support       : $MYSQL"
  517 echo "PostgreSQL support  : $PGSQL"
  518 echo "MariaDB support     : $MARIADB"
  519 echo
  520 echo  "Install prefix:       $prefix"
  521 echo