"Fossies" - the Fresh Open Source Software Archive 
Member "apache-log4j-2.12.4-src/mvnw.cmd" (20 Dec 2021, 5279 Bytes) of package /linux/misc/apache-log4j-2.12.4-src.tar.gz:
As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) MS DOS Batch source code syntax highlighting (style:
standard) with prefixed line numbers.
Alternatively you can here
view or
download the uninterpreted source code file.
See also the last
Fossies "Diffs" side-by-side code changes report for "mvnw.cmd":
2.19.0_vs_2.20.0.
1 @REM ----------------------------------------------------------------------------
2 @REM Licensed to the Apache Software Foundation (ASF) under one
3 @REM or more contributor license agreements. See the NOTICE file
4 @REM distributed with this work for additional information
5 @REM regarding copyright ownership. The ASF licenses this file
6 @REM to you under the Apache License, Version 2.0 (the
7 @REM "License"); you may not use this file except in compliance
8 @REM with the License. You may obtain a copy of the License at
9 @REM
10 @REM http://www.apache.org/licenses/LICENSE-2.0
11 @REM
12 @REM Unless required by applicable law or agreed to in writing,
13 @REM software distributed under the License is distributed on an
14 @REM "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
15 @REM KIND, either express or implied. See the License for the
16 @REM specific language governing permissions and limitations
17 @REM under the License.
18 @REM ----------------------------------------------------------------------------
19
20 @REM ----------------------------------------------------------------------------
21 @REM Maven2 Start Up Batch script
22 @REM
23 @REM Required ENV vars:
24 @REM JAVA_HOME - location of a JDK home dir
25 @REM
26 @REM Optional ENV vars
27 @REM M2_HOME - location of maven2's installed home dir
28 @REM MAVEN_BATCH_ECHO - set to 'on' to enable the echoing of the batch commands
29 @REM MAVEN_BATCH_PAUSE - set to 'on' to wait for a key stroke before ending
30 @REM MAVEN_OPTS - parameters passed to the Java VM when running Maven
31 @REM e.g. to debug Maven itself, use
32 @REM set MAVEN_OPTS=-Xdebug -Xrunjdwp:transport=dt_socket,server=y,suspend=y,address=8000
33 @REM MAVEN_SKIP_RC - flag to disable loading of mavenrc files
34 @REM ----------------------------------------------------------------------------
35
36 @REM Begin all REM lines with '@' in case MAVEN_BATCH_ECHO is 'on'
37 @echo off
38 @REM enable echoing my setting MAVEN_BATCH_ECHO to 'on'
39 @if "%MAVEN_BATCH_ECHO%" == "on" echo %MAVEN_BATCH_ECHO%
40
41 @REM set %HOME% to equivalent of $HOME
42 if "%HOME%" == "" (set "HOME=%HOMEDRIVE%%HOMEPATH%")
43
44 @REM Execute a user defined script before this one
45 if not "%MAVEN_SKIP_RC%" == "" goto skipRcPre
46 @REM check for pre script, once with legacy .bat ending and once with .cmd ending
47 if exist "%HOME%\mavenrc_pre.bat" call "%HOME%\mavenrc_pre.bat"
48 if exist "%HOME%\mavenrc_pre.cmd" call "%HOME%\mavenrc_pre.cmd"
49 :skipRcPre
50
51 @setlocal
52
53 set ERROR_CODE=0
54
55 @REM To isolate internal variables from possible post scripts, we use another setlocal
56 @setlocal
57
58 @REM ==== START VALIDATION ====
59 if not "%JAVA_HOME%" == "" goto OkJHome
60
61 echo.
62 echo Error: JAVA_HOME not found in your environment. >&2
63 echo Please set the JAVA_HOME variable in your environment to match the >&2
64 echo location of your Java installation. >&2
65 echo.
66 goto error
67
68 :OkJHome
69 if exist "%JAVA_HOME%\bin\java.exe" goto init
70
71 echo.
72 echo Error: JAVA_HOME is set to an invalid directory. >&2
73 echo JAVA_HOME = "%JAVA_HOME%" >&2
74 echo Please set the JAVA_HOME variable in your environment to match the >&2
75 echo location of your Java installation. >&2
76 echo.
77 goto error
78
79 @REM ==== END VALIDATION ====
80
81 :init
82
83 set MAVEN_CMD_LINE_ARGS=%MAVEN_CONFIG% %*
84
85 @REM Find the project base dir, i.e. the directory that contains the folder ".mvn".
86 @REM Fallback to current working directory if not found.
87
88 set MAVEN_PROJECTBASEDIR=%MAVEN_BASEDIR%
89 IF NOT "%MAVEN_PROJECTBASEDIR%"=="" goto endDetectBaseDir
90
91 set EXEC_DIR=%CD%
92 set WDIR=%EXEC_DIR%
93 :findBaseDir
94 IF EXIST "%WDIR%"\.mvn goto baseDirFound
95 cd ..
96 IF "%WDIR%"=="%CD%" goto baseDirNotFound
97 set WDIR=%CD%
98 goto findBaseDir
99
100 :baseDirFound
101 set MAVEN_PROJECTBASEDIR=%WDIR%
102 cd "%EXEC_DIR%"
103 goto endDetectBaseDir
104
105 :baseDirNotFound
106 set MAVEN_PROJECTBASEDIR=%EXEC_DIR%
107 cd "%EXEC_DIR%"
108
109 :endDetectBaseDir
110
111 IF NOT EXIST "%MAVEN_PROJECTBASEDIR%\.mvn\jvm.config" goto endReadAdditionalConfig
112
113 @setlocal EnableExtensions EnableDelayedExpansion
114 for /F "usebackq delims=" %%a in ("%MAVEN_PROJECTBASEDIR%\.mvn\jvm.config") do set JVM_CONFIG_MAVEN_PROPS=!JVM_CONFIG_MAVEN_PROPS! %%a
115 @endlocal & set JVM_CONFIG_MAVEN_PROPS=%JVM_CONFIG_MAVEN_PROPS%
116
117 :endReadAdditionalConfig
118
119 SET MAVEN_JAVA_EXE="%JAVA_HOME%\bin\java.exe"
120
121 set WRAPPER_JAR=""%MAVEN_PROJECTBASEDIR%\.mvn\wrapper\maven-wrapper.jar""
122 set WRAPPER_LAUNCHER=org.apache.maven.wrapper.MavenWrapperMain
123
124 @REM avoid using MAVEN_CMD_LINE_ARGS below since that would lose parameter escaping in %*
125 "%MAVEN_JAVA_EXE%" %JVM_CONFIG_MAVEN_PROPS% %MAVEN_OPTS% %MAVEN_DEBUG_OPTS% -classpath "%WRAPPER_JAR%" "-Dmaven.multiModuleProjectDirectory=%MAVEN_PROJECTBASEDIR%" %WRAPPER_LAUNCHER% %MAVEN_CONFIG% %*
126 if ERRORLEVEL 1 goto error
127 goto end
128
129 :error
130 set ERROR_CODE=1
131
132 :end
133 @endlocal & set ERROR_CODE=%ERROR_CODE%
134
135 if not "%MAVEN_SKIP_RC%" == "" goto skipRcPost
136 @REM check for post script, once with legacy .bat ending and once with .cmd ending
137 if exist "%HOME%\mavenrc_post.bat" call "%HOME%\mavenrc_post.bat"
138 if exist "%HOME%\mavenrc_post.cmd" call "%HOME%\mavenrc_post.cmd"
139 :skipRcPost
140
141 @REM pause the script if MAVEN_BATCH_PAUSE is set to 'on'
142 if "%MAVEN_BATCH_PAUSE%" == "on" pause
143
144 if "%MAVEN_TERMINATE_CMD%" == "on" exit %ERROR_CODE%
145
146 exit /B %ERROR_CODE%