"Fossies" - the Fresh Open Source Software Archive

Member "automake-1.16.3/m4/missing.m4" (19 Nov 2020, 1052 Bytes) of package /linux/misc/automake-1.16.3.tar.xz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "missing.m4": 1.16.2_vs_1.16.3.

    1 # Fake the existence of programs that GNU maintainers use.  -*- Autoconf -*-
    2 
    3 # Copyright (C) 1997-2020 Free Software Foundation, Inc.
    4 #
    5 # This file is free software; the Free Software Foundation
    6 # gives unlimited permission to copy and/or distribute it,
    7 # with or without modifications, as long as this notice is preserved.
    8 
    9 # AM_MISSING_PROG(NAME, PROGRAM)
   10 # ------------------------------
   11 AC_DEFUN([AM_MISSING_PROG],
   12 [AC_REQUIRE([AM_MISSING_HAS_RUN])
   13 $1=${$1-"${am_missing_run}$2"}
   14 AC_SUBST($1)])
   15 
   16 # AM_MISSING_HAS_RUN
   17 # ------------------
   18 # Define MISSING if not defined so far and test if it is modern enough.
   19 # If it is, set am_missing_run to use it, otherwise, to nothing.
   20 AC_DEFUN([AM_MISSING_HAS_RUN],
   21 [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
   22 AC_REQUIRE_AUX_FILE([missing])dnl
   23 if test x"${MISSING+set}" != xset; then
   24   MISSING="\${SHELL} '$am_aux_dir/missing'"
   25 fi
   26 # Use eval to expand $SHELL
   27 if eval "$MISSING --is-lightweight"; then
   28   am_missing_run="$MISSING "
   29 else
   30   am_missing_run=
   31   AC_MSG_WARN(['missing' script is too old or missing])
   32 fi
   33 ])