"Fossies" - the Fresh Open Source Software Archive

Member "libextractor-1.11/m4/glib-2.0.m4" (2 Dec 2018, 8312 Bytes) of package /linux/privat/libextractor-1.11.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the last Fossies "Diffs" side-by-side code changes report for "glib-2.0.m4": 1.8_vs_1.9.

    1 # Configure paths for GLIB
    2 # Owen Taylor     1997-2001
    3 
    4 # Increment this whenever this file is changed.
    5 #serial 1
    6 
    7 dnl AM_PATH_GLIB_2_0([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, MODULES]]]])
    8 dnl Test for GLIB, and define GLIB_CFLAGS and GLIB_LIBS, if gmodule, gobject,
    9 dnl gthread, or gio is specified in MODULES, pass to pkg-config
   10 dnl
   11 AC_DEFUN([AM_PATH_GLIB_2_0],
   12 [dnl 
   13 dnl Get the cflags and libraries from pkg-config
   14 dnl
   15 AC_ARG_ENABLE(glibtest, [  --disable-glibtest      do not try to compile and run a test GLIB program],
   16 		    , enable_glibtest=yes)
   17 
   18   pkg_config_args=glib-2.0
   19   for module in . $4
   20   do
   21       case "$module" in
   22          gmodule) 
   23              pkg_config_args="$pkg_config_args gmodule-2.0"
   24          ;;
   25          gmodule-no-export) 
   26              pkg_config_args="$pkg_config_args gmodule-no-export-2.0"
   27          ;;
   28          gobject) 
   29              pkg_config_args="$pkg_config_args gobject-2.0"
   30          ;;
   31          gthread) 
   32              pkg_config_args="$pkg_config_args gthread-2.0"
   33          ;;
   34          gio*) 
   35              pkg_config_args="$pkg_config_args $module-2.0"
   36          ;;
   37       esac
   38   done
   39 
   40   PKG_PROG_PKG_CONFIG([0.16])
   41 
   42   no_glib=""
   43 
   44   if test "x$PKG_CONFIG" = x ; then
   45     no_glib=yes
   46     PKG_CONFIG=no
   47   fi
   48 
   49   min_glib_version=ifelse([$1], ,2.0.0,$1)
   50   AC_MSG_CHECKING(for GLIB - version >= $min_glib_version)
   51 
   52   if test x$PKG_CONFIG != xno ; then
   53     ## don't try to run the test against uninstalled libtool libs
   54     if $PKG_CONFIG --uninstalled $pkg_config_args; then
   55 	  echo "Will use uninstalled version of GLib found in PKG_CONFIG_PATH"
   56 	  enable_glibtest=no
   57     fi
   58 
   59     if $PKG_CONFIG --atleast-version $min_glib_version $pkg_config_args; then
   60 	  :
   61     else
   62 	  no_glib=yes
   63     fi
   64   fi
   65 
   66   if test x"$no_glib" = x ; then
   67     GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
   68     GOBJECT_QUERY=`$PKG_CONFIG --variable=gobject_query glib-2.0`
   69     GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
   70     GLIB_COMPILE_RESOURCES=`$PKG_CONFIG --variable=glib_compile_resources gio-2.0`
   71 
   72     GLIB_CFLAGS=`$PKG_CONFIG --cflags $pkg_config_args`
   73     GLIB_LIBS=`$PKG_CONFIG --libs $pkg_config_args`
   74     glib_config_major_version=`$PKG_CONFIG --modversion glib-2.0 | \
   75            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
   76     glib_config_minor_version=`$PKG_CONFIG --modversion glib-2.0 | \
   77            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
   78     glib_config_micro_version=`$PKG_CONFIG --modversion glib-2.0 | \
   79            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
   80     if test "x$enable_glibtest" = "xyes" ; then
   81       ac_save_CFLAGS="$CFLAGS"
   82       ac_save_LIBS="$LIBS"
   83       CFLAGS="$CFLAGS $GLIB_CFLAGS"
   84       LIBS="$GLIB_LIBS $LIBS"
   85 dnl
   86 dnl Now check if the installed GLIB is sufficiently new. (Also sanity
   87 dnl checks the results of pkg-config to some extent)
   88 dnl
   89       rm -f conf.glibtest
   90       AC_TRY_RUN([
   91 #include <glib.h>
   92 #include <stdio.h>
   93 #include <stdlib.h>
   94 
   95 int 
   96 main (void)
   97 {
   98   unsigned int major, minor, micro;
   99 
  100   fclose (fopen ("conf.glibtest", "w"));
  101 
  102   if (sscanf("$min_glib_version", "%u.%u.%u", &major, &minor, &micro) != 3) {
  103      printf("%s, bad version string\n", "$min_glib_version");
  104      exit(1);
  105    }
  106 
  107   if ((glib_major_version != $glib_config_major_version) ||
  108       (glib_minor_version != $glib_config_minor_version) ||
  109       (glib_micro_version != $glib_config_micro_version))
  110     {
  111       printf("\n*** 'pkg-config --modversion glib-2.0' returned %d.%d.%d, but GLIB (%d.%d.%d)\n", 
  112              $glib_config_major_version, $glib_config_minor_version, $glib_config_micro_version,
  113              glib_major_version, glib_minor_version, glib_micro_version);
  114       printf ("*** was found! If pkg-config was correct, then it is best\n");
  115       printf ("*** to remove the old version of GLib. You may also be able to fix the error\n");
  116       printf("*** by modifying your LD_LIBRARY_PATH enviroment variable, or by editing\n");
  117       printf("*** /etc/ld.so.conf. Make sure you have run ldconfig if that is\n");
  118       printf("*** required on your system.\n");
  119       printf("*** If pkg-config was wrong, set the environment variable PKG_CONFIG_PATH\n");
  120       printf("*** to point to the correct configuration files\n");
  121     } 
  122   else if ((glib_major_version != GLIB_MAJOR_VERSION) ||
  123 	   (glib_minor_version != GLIB_MINOR_VERSION) ||
  124            (glib_micro_version != GLIB_MICRO_VERSION))
  125     {
  126       printf("*** GLIB header files (version %d.%d.%d) do not match\n",
  127 	     GLIB_MAJOR_VERSION, GLIB_MINOR_VERSION, GLIB_MICRO_VERSION);
  128       printf("*** library (version %d.%d.%d)\n",
  129 	     glib_major_version, glib_minor_version, glib_micro_version);
  130     }
  131   else
  132     {
  133       if ((glib_major_version > major) ||
  134         ((glib_major_version == major) && (glib_minor_version > minor)) ||
  135         ((glib_major_version == major) && (glib_minor_version == minor) && (glib_micro_version >= micro)))
  136       {
  137         return 0;
  138        }
  139      else
  140       {
  141         printf("\n*** An old version of GLIB (%u.%u.%u) was found.\n",
  142                glib_major_version, glib_minor_version, glib_micro_version);
  143         printf("*** You need a version of GLIB newer than %u.%u.%u. The latest version of\n",
  144 	       major, minor, micro);
  145         printf("*** GLIB is always available from ftp://ftp.gtk.org.\n");
  146         printf("***\n");
  147         printf("*** If you have already installed a sufficiently new version, this error\n");
  148         printf("*** probably means that the wrong copy of the pkg-config shell script is\n");
  149         printf("*** being found. The easiest way to fix this is to remove the old version\n");
  150         printf("*** of GLIB, but you can also set the PKG_CONFIG environment to point to the\n");
  151         printf("*** correct copy of pkg-config. (In this case, you will have to\n");
  152         printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
  153         printf("*** so that the correct libraries are found at run-time))\n");
  154       }
  155     }
  156   return 1;
  157 }
  158 ],, no_glib=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
  159        CFLAGS="$ac_save_CFLAGS"
  160        LIBS="$ac_save_LIBS"
  161      fi
  162   fi
  163   if test "x$no_glib" = x ; then
  164      AC_MSG_RESULT(yes (version $glib_config_major_version.$glib_config_minor_version.$glib_config_micro_version))
  165      ifelse([$2], , :, [$2])     
  166   else
  167      AC_MSG_RESULT(no)
  168      if test "$PKG_CONFIG" = "no" ; then
  169        echo "*** A new enough version of pkg-config was not found."
  170        echo "*** See http://www.freedesktop.org/software/pkgconfig/"
  171      else
  172        if test -f conf.glibtest ; then
  173         :
  174        else
  175           echo "*** Could not run GLIB test program, checking why..."
  176           ac_save_CFLAGS="$CFLAGS"
  177           ac_save_LIBS="$LIBS"
  178           CFLAGS="$CFLAGS $GLIB_CFLAGS"
  179           LIBS="$LIBS $GLIB_LIBS"
  180           AC_TRY_LINK([
  181 #include <glib.h>
  182 #include <stdio.h>
  183 ],      [ return ((glib_major_version) || (glib_minor_version) || (glib_micro_version)); ],
  184         [ echo "*** The test program compiled, but did not run. This usually means"
  185           echo "*** that the run-time linker is not finding GLIB or finding the wrong"
  186           echo "*** version of GLIB. If it is not finding GLIB, you'll need to set your"
  187           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
  188           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
  189           echo "*** is required on your system"
  190 	  echo "***"
  191           echo "*** If you have an old version installed, it is best to remove it, although"
  192           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH" ],
  193         [ echo "*** The test program failed to compile or link. See the file config.log for the"
  194           echo "*** exact error that occured. This usually means GLIB is incorrectly installed."])
  195           CFLAGS="$ac_save_CFLAGS"
  196           LIBS="$ac_save_LIBS"
  197        fi
  198      fi
  199      GLIB_CFLAGS=""
  200      GLIB_LIBS=""
  201      GLIB_GENMARSHAL=""
  202      GOBJECT_QUERY=""
  203      GLIB_MKENUMS=""
  204      GLIB_COMPILE_RESOURCES=""
  205      ifelse([$3], , :, [$3])
  206   fi
  207   AC_SUBST(GLIB_CFLAGS)
  208   AC_SUBST(GLIB_LIBS)
  209   AC_SUBST(GLIB_GENMARSHAL)
  210   AC_SUBST(GOBJECT_QUERY)
  211   AC_SUBST(GLIB_MKENUMS)
  212   AC_SUBST(GLIB_COMPILE_RESOURCES)
  213   rm -f conf.glibtest
  214 ])