"Fossies" - the Fresh Open Source Software Archive

Member "lrzip-0.641/configure.ac" (5 Mar 2021, 5539 Bytes) of package /linux/misc/lrzip-0.641.tar.xz:


As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) C and C++ source code syntax highlighting (style: standard) with prefixed line numbers and code folding option. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "configure.ac": 0.640_vs_0.641.

    1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
    2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
    3 m4_define([v_maj], [0])
    4 m4_define([v_min], [6])
    5 m4_define([v_mic], [41])
    6 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
    7 m4_define([v_v], m4_join([], v_min, v_mic))
    8 m4_define([v_ver], [v_maj.v_v])
    9 m4_define([lt_rev], m4_eval(v_maj + v_min))
   10 m4_define([lt_cur], v_mic)
   11 m4_define([lt_age], v_min)
   12 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   14 
   15 
   16 dnl Process this file with autoconf to produce a configure script.
   17 AC_INIT([lrzip],[v_ver],[kernel@kolivas.org])
   18 AC_PREREQ([2.59])
   19 AC_CONFIG_SRCDIR([configure.ac])
   20 AC_CONFIG_MACRO_DIR([m4])
   21 AC_CONFIG_HEADERS([config.h])
   22 
   23 AM_INIT_AUTOMAKE([1.6 dist-bzip2 foreign subdir-objects])
   24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   25 AC_USE_SYSTEM_EXTENSIONS
   26 
   27 AC_PROG_LIBTOOL
   28 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   29 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   30 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
   31 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
   32 AC_DEFINE_UNQUOTED(LRZIP_MAJOR_VERSION, [v_maj], [Major version])
   33 AC_DEFINE_UNQUOTED(LRZIP_MINOR_VERSION, [v_min], [Minor version])
   34 AC_DEFINE_UNQUOTED(LRZIP_MINOR_SUBVERSION, [v_mic], [Micro version])
   35 version_info="lt_rev:lt_cur:lt_age"
   36 release_info="v_rel"
   37 AC_SUBST(version_info)
   38 AC_SUBST(release_info)
   39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   40 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   41 VMAJ=v_maj
   42 AC_SUBST(VMAJ)
   43 
   44 AC_CANONICAL_BUILD
   45 AC_CANONICAL_HOST
   46 
   47 dnl Checks for programs.
   48 AC_PROG_CC
   49 AC_PROG_CXX
   50 AC_PROG_INSTALL
   51 AC_PROG_LN_S
   52 AC_SUBST(SHELL)
   53 AC_SYS_LARGEFILE
   54 AC_FUNC_FSEEKO
   55 AC_FUNC_ALLOCA
   56 AC_PROG_CC_C99
   57 AS_IF([test x"$ac_cv_prog_cc_c99" = x"no"],
   58     AC_MSG_ERROR([C compiler does not support C99], 1))
   59 AC_CHECK_PROG([HAVE_POD2MAN], [pod2man], [yes])
   60 AS_IF([test "$HAVE_POD2MAN" != "yes"],
   61     AC_MSG_FAILURE([pod2man is needed to generate manual from POD]))
   62 
   63 
   64 AC_ARG_ENABLE(
   65         asm,
   66         [AC_HELP_STRING([--enable-asm],[Enable native Assembly code])],
   67         ASM=$enableval,
   68         ASM=yes
   69              )
   70 
   71 if test x"$ASM" = x"yes"; then
   72     AC_CHECK_PROG( ASM_PROG, nasm, nasm, no ) # fix to set ASM_PROG to nasm, not yes.
   73     if test x"$ASM_PROG" = x"no "; then
   74         ASM=no
   75     fi
   76 fi
   77 
   78 static=no
   79 AC_ARG_ENABLE([static-bin],
   80     [AC_HELP_STRING([--enable-static-bin],[Build statically linked binary @<:@default=no@:>@])],
   81     [static=$enableval]
   82     )
   83 AM_CONDITIONAL([STATIC], [test x"$static" = x"yes"])
   84 
   85 AC_CHECK_HEADERS(fcntl.h sys/time.h unistd.h sys/mman.h)
   86 AC_CHECK_HEADERS(ctype.h errno.h sys/resource.h)
   87 AC_CHECK_HEADERS(endian.h sys/endian.h arpa/inet.h)
   88 AC_CHECK_HEADERS(alloca.h pthread.h)
   89 
   90 AC_TYPE_OFF_T
   91 AC_TYPE_SIZE_T
   92 AC_C___ATTRIBUTE__
   93 AC_CHECK_SIZEOF(int)
   94 AC_CHECK_SIZEOF(long)
   95 AC_CHECK_SIZEOF(short)
   96 
   97 AC_CACHE_CHECK([for large file support],rzip_cv_HAVE_LARGE_FILES,[
   98 AC_RUN_IFELSE([AC_LANG_SOURCE([[
   99 #include <stdio.h>
  100 #include <sys/types.h>
  101 main() { return (sizeof(off_t) == 4); }]])],[rzip_cv_HAVE_LARGE_FILES=yes],[rzip_cv_HAVE_LARGE_FILES=no],[rzip_cv_HAVE_LARGE_FILES=cross])])
  102 if test x"$rzip_cv_HAVE_LARGE_FILES" = x"yes"; then
  103     AC_DEFINE(HAVE_LARGE_FILES, 1, [ ])
  104 fi
  105 
  106 AC_C_INLINE
  107 
  108 AC_C_BIGENDIAN
  109 
  110 AC_CHECK_LIB(pthread, pthread_create, ,
  111         AC_MSG_ERROR([Could not find pthread library - please install libpthread]))
  112 AC_CHECK_LIB(m, sqrt, ,
  113         AC_MSG_ERROR([Could not find math library - please install libm]))
  114 AC_CHECK_LIB(z, compress2, ,
  115     AC_MSG_ERROR([Could not find zlib library - please install zlib-dev]))
  116 AC_CHECK_LIB(bz2, BZ2_bzBuffToBuffCompress, ,
  117         AC_MSG_ERROR([Could not find bz2 library - please install libbz2-dev]))
  118 AC_CHECK_LIB(lzo2, lzo1x_1_compress, ,
  119         AC_MSG_ERROR([Could not find lzo2 library - please install liblzo2-dev]))
  120 AC_CHECK_LIB(lz4, LZ4_compress_default, ,
  121     AC_MSG_ERROR([Could not find lz4 library - please install liblz4-dev]))
  122 
  123 AC_CHECK_FUNCS(mmap strerror)
  124 AC_CHECK_FUNCS(getopt_long)
  125 
  126 AX_PTHREAD
  127 LIBS="$PTHREAD_LIBS $LIBS"
  128 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  129 CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
  130 
  131 # final checks for assembler
  132 # ASM is back for x86_64 by using newer CRC code from p7zip-16.02
  133 # object files handled in lzma/C/Makefile.am
  134 if test x"$ASM" = x"yes"; then
  135     ASM_OPT="-I../ASM/x86/"
  136     case $host in
  137         i?86-*)
  138             ASM_OPT="$ASM_OPT -g -f elf" ;;
  139         x86_64-*)
  140             ASM_OPT="$ASM_OPT -Dx64 -g -f elf64" ;;
  141         *) ASM_OPT= ;;
  142     esac
  143 else
  144     ASM_OPT=
  145 fi
  146 AM_CONDITIONAL([USE_ASM], [test x"$ASM" = x"yes"])
  147 AC_SUBST([ASM_OPT])
  148 AC_SUBST([ASM_CMD])
  149 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
  150 
  151 AC_CONFIG_FILES([
  152 Makefile
  153 lrzip.pc
  154 lzma/Makefile
  155 lzma/C/Makefile
  156 lzma/ASM/x86/Makefile
  157 doc/Makefile
  158 man/Makefile
  159 ])
  160 AC_OUTPUT
  161 
  162 echo
  163 echo
  164 echo
  165 echo "------------------------------------------------------------------------"
  166 echo "$PACKAGE $VERSION"
  167 echo "------------------------------------------------------------------------"
  168 echo
  169 echo
  170 echo "Configuration Options Summary:"
  171 echo
  172 echo "  ASM................: $ASM"
  173 echo "  Static binary......: $static"
  174 echo
  175 echo "Documentation..........: ${build_doc}"
  176 echo
  177 echo "Compilation............: make (or gmake)"
  178 echo "  CPPFLAGS.............: $CPPFLAGS"
  179 echo "  CFLAGS...............: $CFLAGS"
  180 echo "  CXXFLAGS.............: $CXXFLAGS"
  181 echo "  LDFLAGS..............: $LDFLAGS"
  182 echo
  183 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
  184 echo "  prefix...............: $prefix"
  185 echo