"Fossies" - the Fresh Open Source Software Archive

Member "libextractor-1.11/m4/ac_define_dir.m4" (2 Dec 2018, 1193 Bytes) of package /linux/privat/libextractor-1.11.tar.gz:

As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. 
    1 dnl @synopsis AC_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])
    2 dnl
    3 dnl This macro _AC_DEFINEs VARNAME to the expansion of the DIR
    4 dnl variable, taking care of fixing up ${prefix} and such.
    5 dnl
    6 dnl VARNAME is offered as both a C preprocessor symbol, and an output
    7 dnl variable.
    8 dnl
    9 dnl Note that the 3 argument form is only supported with autoconf 2.13
   10 dnl and later (i.e. only where _AC_DEFINE supports 3 arguments).
   11 dnl
   12 dnl Examples:
   13 dnl
   14 dnl    AC_DEFINE_DIR(DATADIR, datadir)
   15 dnl    AC_DEFINE_DIR(PROG_PATH, bindir, [Location of installed binaries])
   16 dnl
   17 dnl @category Misc
   18 dnl @author Stepan Kasal <kasal@ucw.cz>
   19 dnl @author Andreas Schwab <schwab@suse.de>
   20 dnl @author Guido Draheim <guidod@gmx.de>
   21 dnl @author Alexandre Oliva
   22 dnl @version 2005-01-17
   23 dnl @license AllPermissive
   24 
   25 AC_DEFUN([AC_DEFINE_DIR], [
   26   prefix_NONE=
   27   exec_prefix_NONE=
   28   test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
   29   test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
   30   eval ac_define_dir="\"[$]$2\""
   31   AC_SUBST($1, "$ac_define_dir")
   32   AC_DEFINE_UNQUOTED($1, "$ac_define_dir", [$3])
   33   test "$prefix_NONE" && prefix=NONE
   34   test "$exec_prefix_NONE" && exec_prefix=NONE
   35 ])