"Fossies" - the Fresh Open Source Software Archive

Member "auctex-12.3/configure.ac" (18 Oct 2020, 8898 Bytes) of package /linux/misc/auctex-12.3.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "configure.ac": 12.2_vs_12.3.

    1 dnl Autoconf script for AUCTeX
    2 
    3 dnl Maintainer: auctex-devel@gnu.org
    4 
    5 dnl Copyright (C) 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
    6 
    7 dnl This file is part of AUCTeX.
    8 
    9 dnl AUCTeX is free software; you can redistribute it and/or modify it
   10 dnl under the terms of the GNU General Public License as published by
   11 dnl the Free Software Foundation; either version 3, or (at your option)
   12 dnl any later version.
   13 
   14 dnl AUCTeX is distributed in the hope that it will be useful, but
   15 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
   16 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
   17 dnl General Public License for more details.
   18 
   19 dnl You should have received a copy of the GNU General Public License
   20 dnl along with AUCTeX; see the file COPYING.  If not, write to the Free
   21 dnl Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
   22 dnl MA 02110-1301, USA.
   23 
   24 AC_INIT(auctex,12.3,bug-auctex@gnu.org)
   25 
   26 AC_CHECK_PROGS_REQUIRED(MAKECMD, make, [make not found, aborting!])
   27 AC_PROG_MAKE_SET
   28 AC_PROG_INSTALL
   29 
   30 AC_DATE_VERSION_FROM_CHANGELOG(AUCTEXDATE,AUCTEXVERSION,ChangeLog.1)
   31 AC_SUBST(AUCTEXDATE)
   32 AC_SUBST(AUCTEXVERSION)
   33 
   34 AC_DATE_VERSION_FROM_CHANGELOG(PREVIEWDATE,PREVIEWVERSION,ChangeLog-preview)
   35 AC_SUBST(PREVIEWDATE)
   36 AC_SUBST(PREVIEWVERSION)
   37 
   38 EMACS_PROG_EMACS
   39 
   40 EMACS_CHECK_VERSION(24,1)
   41 
   42 # The Debian package uses `--disable-build-dir-test'; normal users should
   43 # never need to modify the default behavior.
   44 AC_ARG_ENABLE([build-dir-test],
   45   [  --enable-build-dir-test test for build directory inside `load-path'
   46 			  (on by default)],
   47   [if ! [[ "X-${enableval}" = "X-no" ]]
   48      then VALID_BUILD_DIR
   49    fi],
   50   [VALID_BUILD_DIR])
   51 
   52 AC_ARG_ENABLE(preview,
   53   [  --disable-preview       disable inclusion of preview-latex],
   54   [preview_enabled="$enableval"],
   55   [preview_enabled="yes"])
   56 AC_SUBST(preview_enabled)
   57 
   58 EMACS_PATH_LISPDIR
   59 AC_MSG_CHECKING(what file to use for auctex startup)
   60 AC_ARG_WITH(auctexstartfile,
   61 [[  --with-auctexstartfile=FILE    What file to use for auctex startup.]],
   62 [[ auctexstartfile="${withval}" ]],
   63 [ _tmpdir_="${lispdir}"
   64 AC_FULL_EXPAND(_tmpdir_)
   65 if test -d "${_tmpdir_}/site-start.d"
   66 then
   67 auctexstartfile="${lispdir}/site-start.d/auctex.el"
   68 else
   69 auctexstartfile="${lispdir}/auctex.el"
   70 fi])
   71 AC_MSG_RESULT([[${auctexstartfile}]])
   72 
   73 AC_MSG_CHECKING(what file to use for preview startup)
   74 AC_ARG_WITH(previewstartfile,
   75 [[  --with-previewstartfile=FILE    What file to use for preview startup.]],
   76 [[ previewstartfile="${withval}" ]],
   77 [ _tmpdir_="${lispdir}"
   78 AC_FULL_EXPAND(_tmpdir_)
   79 if test -d "${_tmpdir_}/site-start.d"
   80 then
   81 previewstartfile="${lispdir}/site-start.d/preview-latex.el"
   82 else
   83 previewstartfile="${lispdir}/preview-latex.el"
   84 fi])
   85 AC_MSG_RESULT([[${previewstartfile}]])
   86 
   87 packagelispdir="${lispdir}/auctex"
   88 packagedatadir="${packagelispdir}"
   89 texsitedir="${lispdir}"
   90 
   91 AC_SUBST(auctexstartfile)
   92 AC_SUBST(previewstartfile)
   93 
   94 AC_MSG_CHECKING([where the package lisp files go])
   95 AC_ARG_WITH(packagelispdir,
   96 [[  --with-packagelispdir=DIR
   97                         Directory for the package lisp files.]],
   98   [packagelispdir=["${withval}"]])
   99 AC_LISPIFY_DIR(packagelispdir,[["${texsitedir}/tex-site.el"]])
  100 AC_MSG_RESULT([[${packagelispdir}]])
  101 
  102 AC_MSG_CHECKING([where the data files go])
  103 AC_ARG_WITH(packagedatadir,
  104 [[  --with-packagedatadir=DIR         Where the data files go.]],
  105   [packagedatadir=["${withval}"]])
  106 AC_LISPIFY_DIR(packagedatadir,[["${texsitedir}/tex-site.el"]])
  107 AC_MSG_RESULT([[${packagedatadir}]])
  108 
  109 AC_LISPIFY_DIR(texsite,[["${auctexstartfile}"]],tex-site.el)
  110 
  111 AC_MSG_CHECKING(where the info files go)
  112 AC_MSG_RESULT([[${infodir}]])
  113 
  114 AUCTEX_AUTO_DIR
  115 AC_LISPIFY_DIR(autodir,"${texsitedir}/tex-site.el")
  116 
  117 AC_PATH_PROG(TEX, tex, :)
  118 AC_PATH_PROG(PDFTEX, pdftex, :)
  119 AC_PATH_PROG(DVIPS, dvips, :)
  120 
  121 
  122 dnl Preview related options.
  123 if test "X${preview_enabled}" = Xyes
  124 then
  125    AC_ARG_VAR(GS,[Ghostscript executable for batch operation])
  126    AC_CHECK_PROGS(GS, gs GSWIN32C.EXE, NONE)
  127 
  128    EMACS_LISP([[lispGS]],[[(if (member dir (list \"NONE\" (if (eq system-type 'windows-nt) \"GSWIN32C.EXE\" \"gs\"))) \"\" \`(defvar preview-gs-command ,dir))]],-no-site-file,[[dir]],[["${GS}"]])
  129    AC_SUBST(lispGS)
  130 
  131    dnl check to see if GS supports -dTextAlphaBits and -dGraphicsAlphaBits
  132    dnl Check to see if specific drivers are built in.
  133    dnl Need table of mappings, with priority
  134 
  135    AC_PATH_PROG_REQUIRED(LATEX, latex, [LaTeX not found, aborting!
  136    You must install LaTeX for preview to work.])
  137 
  138    AC_PATH_PROG(PDFLATEX, pdflatex)
  139 
  140    # Determine which latex-style components to install
  141    # To match .sty, .def, .cfg, but _not_ .drv
  142    TEXMFGEN=[`sed -n 's/^%<installer>.*file[{]\\([^}.]*\\.[sdc][tef][yfg]\\)[}].*/\\1/p' latex/preview.dtx`]
  143    # Replace newlines with spaces.
  144    TEXMFGEN="`echo ${TEXMFGEN}`"
  145    AC_SUBST(TEXMFGEN)
  146 
  147    AC_PATH_PROG_REQUIRED(TEX, tex, NONE)
  148 
  149    TEX_PATH_TEXMFDIR
  150 
  151    if test "x${texmfdir}" = "xno"
  152    then
  153      packagetexstyles="${packagedatadir}/latex"
  154      AC_LISPIFY_DIR(packagetexstyles,"${previewstartfile}")
  155      lisppackagetexstyles="(defvar preview-TeX-style-dir ${lisppackagetexstyles})"
  156      test "X${TEXHASH}" = X && TEXHASH=:
  157    else
  158      lisppackagetexstyles=
  159    fi
  160    AC_SUBST(lisppackagetexstyles)
  161 
  162    # Be very careful about assuming things about the available hash programs
  163    # MiKTeX comes with a braindead link to mktexlsr, apparently, so first
  164    # try the regular utility from them.
  165    AC_ARG_VAR(TEXHASH,[command to update the TeX filename database.
  166    Set to : to skip updating the database on installation.
  167    This is the default for --without-texmf-dir])
  168 
  169    if test "X${TEXHASH}" = "X"
  170    then
  171      AC_PATH_PROG(TEXHASH, texhash)
  172      AC_CHECK_PROG(TEXHASH, initexmf, initexmf -u)
  173      if test "X${TEXHASH}" = X
  174      then
  175         AC_PATH_PROGS(TEXHASH, mktexlsr MakeTeXls-R, :)
  176      fi
  177    fi
  178 
  179    AC_MSG_CHECKING([[for glaring installation conflicts]])
  180    exppackagelispdir="$packagelispdir"
  181    AC_FULL_EXPAND(exppackagelispdir)
  182    exppreviewstartfile="$previewstartfile"
  183    AC_FULL_EXPAND(exppreviewstartfile)
  184 
  185    EMACS_LISP(shadows,[[
  186      (concat
  187        (and (setq tmp (locate-library \"preview.elc\"))
  188             (not (string= (file-truename tmp)
  189                        (file-truename (expand-file-name \"preview.elc\"
  190                                          packagelispdir))))
  191             (format \"Conflicting previous installation in \`%s' found!\n\"
  192                     (file-name-directory tmp)))
  193        (and (setq tmp (locate-library \"preview-latex.el\"))
  194             (not (string= (file-truename tmp)
  195                           (file-truename previewstartfile)))
  196             (format \"Conflicting previous startup file \`%s' found!\n\" tmp)))]],,
  197      [[packagelispdir previewstartfile]],[["${exppackagelispdir}" "${exppreviewstartfile}"]])
  198    if test "NONE${shadows}" != NONE
  199    then
  200      conflictsmsg="Conflicts with previous installations have been detected.
  201    Please fix them before continuing.
  202    "
  203      AC_MSG_RESULT([[ouch!
  204    ]])
  205    AC_MSG_WARN([[${shadows}
  206    ]])
  207    else
  208      conflictsmsg=
  209      AC_MSG_RESULT([[probably none]])
  210    fi
  211 
  212    AC_SHELL_QUOTIFY(texmfdir)
  213    AC_SHELL_QUOTIFY(exec_prefix)
  214    AC_SHELL_QUOTIFY(libdir)
  215    AC_SHELL_QUOTIFY(previewtexmfdir)
  216    AC_SHELL_QUOTIFY(previewdocdir)
  217    AC_SHELL_QUOTIFY(previewstartfile)
  218    AC_SHELL_QUOTIFY(auctexdir)
  219    AC_SHELL_QUOTIFY(datadir)
  220    AC_SHELL_QUOTIFY(GS)
  221    AC_SHELL_QUOTIFY(TEXHASH)
  222    AC_SHELL_QUOTIFY(LATEX)
  223    AC_SHELL_QUOTIFY(PDFLATEX)
  224 fi
  225 
  226 AC_ARG_VAR(PERL,[Perl executable.  If set to :, some documentation
  227 cannot be regenerated, but installation of an unmodified tarball will
  228 succeed.])
  229 
  230 if test "x$PERL" = x
  231 then
  232    AC_PATH_PROG(PERL, perl, :)
  233 fi
  234 
  235 AC_ARG_VAR(MAKEINFO,[Makeinfo executable.  If set to :, some documentation
  236 cannot be regenerated, but installation of an unmodified tarball will
  237 succeed.])
  238 
  239 AC_PATH_PROG(MAKEINFO, makeinfo, :)
  240 AC_PATH_PROG(TEXI2HTML, texi2html, :)
  241 AC_PATH_PROG(TEXI2DVI, texi2dvi, :)
  242 AC_PATH_PROG(TEXI2PDF, texi2pdf, :)
  243 
  244 AC_ARG_VAR(INSTALL_INFO, [install-info executable.  Set to : to skip making a dir file.])
  245 
  246 if test "X${INSTALL_INFO}" = X
  247 then
  248   AC_PATH_PROG(INSTALL_INFO, install-info, :, ${PATH} /usr/sbin /sbin)
  249 fi
  250 
  251 AC_SHELL_QUOTIFY(prefix)
  252 AC_SHELL_QUOTIFY(localstatedir)
  253 AC_SHELL_QUOTIFY(packagelispdir)
  254 AC_SHELL_QUOTIFY(packagedatadir)
  255 AC_SHELL_QUOTIFY(lispdir)
  256 AC_SHELL_QUOTIFY(infodir)
  257 AC_SHELL_QUOTIFY(datadir)
  258 AC_SHELL_QUOTIFY(autodir)
  259 AC_SHELL_QUOTIFY(auctexstartfile)
  260 AC_SHELL_QUOTIFY(EMACS)
  261 AC_SHELL_QUOTIFY(INSTALL_INFO)
  262 AC_SHELL_QUOTIFY(PERL)
  263 AC_SHELL_QUOTIFY(MAKEINFO)
  264 AC_SHELL_QUOTIFY(TEX)
  265 AC_SHELL_QUOTIFY(PDFTEX)
  266 AC_SHELL_QUOTIFY(DVIPS)
  267 AC_SHELL_QUOTIFY(TEXI2HTML)
  268 AC_SHELL_QUOTIFY(TEXI2DVI)
  269 AC_SHELL_QUOTIFY(TEXI2PDF)
  270 
  271 AC_OUTPUT(Makefile tex-site.el.out:tex-site.el.in doc/Makefile auctex.el preview.el latex/Makefile)
  272 
  273 
  274 cat >&2 <<EOF
  275 
  276 Congratulations!  Configuration of AUCTeX is complete.
  277 
  278 Type "make" at the prompt to build.
  279 EOF