"Fossies" - the Fresh Open Source Software Archive

Member "kaffeine-2.0.18/CMakeLists.txt" (14 May 2019, 2955 Bytes) of package /linux/misc/kaffeine-2.0.18.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "CMakeLists.txt": 2.0.17_vs_2.0.18.

    1 project(kaffeine)
    2 
    3 set(KAFFEINE_MAJOR_VERSION 2)
    4 set(KAFFEINE_MINOR_VERSION 0)
    5 set(KAFFEINE_PATCH_VERSION 18)
    6 
    7 # comment/uuncomment below if either the version is a production or a development one
    8 #set(KAFFEINE_EXTRA_VERSION -git)
    9 
   10 set(KAFFEINE_VERSION
   11   ${KAFFEINE_MAJOR_VERSION}.${KAFFEINE_MINOR_VERSION}.${KAFFEINE_PATCH_VERSION}${KAFFEINE_EXTRA_VERSION})
   12 
   13 option(BUILD_TOOLS "Build the helper tools" OFF)
   14 
   15 # Minimal versions where build is known to work
   16 cmake_minimum_required(VERSION 2.8.12)
   17 set(QT_MIN_VERSION "5.4.0")
   18 set(KF5_MIN_VERSION "5.11.0")
   19 
   20 # shut up cmake warnings about newer policies
   21 if(POLICY CMP0063)
   22   cmake_policy(SET CMP0063 NEW)
   23 endif(POLICY CMP0063)
   24 
   25 ## workaround for ki18n 5.34.0++ changes (see BUG 379834)
   26 if(POLICY CMP0002)
   27   cmake_policy(SET CMP0002 OLD)
   28 endif(POLICY CMP0002)
   29 
   30 find_package(Qt5Core)
   31 find_package(ECM 1.0.0 REQUIRED NO_MODULE)
   32 set(CMAKE_MODULE_PATH
   33 	${ECM_MODULE_PATH}
   34 	${ECM_KDE_MODULE_DIR}
   35 	"${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
   36 )
   37 
   38 include(KDEInstallDirs)
   39 include(KDECMakeSettings)
   40 include(KDECompilerSettings)
   41 include(FeatureSummary)
   42 include(ECMInstallIcons)
   43 include(CheckIncludeFiles)
   44 
   45 # Instruct CMake to run moc automatically when needed.
   46 set(CMAKE_AUTOMOC ON)
   47 
   48 # Find Qt modules
   49 find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS
   50 	Core    # QCommandLineParser, QStringLiteral
   51 	Widgets # QApplication
   52 	Network
   53 	Sql
   54 	X11Extras
   55 )
   56 
   57 # Find KDE modules
   58 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
   59 	CoreAddons      # KAboutData
   60 	I18n            # KLocalizedString
   61 	WidgetsAddons   # KMessageBox
   62 	WindowSystem	# KStartupInfo
   63 	XmlGui		# KActonCollection
   64 	KIO		# KFileWidget
   65 	Solid
   66 	DBusAddons
   67 )
   68 find_package(KF5DocTools ${KF5_MIN_VERSION} QUIET)
   69 
   70 find_package(X11 REQUIRED)
   71 find_package(VLC 1.2 REQUIRED)
   72 
   73 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
   74 
   75 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_BINARY_DIR} ${VLC_INCLUDE_DIRS}
   76                     ${X11_Xscreensaver_INCLUDE_PATH})
   77 
   78 check_include_files(${CMAKE_CURRENT_SOURCE_DIR}/include/frontend.h HAVE_DVB)
   79 
   80 if(NOT HAVE_DVB)
   81   MESSAGE(STATUS "Disabled features:\nDVB  Digital television support for Linux\n")
   82   set(HAVE_DVB 0)
   83 else()
   84   set(HAVE_DVB 1)
   85 endif(NOT HAVE_DVB)
   86 
   87 if(HAVE_DVB)
   88   find_package(Libdvbv5)
   89   if(NOT Libdvbv5_FOUND)
   90     set(HAVE_LIBDVBV5 0)
   91     set(HAVE_DVB 0)
   92     message(STATUS "Disabled features:\nDVB  Digital television support for Linux, as libdvbv5 was not found.\n")
   93   endif(NOT Libdvbv5_FOUND)
   94 endif(HAVE_DVB)
   95 
   96 add_subdirectory(deviceactions)
   97 add_subdirectory(icons)
   98 add_subdirectory(profiles)
   99 add_subdirectory(src)
  100 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
  101   if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/po/CMakeLists.txt" )
  102     add_subdirectory(po)
  103   else()
  104     ki18n_install(po)
  105   endif()
  106 endif()
  107 
  108 if(KF5DocTools_VERSION)
  109   add_subdirectory(doc)
  110 endif(KF5DocTools_VERSION)
  111 
  112 if(BUILD_TOOLS)
  113   add_subdirectory(tools)
  114 endif(BUILD_TOOLS)