"Fossies" - the Fresh Open Source Software Archive

Member "gawk-5.1.0/extension/configure.ac" (14 Apr 2020, 3396 Bytes) of package /linux/misc/gawk-5.1.0.tar.xz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "configure.ac": 5.0.1_vs_5.1.0.

    1 dnl
    2 dnl configure.ac --- autoconf input file for gawk
    3 dnl
    4 dnl Copyright (C) 2012-2020 the Free Software Foundation, Inc.
    5 dnl
    6 dnl This file is part of GAWK, the GNU implementation of the
    7 dnl AWK Programming Language.
    8 dnl
    9 dnl GAWK is free software; you can redistribute it and/or modify
   10 dnl it under the terms of the GNU General Public License as published by
   11 dnl the Free Software Foundation; either version 3 of the License, or
   12 dnl (at your option) any later version.
   13 dnl
   14 dnl GAWK is distributed in the hope that it will be useful,
   15 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
   16 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   17 dnl GNU General Public License for more details.
   18 dnl
   19 dnl You should have received a copy of the GNU General Public License
   20 dnl along with this program; if not, write to the Free Software
   21 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA
   22 dnl
   23 
   24 dnl Process this file with autoconf to produce a configure script.
   25 
   26 AC_INIT([GNU Awk Bundled Extensions],[5.1.0],[bug-gawk@gnu.org],[gawk-extensions])
   27 
   28 AC_PREREQ([2.69])
   29 
   30 AC_CONFIG_MACRO_DIR([m4])
   31 AC_CONFIG_AUX_DIR([build-aux])
   32 
   33 AM_INIT_AUTOMAKE([1.15 -Wall -Werror])
   34 
   35 GAWK_CANONICAL_HOST
   36 AC_USE_SYSTEM_EXTENSIONS
   37 AC_ZOS_USS
   38 
   39 INSTALL="$ac_aux_dir/install-sh -c"
   40 export INSTALL
   41 
   42 SKIP_MPFR=no
   43 AC_ARG_ENABLE([mpfr],
   44 	[AS_HELP_STRING([--disable-mpfr],[do not check for MPFR])],
   45 	if test "$enableval" = no
   46 	then
   47 		SKIP_MPFR=yes
   48 	fi
   49 )
   50 
   51 dnl Set the programming language for checks. Fortunately,
   52 dnl this only needs to be set once, since everything is in C.
   53 AC_LANG([C])
   54 
   55 dnl initialize GNU gettext
   56 dnl this seems to help with finding MPFR on some systems, too.
   57 AM_GNU_GETTEXT([external])
   58 AM_GNU_GETTEXT_VERSION([0.19.7])
   59 AM_LANGINFO_CODESET
   60 gt_LC_MESSAGES
   61 
   62 dnl checks for structure members
   63 AC_CHECK_MEMBERS([struct stat.st_blksize])
   64 
   65 AM_PROG_AR
   66 AC_SYS_LARGEFILE
   67 LT_INIT([win32-dll disable-static])
   68 dnl AC_PROG_INSTALL
   69 
   70 dnl use the same definition as the main configure script.
   71 dnl EXTENSIONDIR is exported if it was set there.
   72 dnl N.B. We must use ${libdir}/gawk instead of $pkglibdir because $pkglibdir
   73 dnl is set to ${libdir}/gawk-extensions, which is not what we want.
   74 AC_SUBST([pkgextensiondir], ['${libdir}/gawk'${EXTENSIONDIR}])
   75 
   76 if test "$GCC" = yes
   77 then
   78 	CFLAGS="$CFLAGS -Wall"	# Don't add -Wextra, hurts older gcc
   79 fi
   80 
   81 AC_MSG_CHECKING([for special development options])
   82 if test -f $srcdir/../.developing
   83 then
   84 	if test "$GCC" = yes
   85 	then
   86 		CFLAGS="$CFLAGS -Wall -fno-builtin -g3 -gdwarf-2"
   87 	fi
   88 	AC_MSG_RESULT([yes])
   89 else
   90 	AC_MSG_RESULT([no])
   91 fi
   92 
   93 AC_CHECK_HEADERS(fnmatch.h limits.h sys/mkdev.h sys/param.h sys/select.h \
   94 		sys/statvfs.h sys/sysmacros.h sys/time.h)
   95 
   96 AC_HEADER_DIRENT
   97 dnl 12/2017: AC_HEADER_MAJOR no longer works on recent Fedora / GLIBC.
   98 dnl Instead we just check for the headers in the call above.
   99 dnl AC_HEADER_MAJOR
  100 AC_HEADER_TIME
  101 
  102 dnl check for mpfr support
  103 case `uname -m` in
  104 *'Power Macintosh'*)
  105 	: ;;
  106 *)
  107 	case $SKIP_MPFR in
  108 	no)	GNUPG_CHECK_MPFR
  109 		;;
  110 	esac
  111 	;;
  112 esac
  113 
  114 AC_SEARCH_LIBS(fmod, m)
  115 AC_CHECK_FUNCS(fdopendir fmod fnmatch getdtablesize \
  116 		gettimeofday nanosleep select statvfs \
  117 		GetSystemTimeAsFileTime)
  118 
  119 GAWK_FUNC_DIRFD
  120 GAWK_PREREQ_DIRFD
  121 
  122 dnl checks for compiler characteristics
  123 AC_C_INLINE
  124 
  125 AC_CONFIG_HEADERS([config.h:configh.in])
  126 AH_BOTTOM([#include "ext_custom.h"])
  127 
  128 AC_CONFIG_FILES(Makefile po/Makefile.in)
  129 AC_OUTPUT