"Fossies" - the Fresh Open Source Software Archive

Member "TeXmacs-2.1.2-src/packages/windows/TeXmacs.iss" (5 May 2022, 2732 Bytes) of package /linux/misc/TeXmacs-2.1.2-src.tar.gz:

As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) Inno Setup source code syntax highlighting (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "TeXmacs.iss": 2.1.1_vs_2.1.2.

    1 ; -- TeXmacs.iss --
    2 ; Inno Setup configuration file for the compilation of the 
    3 ; Windows TeXmacs installer
    4 
    5 [Setup]
    6 AppName=TeXmacs
    7 AppVerName=Texmacs
    8 DefaultDirName={commonpf32}\TeXmacs
    9 DefaultGroupName=TeXmacs
   10 ;denis begin
   11 VersionInfoTextVersion=2.1.2
   12 AppPublisher=MAGIX
   13 AppPublisherURL=https://www.texmacs.org/
   14 AppVersion=2.1.2
   15 LicenseFile=..\..\..\distr\TeXmacs-Windows\LICENSE
   16 ;denis end
   17 
   18 UninstallDisplayIcon={app}\TeXmacs.ico
   19 OutputDir=..\..\..\distr\windows
   20 OutputBaseFilename=TeXmacs-2.1.2-installer
   21 ; SourceDir=../..
   22 ChangesAssociations=yes
   23 
   24 WizardImageFile=TeXmacs-large.bmp
   25 WizardImageStretch=no
   26 WizardSmallImageFile=TeXmacs-small.bmp
   27 
   28 ;PrivilegesRequired=none
   29 
   30 CloseApplications=yes
   31 
   32 [Registry]
   33 Root: HKCR; Subkey: ".tm"; ValueType: string; ValueName: ""; ValueData: "tmfile"; Flags: uninsdeletevalue
   34 Root: HKCR; Subkey: "tmfile"; ValueType: string; ValueName: ""; ValueData: "text/tm"; Flags: uninsdeletekey
   35 Root: HKCR; Subkey: "tmfile\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\TeXmacs.ico"
   36 Root: HKCR; Subkey: "tmfile\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\bin\texmacs.exe"" ""%1""" 
   37 
   38 [Files]
   39 Source: ..\..\..\distr\TeXmacs-Windows\*; DestDir: {app}; Flags: recursesubdirs createallsubdirs ignoreversion
   40 Source: TeXmacs.ico; DestDir: {app}
   41 
   42 [Icons]
   43 Name: "{group}\TeXmacs"; Filename: "{app}\bin\texmacs.exe"; IconFilename: "{app}\TeXmacs.ico"
   44 Name: "{group}\Uninstall TeXmacs"; Filename: "{uninstallexe}"
   45 Name: "{commondesktop}\TeXmacs"; Filename: "{app}\bin\texmacs.exe"; IconFilename: "{app}\TeXmacs.ico"
   46 
   47 [UninstallDelete]
   48 Type: files; Name: "{app}\*"
   49 Type: dirifempty; Name: "{app}"
   50 
   51 [Code]
   52 
   53 procedure UninstallTeXmacs();
   54 var
   55   FindRec: TFindRec;
   56   Uninstaller: String;
   57   FoundInstalled: Boolean;
   58   ConfirmedUninstall: Boolean;
   59   UninstallResultCode: integer;
   60 begin
   61   Uninstaller := '';
   62   ConfirmedUninstall := false;
   63   FoundInstalled := FindFirst(ExpandConstant('{app}/unins*.exe'), FindRec);
   64   if FoundInstalled then
   65     if MsgBox('Before installing TeXmacs into the destination folder ('
   66               + ExpandConstant('{app}') + '), it is recommened to uninstall software already present in this folder.'
   67           + #13#10 + 'Do you want to perform these uninstallations before installating?', mbConfirmation, MB_YESNO or MB_DEFBUTTON2) = idYes then
   68     ConfirmedUninstall := true;
   69   if ConfirmedUninstall then
   70   repeat
   71     Uninstaller := FindRec.Name;
   72     Exec(ExpandConstant('{app}/') + Uninstaller, '', '', SW_SHOW,
   73          ewWaitUntilTerminated, UninstallResultCode);
   74   until
   75     not FindNext(FindRec);
   76   FindClose(FindRec);
   77 end;
   78 
   79 procedure CurStepChanged(CurStep: TSetupStep);
   80 begin
   81   if (CurStep = ssInstall) then
   82     UninstallTeXmacs();
   83 end;