"Fossies" - the Fresh Open Source Software Archive

Member "auctex-12.3/style/minted.el" (18 Oct 2020, 18604 Bytes) of package /linux/misc/auctex-12.3.tar.gz:


As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) Lisp source code syntax highlighting (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "minted.el": 12.2_vs_12.3.

    1 ;;; minted.el --- AUCTeX style for `minted.sty' (v2.5)
    2 
    3 ;; Copyright (C) 2014-2018, 2020 Free Software Foundation, Inc.
    4 
    5 ;; Author: Tassilo Horn <tsdh@gnu.org>
    6 ;; Maintainer: auctex-devel@gnu.org
    7 ;; Created: 2014-12-19
    8 ;; Keywords: tex
    9 
   10 ;; This file is part of AUCTeX.
   11 
   12 ;; AUCTeX is free software; you can redistribute it and/or modify it
   13 ;; under the terms of the GNU General Public License as published by
   14 ;; the Free Software Foundation; either version 3, or (at your option)
   15 ;; any later version.
   16 
   17 ;; AUCTeX is distributed in the hope that it will be useful, but
   18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
   19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
   20 ;; General Public License for more details.
   21 
   22 ;; You should have received a copy of the GNU General Public License
   23 ;; along with AUCTeX; see the file COPYING.  If not, write to the Free
   24 ;; Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA
   25 ;; 02110-1301, USA.
   26 
   27 ;;; Commentary:
   28 
   29 ;; This file adds support for `minted.sty' (v2.5) from 2017/07/19.
   30 
   31 ;;; Code:
   32 
   33 (require 'tex)
   34 
   35 ;; Silence the compiler:
   36 (declare-function font-latex-add-keywords
   37           "font-latex"
   38           (keywords class))
   39 
   40 (declare-function font-latex-set-syntactic-keywords
   41           "font-latex")
   42 
   43 (declare-function LaTeX-color-definecolor-list "color" ())
   44 (declare-function LaTeX-xcolor-definecolor-list "xcolor" ())
   45 (declare-function LaTeX-add-newfloat-DeclareFloatingEnvironments
   46           "newfloat" (&rest newfloat-declarefloatingenvironments))
   47 
   48 (defvar font-latex-syntactic-keywords-extra)
   49 
   50 (defvar LaTeX-minted-key-val-options
   51   '(("autogobble" ("true" "false"))
   52     ("baselinestretch" ("auto"))
   53     ("beameroverlays" ("true" "false"))
   54     ("breakafter")
   55     ("breakaftergroup" ("true" "false"))
   56     ("breakaftersymbolpre")
   57     ("breakaftersymbolpost")
   58     ("breakanywhere" ("true" "false"))
   59     ("breakanywheresymbolpre")
   60     ("breakanywheresymbolpost")
   61     ("breakautoindent" ("true" "false"))
   62     ("breakbefore")
   63     ("breakbeforegroup" ("true" "false"))
   64     ("breakbeforesymbolpre")
   65     ("breakbeforesymbolpost")
   66     ("breakbytoken" ("true" "false"))
   67     ("breakbytokenanywhere" ("true" "false"))
   68     ("breakindent")
   69     ("breakindentnchars")
   70     ("breaklines" ("true" "false"))
   71     ("breaksymbol")
   72     ("breaksymbolleft")
   73     ("breaksymbolright")
   74     ("breaksymbolindent")
   75     ("breaksymbolindentnchars")
   76     ("breaksymbolindentleft")
   77     ("breaksymbolindentleftnchars")
   78     ("breaksymbolindentright")
   79     ("breaksymbolseprightnchars")
   80     ("breaksymbolsep")
   81     ("breaksymbolsepnchars")
   82     ("breaksymbolsepleft")
   83     ("breaksymbolsepleftnchars")
   84     ("breaksymbolsepright")
   85     ("breaksymbolseprightnchars")
   86     ("bgcolor")
   87     ("codetagify")
   88     ("curlyquotes" ("true" "false"))
   89     ("encoding")
   90     ("escapeinside")
   91     ("firstline")
   92     ("firstnumber" ("auto" "last" "integer"))
   93     ("fontfamily" ("tt" "courier" "helvetica"))
   94     ("fontseries" ("auto"))
   95     ("fontsize" ("auto" "\\tiny" "\\large" "\\scriptsize" "\\Large"
   96          "\\footnotesize" "\\LARGE" "\\small" "\\huge"
   97          "\\normalsize" "\\Huge"))
   98     ("fontshape" ("auto"))
   99     ("formatcom")
  100     ("frame" ("none" "leftline" "topline" "bottomline" "lines" "single"))
  101     ("framerule")
  102     ("framesep")
  103     ("funcnamehighlighting" ("true" "false"))
  104     ("gobble")
  105     ("highlightcolor")
  106     ("highlightlines")
  107     ("keywordcase" ("lower" "upper" "capitalize"))
  108     ("label")
  109     ("labelposition" ("none" "topline" "bottomline" "all"))
  110     ("lastline")
  111     ("linenos" ("true" "false"))
  112     ("numberfirstline" ("true" "false"))
  113     ("numbers" ("left" "right" "both" "none"))
  114     ("mathescape" ("true" "false"))
  115     ("numberblanklines" ("true" "false"))
  116     ("numbersep")
  117     ("obeytabs" ("true" "false"))
  118     ("outencoding")
  119     ("python3" ("true" "false"))
  120     ("resetmargins" ("true" "false"))
  121     ("rulecolor")
  122     ("samepage" ("true" "false"))
  123     ("showspaces" ("true" "false"))
  124     ("showtabs" ("true" "false"))
  125     ("space")
  126     ("spacecolor")
  127     ("startinline" ("true" "false"))
  128     ;; FIXME: It would be nice to use the function
  129     ;; `LaTeX-minted-style-list' here, but with a file local var like:
  130     ;;     %%% TeX-command-extra-options: "-shell-escape"
  131     ;; in a .tex file, Emacs asks to apply a variable which is not
  132     ;; safe and does not restore the frame; the splitted frame
  133     ;; remains.  I couldn't figure out why, so for now, I add the
  134     ;; styles from Pygments version 2.5.2 here.
  135     ("style" ("abap" "algol" "algol_nu" "arduino" "autumn"
  136           "borland" "bw" "colorful" "default" "emacs"
  137           "friendly" "fruity" "igor" "inkpot" "lovelace"
  138           "manni" "monokai" "murphy" "native" "paraiso-dark"
  139           "paraiso-light" "pastie" "perldoc"
  140           "rainbow_dash" "rrt" "sas"
  141           "solarized-dark" "solarized-light" "stata"
  142           "stata-dark" "stata-light"
  143           "tango" "trac" "vim" "vs" "xcode"))
  144     ("stepnumber")
  145     ("stepnumberfromfirst")
  146     ("stepnumberoffsetvalues" ("true" "false"))
  147     ("stripall" ("true" "false"))
  148     ("stripnl" ("true" "false"))
  149     ("tab")
  150     ("tabcolor")
  151     ("tabsize")
  152     ("texcl" ("true" "false"))
  153     ("texcomments" ("true" "false"))
  154     ("xleftmargin")
  155     ("xrightmargin"))
  156   "Key=value options for minted macros and environments.")
  157 
  158 (defvar LaTeX-minted-key-val-options-local nil
  159   "Buffer-local key=value options for minted macros and environments.")
  160 (make-variable-buffer-local 'LaTeX-minted-key-val-options-local)
  161 
  162 (defvar LaTeX-minted-pygmentize-program (executable-find "pygmentize"))
  163 
  164 (defvar LaTeX-minted-language-list nil
  165   "List containing languages provided by pymentize program.")
  166 
  167 (defun LaTeX-minted-language-list (&rest _ignored)
  168   "Return a list of languages provided by pymentize program.
  169 Update the variable `LaTeX-minted-language-list' if still nil."
  170   (or LaTeX-minted-language-list
  171       (when LaTeX-minted-pygmentize-program
  172     (with-temp-buffer
  173       (shell-command (concat LaTeX-minted-pygmentize-program " -L lexers")
  174              (current-buffer))
  175       (goto-char (point-min))
  176       (let (languages)
  177         (while (re-search-forward "^\\*[[:space:]]\\([^:]+\\):" nil t)
  178           (dolist (lang (split-string (match-string 1) "[[:space:],]" t))
  179         (push lang languages)))
  180         (setq LaTeX-minted-language-list languages))
  181       LaTeX-minted-language-list))))
  182 
  183 (defun LaTeX-arg-minted-language (optional &optional prompt)
  184     "Insert a selected pygmentize language as argument for macros from minted.sty.
  185 If OPTIONAL is non-nil, insert it as optional argument in
  186 brackets.  PROMPT replaces the standard one."
  187   (TeX-argument-insert
  188    (completing-read (TeX-argument-prompt optional prompt "Language")
  189             (LaTeX-minted-language-list))
  190    optional))
  191 
  192 (defvar LaTeX-minted-style-list nil
  193   "List containing styles provided by pymentize program.")
  194 
  195 (defun LaTeX-minted-style-list (&rest _ignored)
  196   "Return a list of styles provided by pymentize program.
  197 Update the variable `LaTeX-minted-style-list' if still nil."
  198   (or LaTeX-minted-style-list
  199       (when LaTeX-minted-pygmentize-program
  200     (with-temp-buffer
  201       (shell-command (concat LaTeX-minted-pygmentize-program " -L styles")
  202              (current-buffer))
  203       (goto-char (point-min))
  204       (let (styles)
  205         (while (re-search-forward "^\\*[[:space:]]\\([^:]+\\):" nil t)
  206           (dolist (style (split-string (match-string 1) "[[:space:],]" t))
  207         (push style styles)))
  208         (setq LaTeX-minted-style-list styles))
  209       LaTeX-minted-style-list))))
  210 
  211 (defun LaTeX-arg-minted-style (optional &optional prompt)
  212   "Insert a selected pygmentize style as argument for macros from minted.sty.
  213 If OPTIONAL is non-nil, insert it as optional argument in
  214 brackets.  PROMPT replaces the standard one."
  215   (TeX-argument-insert
  216    (completing-read (TeX-argument-prompt optional prompt "Style")
  217             (LaTeX-minted-style-list))
  218    optional))
  219 
  220 (defun LaTeX-minted-update-key-vals ()
  221   "Update color related key-vals in `LaTeX-minted-key-val-options-local'.
  222 This function checks if one of the packages \"xcolor.sty\" or
  223 \"xcolor.sty\" is loaded and appends defined colors as values to
  224 color related key.  \"xcolor.sty\" is preferred if both packages
  225 are loaded."
  226   (when (or (member "xcolor" (TeX-style-list))
  227         (member "color" (TeX-style-list)))
  228     (let* ((colorcmd (if (member "xcolor" (TeX-style-list))
  229              #'LaTeX-xcolor-definecolor-list
  230                #'LaTeX-color-definecolor-list))
  231        (colorkeys '("bgcolor" "highlightcolor"
  232             "rulecolor" "spacecolor" "tabcolor"))
  233        (opts (copy-alist LaTeX-minted-key-val-options-local)))
  234       (dolist (key colorkeys)
  235     (setq opts (assq-delete-all (car (assoc key opts)) opts))
  236     (push (list key (mapcar #'car (funcall colorcmd)))
  237           opts))
  238       (setq LaTeX-minted-key-val-options-local
  239         (copy-alist opts)))))
  240 
  241 (defvar LaTeX-minted-auto-newminted nil)
  242 (defvar LaTeX-minted-newminted-regexp
  243   '("\\\\newminted\\(?:\\[\\([^]]+\\)\\]\\)?{\\([^}]+\\)}{[^}]*}"
  244     (1 2) LaTeX-minted-auto-newminted))
  245 
  246 (defvar LaTeX-minted-auto-newmint nil)
  247 (defvar LaTeX-minted-newmint-regexp
  248   '("\\\\newmint\\(?:\\[\\([^]]+\\)\\]\\)?{\\([^}]+\\)}{[^}]*}"
  249     (1 2) LaTeX-minted-auto-newmint))
  250 
  251 (defvar LaTeX-minted-auto-newmintinline nil)
  252 (defvar LaTeX-minted-newmintinline-regexp
  253   '("\\\\newmintinline\\(?:\\[\\([^]]+\\)\\]\\)?{\\([^}]+\\)}{[^}]*}"
  254     (1 2) LaTeX-minted-auto-newmintinline))
  255 
  256 (defvar LaTeX-minted-auto-newmintedfile nil)
  257 (defvar LaTeX-minted-newmintedfile-regexp
  258   '("\\\\newmintedfile\\(?:\\[\\([^]]+\\)\\]\\)?{\\([^}]+\\)}{[^}]*}"
  259     (1 2) LaTeX-minted-auto-newmintedfile))
  260 
  261 (defun LaTeX-minted-auto-prepare ()
  262   (setq LaTeX-minted-auto-newminted     nil
  263     LaTeX-minted-auto-newmint       nil
  264     LaTeX-minted-auto-newmintinline nil
  265     LaTeX-minted-auto-newmintedfile nil
  266     LaTeX-minted-language-list      nil
  267     LaTeX-minted-style-list         nil))
  268 
  269 (defun LaTeX-minted-auto-cleanup ()
  270   ;; \newminted{lang}{opts} => new langcode and langcode* envs.
  271   ;; \newminted[envname]{lang}{opts} => new envname/envname* envs.
  272   (dolist (name-lang LaTeX-minted-auto-newminted)
  273     (let* ((env (if (> (length (car name-lang)) 0)
  274             (car name-lang)
  275           (concat (cadr name-lang) "code")))
  276        (env* (concat env "*")))
  277       (add-to-list 'LaTeX-auto-environment (list env))
  278       (add-to-list 'LaTeX-auto-environment
  279            (list env* 'LaTeX-env-args
  280              '(TeX-arg-key-val LaTeX-minted-key-val-options-local)))
  281       (add-to-list 'LaTeX-indent-environment-list `(,env current-indentation) t)
  282       (add-to-list 'LaTeX-indent-environment-list `(,env* current-indentation) t)
  283       (add-to-list 'LaTeX-verbatim-environments-local env)
  284       (add-to-list 'LaTeX-verbatim-environments-local env*)))
  285   ;; \newmint{foo}{opts} => \foo[key=vals]|code|
  286   ;; \newmint[macname]{foo}{opts} => \macname[key=vals]|code|
  287   (dolist (name-lang LaTeX-minted-auto-newmint)
  288     (let ((lang (if (> (length (car name-lang)) 0)
  289             (car name-lang)
  290           (cadr name-lang))))
  291       (add-to-list 'TeX-auto-symbol
  292            `(,lang [ TeX-arg-key-val LaTeX-minted-key-val-options-local ]
  293                TeX-arg-verb))
  294       (add-to-list 'LaTeX-verbatim-macros-with-delims-local lang)
  295       (when (and (fboundp 'font-latex-add-keywords)
  296          (eq TeX-install-font-lock 'font-latex-setup))
  297     (font-latex-add-keywords `((,lang "[")) 'textual))))
  298   ;; \newmintinline{foo}{opts} => \fooinline[key=vals]|code| or
  299   ;;                              \fooinline[key=vals]{code}
  300   ;; \newmintinline[macname]{foo}{opts} => \macname[key=vals]|code| or
  301   ;;                                       \macname[key=vals]{code}
  302   (dolist (name-lang LaTeX-minted-auto-newmintinline)
  303     (let ((lang (if (> (length (car name-lang)) 0)
  304             (car name-lang)
  305           (concat (cadr name-lang) "inline"))))
  306       (add-to-list 'TeX-auto-symbol
  307            `(,lang [ TeX-arg-key-val LaTeX-minted-key-val-options-local ]
  308                TeX-arg-verb-delim-or-brace))
  309       (add-to-list 'LaTeX-verbatim-macros-with-delims-local lang)
  310       (add-to-list 'LaTeX-verbatim-macros-with-braces-local lang)
  311       (when (and (fboundp 'font-latex-add-keywords)
  312          (eq TeX-install-font-lock 'font-latex-setup))
  313     (font-latex-add-keywords `((,lang "[")) 'textual))))
  314   ;; \newmintedfile{foo}{opts} => \foofile[key=vals]{file-name}
  315   ;; \newmintedfile[macname]{foo}{opts} => \macname[key=vals]{file-name}
  316   (dolist (name-lang LaTeX-minted-auto-newmintedfile)
  317     (let ((lang (if (> (length (car name-lang)) 0)
  318             (car name-lang)
  319           (concat (cadr name-lang) "file"))))
  320       (add-to-list 'TeX-auto-symbol
  321            `(,lang [ TeX-arg-key-val LaTeX-minted-key-val-options-local ]
  322                TeX-arg-file))))
  323   (when (and (fboundp 'font-latex-set-syntactic-keywords)
  324          (eq TeX-install-font-lock 'font-latex-setup))
  325     ;; Refresh font-locking so that the verbatim envs take effect.
  326     (font-latex-set-syntactic-keywords))
  327   ;; Also update the key=vals
  328   (LaTeX-minted-update-key-vals))
  329 
  330 (add-hook 'TeX-auto-prepare-hook #'LaTeX-minted-auto-prepare t)
  331 (add-hook 'TeX-auto-cleanup-hook #'LaTeX-minted-auto-cleanup t)
  332 (add-hook 'TeX-update-style-hook #'TeX-auto-parse t)
  333 
  334 (defun LaTeX-minted-add-syntactic-keywords-extra (type macro)
  335   "Add MACRO from minted.sty to `font-latex-syntactic-keywords-extra'.
  336 TYPE is one of the symbols `brace' or `delim' indicating how
  337 verbatim text is enclosed after the macro.  MACRO is a string or
  338 a list of strings."
  339   (let ((syntax (if (eq type 'brace)
  340             '((1 "|") (2 "|"))
  341           '((1 "\"") (2 ".") (3 "\""))))
  342     regexp)
  343     (when (listp macro)
  344       (setq macro (regexp-opt macro "\\(?:")))
  345     (setq regexp `(,(concat
  346              ;; The backslash
  347              (regexp-quote TeX-esc)
  348              ;; Name of the macro(s)
  349              macro
  350              ;; The optional argument
  351              "\\(?:\\[[^][]*\\(?:\\[[^][]*\\][^][]*\\)*\\]\\)?"
  352              ;; The first mandatory argument
  353              "\\(?:{[^}]+}\\)"
  354              ;; With 'brace, allow braced sub-groups otherwise
  355              ;; we stop matching too early.  With 'delim, copy
  356              ;; font-latex.el:
  357              (if (eq type 'brace)
  358              (concat "\\({\\)"
  359                    "\\(?:[^}{]*"
  360                      "\\(?:{[^}{]*"
  361                        "\\(?:{[^}{]*"
  362                      "\\(?:{[^}{]*}[^}{]*\\)*"
  363                        "}[^}{]*\\)*"
  364                      "}[^}{]*\\)*"
  365                    "\\)"
  366                  "\\(}\\)")
  367                (concat
  368             ;; Opening delimiter
  369             "\\([^a-z@*\n\f{]\\).*?"
  370             ;; Closing delimiter
  371             "\\(" (regexp-quote TeX-esc) "*\\)\\(\\1\\)")))))
  372     (add-to-list 'font-latex-syntactic-keywords-extra (append regexp syntax))))
  373 
  374 (TeX-add-style-hook
  375  "minted"
  376  (lambda ()
  377 
  378    ;; Activate local-version of key=vals
  379    (setq LaTeX-minted-key-val-options-local
  380      (copy-alist LaTeX-minted-key-val-options))
  381 
  382    ;; New symbols
  383    (TeX-add-symbols
  384     '("mint"
  385       [ TeX-arg-key-val LaTeX-minted-key-val-options-local ]
  386       LaTeX-arg-minted-language TeX-arg-verb)
  387     '("mintinline"
  388       [ TeX-arg-key-val LaTeX-minted-key-val-options-local ]
  389       LaTeX-arg-minted-language TeX-arg-verb-delim-or-brace)
  390     '("newminted" ["Environment Name"] LaTeX-arg-minted-language
  391       (TeX-arg-key-val LaTeX-minted-key-val-options-local))
  392     '("newmint" ["Macro Name"] LaTeX-arg-minted-language
  393       (TeX-arg-key-val LaTeX-minted-key-val-options-local))
  394     '("newmintinline" ["Macro Name"] LaTeX-arg-minted-language
  395       (TeX-arg-key-val LaTeX-minted-key-val-options-local))
  396     '("newmintedfile" ["Macro Name"] LaTeX-arg-minted-language
  397       (TeX-arg-key-val LaTeX-minted-key-val-options-local))
  398     ;; 3.3 Formatting source code
  399     '("inputminted"
  400       [ TeX-arg-key-val LaTeX-minted-key-val-options-local ]
  401       (LaTeX-arg-minted-language)
  402       TeX-arg-file)
  403     ;; 3.4 Using different styles
  404     '("usemintedstyle"
  405       [ LaTeX-arg-minted-language ] LaTeX-arg-minted-style)
  406     ;; 5.2 Macro option usage
  407     '("setminted"
  408       [ LaTeX-arg-minted-language ]
  409       (TeX-arg-key-val LaTeX-minted-key-val-options-local))
  410     '("setmintedinline"
  411       [ LaTeX-arg-minted-language ]
  412       (TeX-arg-key-val LaTeX-minted-key-val-options-local)))
  413 
  414    ;; New environments
  415    (LaTeX-add-environments
  416     '("minted" LaTeX-env-args [TeX-arg-key-val LaTeX-minted-key-val-options-local]
  417       LaTeX-arg-minted-language))
  418 
  419    ;; 4 Floating listings: If option "newfloat" is given, run the
  420    ;; style hook and use the interface provided by the style,
  421    ;; otherwise add "listing" manually
  422    (if (or (LaTeX-provided-package-options-member "minted" "newfloat")
  423        (LaTeX-provided-package-options-member "minted" "newfloat=true"))
  424        (progn
  425      (TeX-run-style-hooks "newfloat")
  426      (LaTeX-add-newfloat-DeclareFloatingEnvironments
  427       '("listing" "verbatim")))
  428      (LaTeX-add-environments '("listing" ["Float Position"]))
  429      (TeX-add-symbols '("listoflistings")
  430               '("listingscaption")
  431               '("listoflistingscaption"))
  432      (add-to-list (make-local-variable 'LaTeX-indent-environment-list)
  433           '("listing" current-indentation) t)
  434      (add-to-list 'LaTeX-label-alist '("listing" . LaTeX-listing-label) t)
  435      (when (fboundp 'reftex-add-label-environments)
  436        (reftex-add-label-environments
  437     '(("listing" ?l "lst:" "~\\ref{%s}" caption nil nil)))))
  438 
  439    ;; Add to the auto parser
  440    (TeX-auto-add-regexp LaTeX-minted-newminted-regexp)
  441    (TeX-auto-add-regexp LaTeX-minted-newmint-regexp)
  442    (TeX-auto-add-regexp LaTeX-minted-newmintinline-regexp)
  443    (TeX-auto-add-regexp LaTeX-minted-newmintedfile-regexp)
  444 
  445    ;; Filling
  446    (add-to-list (make-local-variable 'LaTeX-indent-environment-list)
  447         '("minted" current-indentation) t)
  448    (add-to-list 'LaTeX-verbatim-environments-local "minted")
  449 
  450    ;; Fontification
  451    (when (and (fboundp 'font-latex-add-keywords)
  452           (eq TeX-install-font-lock 'font-latex-setup))
  453      (font-latex-add-keywords '(("usemintedstyle"  "[{")
  454                 ("setminted"       "[{")
  455                 ("setmintedinline" "[{")
  456                 ("newminted"       "[{{")
  457                 ("newmint"         "[{{")
  458                 ("newmintinline"   "[{{")
  459                 ("newmintedfile"   "[{{"))
  460                   'function)
  461      (font-latex-add-keywords '(("inputminted" "[{{")
  462                 ("mint"        "[{")
  463                 ("mintinline"  "[{"))
  464                   'textual)
  465      ;; Add \mint & \mintinline to
  466      ;; `font-latex-syntactic-keywords-extra' and cater for their
  467      ;; special syntax: \mint[optional]{lang}{verbatim} or
  468      ;;                 \mint[optional]{lang}|verbatim|
  469      (LaTeX-minted-add-syntactic-keywords-extra 'brace
  470                         '("mint" "mintinline"))
  471      (LaTeX-minted-add-syntactic-keywords-extra 'delim
  472                         '("mint" "mintinline"))
  473      ;; Tell font-lock about the update.
  474      (font-latex-set-syntactic-keywords)))
  475  LaTeX-dialect)
  476 
  477 (defvar LaTeX-minted-package-options '("chapter"     "cache"
  478                        "cachedir"    "finalizecache"
  479                        "frozencache" "draft"
  480                        "final"       "kpsewhich"
  481                        "langlinenos" "newfloat"
  482                        "outputdir"   "section")
  483   "Package options for the minted package.")
  484 
  485 ;;; minted.el ends here