"Fossies" - the Fresh Open Source Software Archive

Member "automake-1.16.3/configure.ac" (19 Nov 2020, 22301 Bytes) of package /linux/misc/automake-1.16.3.tar.xz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "configure.ac": 1.16.2_vs_1.16.3.

    1 # Process this file with autoconf to produce a configure script.
    2 
    3 # Copyright (C) 1995-2020 Free Software Foundation, Inc.
    4 #
    5 # This program is free software; you can redistribute it and/or modify
    6 # it under the terms of the GNU General Public License as published by
    7 # the Free Software Foundation; either version 2, or (at your option)
    8 # any later version.
    9 #
   10 # This program is distributed in the hope that it will be useful,
   11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
   12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   13 # GNU General Public License for more details.
   14 #
   15 # You should have received a copy of the GNU General Public License
   16 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
   17 
   18 AC_PREREQ([2.69])
   19 AC_INIT([GNU Automake], [1.16.3], [bug-automake@gnu.org])
   20 
   21 AC_CONFIG_SRCDIR([bin/automake.in])
   22 AC_CONFIG_AUX_DIR([lib])
   23 
   24 AM_SILENT_RULES([yes])
   25 
   26 AC_CANONICAL_HOST
   27 AC_CANONICAL_BUILD
   28 
   29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
   30 # way we can run Autoconf tests from configure (or from the test
   31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
   32 # autoreconf, autoheader, and autoupdate.
   33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
   34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
   35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
   36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
   37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
   38 
   39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
   40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
   41 dnl the automake options to avoid bloating and potential problems.
   42 AM_INIT_AUTOMAKE([-Wall -Werror dist-xz filename-length-max=99
   43                   no-define no-dependencies])
   44 
   45 # Keep this on a line of its own, since it must be found and processed
   46 # by the 'update-copyright' rule in our Makefile.
   47 RELEASE_YEAR=2020
   48 AC_SUBST([RELEASE_YEAR])
   49 
   50 # The API version is the base version.  We must guarantee
   51 # compatibility for all releases with the same API version.
   52 APIVERSION=1.16
   53 AC_SUBST([APIVERSION])
   54 
   55 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
   56 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
   57 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
   58 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
   59 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
   60 
   61 # Our build system is bootstrapped with the bleeding-edge versions of
   62 # aclocal and automake, hence the remake rules must use those versions
   63 # as well.  The extra quoting is to cater to cases when the build
   64 # directory contains whitespace or shell metacharacters.
   65 ACLOCAL="\"`pwd`/pre-inst-env\" aclocal-$APIVERSION"
   66 AUTOMAKE="\"`pwd`/pre-inst-env\" automake-$APIVERSION"
   67 
   68 AC_PROG_LN_S
   69 
   70 AC_PATH_PROG([PERL], [perl])
   71 if test -z "$PERL"; then
   72    AC_MSG_ERROR([perl not found])
   73 fi
   74 # Save details about the selected perl interpreter in config.log.
   75 AM_RUN_LOG([$PERL --version])
   76 $PERL -e 'require 5.006;' || {
   77    AC_MSG_ERROR(
   78 [perl 5.6 or better is required; perl 5.8.2 or better
   79 is recommended.  If you have several perl versions
   80 installed, select the one Automake should use using
   81   ./configure PERL=/path/to/perl])
   82 }
   83 
   84 # The test suite will skip some tests if tex is absent.
   85 AC_CHECK_PROG([TEX], [tex], [tex])
   86 # Save details about the selected TeX program in config.log.
   87 # Redirect input from /dev/null, as TeX might otherwise hang waiting
   88 # for input from the terminal.
   89 AM_RUN_LOG([$TEX --version </dev/null])
   90 
   91 # The test suite will skip some tests if no lex or yacc program is
   92 # available.
   93 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
   94 #  1. we don't want flex (resp. bison) to be preferred to system lex
   95 #     (resp. system yacc);
   96 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
   97 #     by default;
   98 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
   99 #     LEXLIB to be calculated and/or AC_SUBST'd;
  100 #  4. we prefer that the YACC and LEX variables are not reported in the
  101 #     configure help screen.
  102 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
  103 AC_CHECK_PROGS([LEX], [lex flex], [false])
  104 
  105 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
  106 # deletion of any files created (such as those added to
  107 # autom4te.cache).  We used to perform only the last of the three
  108 # following tests, but some users were unable to figure out that their
  109 # installation was broken since --version appeared to work.
  110 
  111 AC_SUBST([required_autoconf_version], [2.65])
  112 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
  113 [if AM_RUN_LOG([$am_AUTOCONF --version]);
  114 then
  115   am_cv_autoconf_installed=yes
  116 else
  117   am_cv_autoconf_installed=no
  118 fi])
  119 if test "$am_cv_autoconf_installed" = no; then
  120   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
  121     Please make sure it is installed and in your PATH.])
  122 fi
  123 
  124 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
  125 [mkdir conftest
  126 echo 'AC''_INIT' > conftest/conftest.ac
  127 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
  128 then
  129   am_cv_autoconf_works=yes
  130 else
  131   am_cv_autoconf_works=no
  132 fi
  133 rm -rf conftest])
  134 if test "$am_cv_autoconf_works" = no; then
  135   AC_MSG_ERROR([The installed version of autoconf does not work.
  136     Please check config.log for error messages before this one.])
  137 fi
  138 
  139 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
  140 [mkdir conftest
  141 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
  142 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
  143 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
  144 then
  145   am_cv_autoconf_version=yes
  146 else
  147   am_cv_autoconf_version=no
  148 fi
  149 rm -rf conftest])
  150 if test "$am_cv_autoconf_version" = no; then
  151   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
  152 fi
  153 
  154 # Test for ln.  We need use it to install the versioned binaries.
  155 AC_MSG_CHECKING([whether ln works])
  156 AC_CACHE_VAL([am_cv_prog_ln], [
  157 rm -f conftest conftest.file
  158 : >conftest.file
  159 if ln conftest.file conftest 2>/dev/null; then
  160   am_cv_prog_ln=ln
  161 else
  162   am_cv_prog_ln='cp -p'
  163 fi
  164 rm -f conftest conftest.file])
  165 AC_SUBST([LN], [$am_cv_prog_ln])
  166 result=no
  167 test "x$am_cv_prog_ln" = xln && result=yes
  168 AC_MSG_RESULT([$result])
  169 
  170 # The amount we should wait after modifying files depends on the platform.
  171 # On Windows '95, '98 and ME, files modifications have 2-seconds
  172 # granularity and can be up to 3 seconds in the future w.r.t. the
  173 # system clock.  When it is important to ensure one file is older
  174 # than another we wait at least 5 seconds between creations.
  175 case $build in
  176   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
  177   *)               MODIFICATION_DELAY=2;;
  178 esac
  179 AC_SUBST([MODIFICATION_DELAY])
  180 
  181 ## ------------------------------------------- ##
  182 ##  Test for things needed by the test suite.  ##
  183 ## ------------------------------------------- ##
  184 
  185 AC_PROG_EGREP
  186 AC_PROG_FGREP
  187 
  188 dnl FIXME: could we extract this in a simpler way through autoconf
  189 dnl FIXME: idioms or internals?
  190 AC_DEFUN(
  191   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
  192   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
  193 
  194 dnl
  195 dnl Arguments to this macro:
  196 dnl
  197 dnl   $1 - shell to test
  198 dnl   $2 - description of the tested feature
  199 dnl   $3 - shell code used to check the feature; to indicate success,
  200 dnl        it can either exit with status 77, or have the last command
  201 dnl        returning with exit status of zero
  202 dnl   $4 - shell code to execute if the check on the shell is successful
  203 dnl        (defaults to nothing)
  204 dnl   $5 - shell code to execute if the check on the shell is not
  205 dnl        successful (defaults to nothing)
  206 dnl
  207 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
  208   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
  209   AC_MSG_CHECKING([whether $1 $2])
  210   if { $1 -c "$am_bourne_compatible
  211 AS_ESCAPE([$3])
  212 test \$? -eq 0 || exit 1
  213 # Use 77 to indicate success (rather than 0), in case some shell
  214 # acts like Solaris 10's /bin/sh, exiting successfully on some
  215 # syntax errors.
  216 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
  217   then
  218     AC_MSG_RESULT([yes])
  219     $4
  220   else
  221     AC_MSG_RESULT([no])
  222     $5
  223   fi])
  224 
  225 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
  226 # -----------------------------------------
  227 #
  228 # Check if the given shell is good enough to run our test scripts.
  229 # Inspired to gnulib's 'tests/init.sh'.
  230 #
  231 # We require POSIX and XSI features (e.g., '$(...)' for command
  232 # substitutions, '$((...))' for shell arithmetic, and support for
  233 # '${var#...}' and '${var%...}' parameter expansions).
  234 #
  235 # We require that the shell can correctly trap EXIT when 'set -e' is in
  236 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
  237 #
  238 # We want to able to define shell aliases with the same name of shell
  239 # builtins.
  240 #
  241 # We also prefer shells that, when 'set -x' is in effect, do not also
  242 # redirect traces upon stderr redirections.  For example,
  243 #  $ set -x; echo x 2>file
  244 # would emit "+ echo x" into file with older zsh versions.  Similarly,
  245 #   $ set -x; P=1 true 2>file
  246 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
  247 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
  248 #
  249 # Use '$am_score' to indicate the degree of acceptability of the shell.
  250 # A score of "10" means that the shell is good enough for our needs;
  251 # a score of "9" means that the shell has some minor bugs or limitation,
  252 # but is still (barely) acceptable for our uses.  Any other score means
  253 # that the shell is broken or unfit.
  254 #
  255 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
  256   [am_score=10
  257   while :; do
  258 
  259     _AM_CHECK_SHELL_FEATURE([$1],
  260       [supports \$(cmd)],
  261       [test "$(echo x)" = x],
  262       [], [am_score=1; break])
  263 
  264     _AM_CHECK_SHELL_FEATURE([$1],
  265       [supports \$((expr))],
  266       [test $((1 + 2 * 3)) = 7],
  267       [], [am_score=1; break])
  268 
  269     _AM_CHECK_SHELL_FEATURE([$1],
  270       [supports \${@%:@var}],
  271       [zero='' one='x' twelve=' foobar baz!' \
  272         && test ${@%:@zero} -eq 0 \
  273         && test ${@%:@one} -eq 1 \
  274         && test ${@%:@twelve} -eq 12],
  275       [], [am_score=1; break])
  276 
  277     _AM_CHECK_SHELL_FEATURE([$1],
  278       [supports \${var@%:@glob} and \${var%glob}],
  279       [v=a/b/c \
  280         && test ${v@%:@*/} = b/c \
  281         && test ${v@%:@@%:@*/} = c \
  282         && test ${v%/*} = a/b \
  283         && test ${v%%/*} = a],
  284       [], [am_score=1; break])
  285 
  286     _AM_CHECK_SHELL_FEATURE([$1],
  287       [preserves exit traps with "set -e"],
  288       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
  289       [], [am_score=1; break])
  290 
  291     _AM_CHECK_SHELL_FEATURE([$1],
  292       [can define exit traps in a shell function],
  293       [fail=0 && foo() { trap 'fail=1' 0; } && foo && test $fail = 0],
  294       [], [am_score=1; break])
  295 
  296     _AM_CHECK_SHELL_FEATURE([$1],
  297       [corrupts stderr with "set -x"],
  298       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
  299       [am_score=9], [])
  300 
  301     echo 'return 34' > conftest-return.sh
  302     echo 'ok=no' >> conftest-return.sh
  303     _AM_CHECK_SHELL_FEATURE([$1],
  304       [can return early from "dot-sourced" files],
  305       [ok=yes; . ./conftest-return.sh; test $? -eq 34 && test $ok = yes],
  306       [rm -f conftest-return.sh],
  307       [rm -f conftest-return.sh; am_score=1; break])
  308 
  309     echo 'alias false=echo' > conftest-alias.sh
  310     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
  311     _AM_CHECK_SHELL_FEATURE([$1],
  312       [supports alias named like shell builtins],
  313       [. ./conftest-alias.sh],
  314       [rm -f conftest-alias.sh],
  315       [rm -f conftest-alias.sh; am_score=1; break])
  316 
  317     _AM_CHECK_SHELL_FEATURE([$1],
  318       [supports "test -e"],
  319       [test -e config.log && test -e . && test ! -e nonesuch],
  320       [], [am_score=1; break])
  321 
  322     break
  323   done])
  324 
  325 # These messages only goes to the config.log file.
  326 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
  327 
  328 AC_CACHE_VAL(
  329   [ac_cv_AM_TEST_RUNNER_SHELL],
  330   [if test "$AM_TEST_RUNNER_SHELL"; then
  331     # Let the user override it.
  332     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
  333   else
  334     ac_cv_AM_TEST_RUNNER_SHELL=no
  335     am_candidate_shells=${CONFIG_SHELL-}
  336     # For the benefit of Solaris.
  337     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
  338     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
  339       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
  340       if test -n "$am_candidate_sh"; then
  341         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
  342       fi
  343       AM_SUBST_NOTMAKE([am_candidate_sh])
  344       # Must nullify these in order not to interfere with the checks in
  345       # the next loop.
  346       AS_UNSET([am_candidate_sh])
  347       AS_UNSET([ac_cv_path_am_candidate_sh])
  348     done
  349     AS_UNSET([am_PATH]) # Not required anymore
  350     for am_sh in $am_candidate_shells; do
  351       am_score=0
  352       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
  353       if test $am_score -eq 9; then
  354         # The shell is barely acceptable for our needs.  We might
  355         # still find one that is even better, so continue looking.
  356         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
  357         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
  358       elif test $am_score -eq 10; then
  359         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
  360         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
  361         break
  362       fi
  363     done
  364   fi
  365   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
  366 
  367 if test $AM_TEST_RUNNER_SHELL = no; then
  368   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
  369                                 enough to be used in our testsuite])])
  370 else
  371   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
  372 fi
  373 
  374 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
  375            [a sturdy POSIX shell for our testsuite])
  376 
  377 
  378 ###########################################################################
  379 
  380 # Look for C, C++ and fortran compilers to be used in the testsuite.
  381 
  382 dnl We don't want to abort our configuration script if no C compiler is
  383 dnl available, as such a compiler is only required to run part of the
  384 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
  385 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
  386 dnl easy way to obtain this behaviour, so we'll need a few hacks.
  387 
  388 dnl We want the body of this macro to expand as a single shell statement,
  389 dnl thus we wrap it into { ... } brackets.
  390 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
  391   AC_MSG_WARN([$1])
  392   am__failed=yes
  393   break
  394 } ])
  395 
  396 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
  397   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
  398   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
  399   am__failed=no
  400   while :; do
  401      $1
  402      break
  403   done
  404   AS_IF([test $am__failed = yes], [$2])
  405   # We have to clear these cache variables, so that future checks on
  406   # compilers for different languages won't be confused.
  407   unset ac_cv_objext ac_cv_exeext
  408   # We also need to meddle with the autoconf internals to ensure that
  409   # checks to find object and executable extensions will be run anew.
  410   # FIXME: In the long run, the better thing to do would be to fix
  411   # FIXME: autoconf instead ...
  412   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
  413   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
  414   m4_popdef([AC_MSG_FAILURE])
  415   m4_popdef([AC_MSG_ERROR])
  416 ])
  417 
  418 AC_DEFUN([_AM_SKIP_COMP_TESTS],
  419   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
  420 
  421 # Prefer generic compilers to GNU ones when possible.  This will ensure
  422 # more testsuite coverage "in the wild".
  423 # Note that we don't look for the MSVC C/C++ compiler here.  This is
  424 # deliberate; for more discussion and rationale, see:
  425 # <https://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
  426 
  427 AC_MSG_NOTICE([will now look for generic compilers])
  428 
  429 # C compiler.
  430 _AM_COMPILER_CAN_FAIL(dnl
  431   [AC_PROG_CC([cc gcc])],
  432   [CC=false; _AM_SKIP_COMP_TESTS([C])])
  433 
  434 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
  435 
  436 # On case-insensitive file systems (seen e.g. on Cygwin and Mac OS X)
  437 # we must avoid looking for 'CC', because that would be the same as
  438 # 'cc', and could cause $CXX to point to the C compiler, instead of
  439 # to a C++ compiler as expected (see automake bugs #11893 and #10766).
  440 # Similarly, we must avoid looking for 'RCC', as that can point to the
  441 # Qt4 "Resource Compiler": <http://doc.qt.digia.com/4.2/rcc.html>
  442 if test -f /bIn/rMdIr || test -f /uSr/bIn/rMdIr; then
  443   # Case-insensitive file system, don't look for CC.
  444   am_CC= am_RCC=
  445 else
  446   am_CC=CC am_RCC=RCC
  447 fi
  448 
  449 # The list of C++ compilers here has been copied, pasted and edited
  450 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
  451 # Keep it in sync, or better again, find out a way to avoid this code
  452 # duplication.
  453 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
  454   [aCC $am_CC FCC KCC $am_RCC xlC_r xlC c++ cxx cc++ gpp g++])],
  455   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
  456 
  457 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
  458 
  459 # The lists of Fortran compilers here has been copied, pasted and edited
  460 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
  461 # Keep it in sync, or better again, find out a way to avoid this code
  462 # duplication.
  463 
  464 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
  465   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
  466   [xlf90 f90 armflang flang pgf90 pghpf epcf90 g95 gfortran])],
  467   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
  468 
  469 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
  470 
  471 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
  472   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 armflang flang gfortran])],
  473   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
  474 
  475 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
  476 
  477 # Some tests will need the GNU compilers.  Searching for them here would
  478 # be overkill, since our testsuite already handles their search and setup
  479 # pretty well.  But in case the compilers already found are the GNU ones,
  480 # we want to use them in the testsuite where GNU compilers are required.
  481 # Also, in case the compilers detected above (at configure time) are not
  482 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
  483 # FFLAGS detected for them with the GNU compilers too, since it's likely
  484 # they won't be compatible.  So we allow the user to define variants of
  485 # these variables for the GNU compilers separately.
  486 
  487 AC_MSG_NOTICE([will now look for GNU compilers])
  488 
  489 # GNU C compiler.
  490 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
  491 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
  492 if test $am_CC_is_GNU = yes; then
  493   AC_MSG_NOTICE([$CC is already a GNU C compiler])
  494   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
  495 else
  496   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
  497 fi
  498 if test "$GNU_CC" != false; then
  499   AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
  500         [AC_MSG_WARN([botched installation for GNU C compiler])
  501          _AM_SKIP_COMP_TESTS([GNU C])])
  502 fi
  503 
  504 # GNU C++ compiler.
  505 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
  506 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
  507 if test $am_CXX_is_GNU = yes; then
  508   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
  509   GNU_CXX=$CXX
  510   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
  511 else
  512   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
  513 fi
  514 if test "$GNU_CXX" != false; then
  515   AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
  516         [AC_MSG_WARN([botched installation for GNU C++ compiler])
  517          _AM_SKIP_COMP_TESTS([GNU C++])])
  518 fi
  519 
  520 # GNU Fortran compiler.
  521 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
  522 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
  523 if test $am_FC_is_GNU = yes; then
  524   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
  525   GNU_FC=$FC
  526   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
  527 else
  528   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
  529 fi
  530 if test "$GNU_FC" != false; then
  531   AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
  532         [AC_MSG_WARN([botched installation for GNU Fortran compiler])
  533          _AM_SKIP_COMP_TESTS([GNU Fortran])])
  534 fi
  535 
  536 # GNU Fortran 77 compiler.
  537 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
  538 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
  539 if test $am_F77_is_GNU = yes; then
  540   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
  541   GNU_F77=$F77
  542   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
  543 else
  544   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
  545 fi
  546 if test "$GNU_F77" != false; then
  547   AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
  548         [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
  549         _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
  550 fi
  551 
  552 # GNU Java compiler.
  553 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
  554 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
  555 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
  556 if test "$GNU_GCJ" != false; then
  557   AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
  558         [AC_MSG_WARN([botched installation for GNU Java compiler])
  559         _AM_SKIP_COMP_TESTS([GNU Java])])
  560 fi
  561 
  562 # If we have been able to find at least a working compiler above, we
  563 # know what the object and executable extensions for this platform are.
  564 OBJEXT=${ac_cv_objext-UNKNOWN}
  565 EXEEXT=${ac_cv_exeext-UNKNOWN}
  566 AC_SUBST([OBJEXT])
  567 AC_SUBST([EXEEXT])
  568 
  569 ###########################################################################
  570 
  571 ## ---------------------- ##
  572 ##  Create output files.  ##
  573 ## ---------------------- ##
  574 
  575 AC_CONFIG_FILES([Makefile])
  576 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
  577 AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
  578 AC_OUTPUT
  579 
  580 # Inform the user if this version of automake is a beta release or
  581 # a development snapshot.
  582 # According to HACKING, the version of a development snapshot should
  583 # end with an "odd" letter (a, c, ...), the version of a test release
  584 # should end wit an "even" letter (b, d, ...).
  585 
  586 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
  587 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
  588 
  589 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
  590   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
  591   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
  592   { print \"development snapshot\"; }"]`
  593 
  594 # '$silent' is set to yes if configure is passed the '--quiet' option.
  595 test "$am_release_type" = stable || test "$silent" = yes || cat <<EOF
  596 
  597 WARNING: You are about to use a $am_release_type of automake.
  598 WARNING: It might easily suffer from new bugs or regressions.
  599 WARNING: You are strongly advised not to use it in production code.
  600 
  601 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
  602 EOF
  603 
  604 AS_EXIT([0])