"Fossies" - the Fresh Open Source Software Archive

Member "gtklp-1.3.4/m4/po.m4" (1 Nov 2019, 18831 Bytes) of package /linux/privat/gtklp-1.3.4.src.tar.gz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes report for "po.m4": 1.3.3_vs_1.3.4.

    1 # po.m4 serial 30 (gettext-0.20)
    2 dnl Copyright (C) 1995-2014, 2016, 2018-2019 Free Software Foundation, Inc.
    3 dnl This file is free software; the Free Software Foundation
    4 dnl gives unlimited permission to copy and/or distribute it,
    5 dnl with or without modifications, as long as this notice is preserved.
    6 dnl
    7 dnl This file can be used in projects which are not available under
    8 dnl the GNU General Public License or the GNU Library General Public
    9 dnl License but which still want to provide support for the GNU gettext
   10 dnl functionality.
   11 dnl Please note that the actual code of the GNU gettext library is covered
   12 dnl by the GNU Library General Public License, and the rest of the GNU
   13 dnl gettext package is covered by the GNU General Public License.
   14 dnl They are *not* in the public domain.
   15 
   16 dnl Authors:
   17 dnl   Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
   18 dnl   Bruno Haible <haible@clisp.cons.org>, 2000-2003.
   19 
   20 AC_PREREQ([2.60])
   21 
   22 dnl Checks for all prerequisites of the po subdirectory.
   23 AC_DEFUN([AM_PO_SUBDIRS],
   24 [
   25   AC_REQUIRE([AC_PROG_MAKE_SET])dnl
   26   AC_REQUIRE([AC_PROG_INSTALL])dnl
   27   AC_REQUIRE([AC_PROG_MKDIR_P])dnl
   28   AC_REQUIRE([AC_PROG_SED])dnl
   29   AC_REQUIRE([AM_NLS])dnl
   30 
   31   dnl Release version of the gettext macros. This is used to ensure that
   32   dnl the gettext macros and po/Makefile.in.in are in sync.
   33   AC_SUBST([GETTEXT_MACRO_VERSION], [0.20])
   34 
   35   dnl Perform the following tests also if --disable-nls has been given,
   36   dnl because they are needed for "make dist" to work.
   37 
   38   dnl Search for GNU msgfmt in the PATH.
   39   dnl The first test excludes Solaris msgfmt and early GNU msgfmt versions.
   40   dnl The second test excludes FreeBSD msgfmt.
   41   AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
   42     [$ac_dir/$ac_word --statistics /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 &&
   43      (if $ac_dir/$ac_word --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
   44     :)
   45   AC_PATH_PROG([GMSGFMT], [gmsgfmt], [$MSGFMT])
   46 
   47   dnl Test whether it is GNU msgfmt >= 0.15.
   48 changequote(,)dnl
   49   case `$GMSGFMT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in
   50     '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) GMSGFMT_015=: ;;
   51     *) GMSGFMT_015=$GMSGFMT ;;
   52   esac
   53 changequote([,])dnl
   54   AC_SUBST([GMSGFMT_015])
   55 
   56   dnl Search for GNU xgettext 0.12 or newer in the PATH.
   57   dnl The first test excludes Solaris xgettext and early GNU xgettext versions.
   58   dnl The second test excludes FreeBSD xgettext.
   59   AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
   60     [$ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 &&
   61      (if $ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
   62     :)
   63   dnl Remove leftover from FreeBSD xgettext call.
   64   rm -f messages.po
   65 
   66   dnl Test whether it is GNU xgettext >= 0.15.
   67 changequote(,)dnl
   68   case `$XGETTEXT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in
   69     '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) XGETTEXT_015=: ;;
   70     *) XGETTEXT_015=$XGETTEXT ;;
   71   esac
   72 changequote([,])dnl
   73   AC_SUBST([XGETTEXT_015])
   74 
   75   dnl Search for GNU msgmerge 0.11 or newer in the PATH.
   76   AM_PATH_PROG_WITH_TEST(MSGMERGE, msgmerge,
   77     [$ac_dir/$ac_word --update -q /dev/null /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1], :)
   78 
   79   dnl Test whether it is GNU msgmerge >= 0.20.
   80   if LC_ALL=C $MSGMERGE --help | grep ' --for-msgfmt ' >/dev/null; then
   81     MSGMERGE_FOR_MSGFMT_OPTION='--for-msgfmt'
   82   else
   83     dnl Test whether it is GNU msgmerge >= 0.12.
   84     if LC_ALL=C $MSGMERGE --help | grep ' --no-fuzzy-matching ' >/dev/null; then
   85       MSGMERGE_FOR_MSGFMT_OPTION='--no-fuzzy-matching --no-location --quiet'
   86     else
   87       dnl With these old versions, $(MSGMERGE) $(MSGMERGE_FOR_MSGFMT_OPTION) is
   88       dnl slow. But this is not a big problem, as such old gettext versions are
   89       dnl hardly in use any more.
   90       MSGMERGE_FOR_MSGFMT_OPTION='--no-location --quiet'
   91     fi
   92   fi
   93   AC_SUBST([MSGMERGE_FOR_MSGFMT_OPTION])
   94 
   95   dnl Support for AM_XGETTEXT_OPTION.
   96   test -n "${XGETTEXT_EXTRA_OPTIONS+set}" || XGETTEXT_EXTRA_OPTIONS=
   97   AC_SUBST([XGETTEXT_EXTRA_OPTIONS])
   98 
   99   AC_CONFIG_COMMANDS([po-directories], [[
  100     for ac_file in $CONFIG_FILES; do
  101       # Support "outfile[:infile[:infile...]]"
  102       case "$ac_file" in
  103         *:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;;
  104       esac
  105       # PO directories have a Makefile.in generated from Makefile.in.in.
  106       case "$ac_file" in */Makefile.in)
  107         # Adjust a relative srcdir.
  108         ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
  109         ac_dir_suffix=/`echo "$ac_dir"|sed 's%^\./%%'`
  110         ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
  111         # In autoconf-2.13 it is called $ac_given_srcdir.
  112         # In autoconf-2.50 it is called $srcdir.
  113         test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
  114         case "$ac_given_srcdir" in
  115           .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
  116           /*) top_srcdir="$ac_given_srcdir" ;;
  117           *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
  118         esac
  119         # Treat a directory as a PO directory if and only if it has a
  120         # POTFILES.in file. This allows packages to have multiple PO
  121         # directories under different names or in different locations.
  122         if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then
  123           rm -f "$ac_dir/POTFILES"
  124           test -n "$as_me" && echo "$as_me: creating $ac_dir/POTFILES" || echo "creating $ac_dir/POTFILES"
  125           gt_tab=`printf '\t'`
  126           cat "$ac_given_srcdir/$ac_dir/POTFILES.in" | sed -e "/^#/d" -e "/^[ ${gt_tab}]*\$/d" -e "s,.*,     $top_srcdir/& \\\\," | sed -e "\$s/\(.*\) \\\\/\1/" > "$ac_dir/POTFILES"
  127           POMAKEFILEDEPS="POTFILES.in"
  128           # ALL_LINGUAS, POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES depend
  129           # on $ac_dir but don't depend on user-specified configuration
  130           # parameters.
  131           if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
  132             # The LINGUAS file contains the set of available languages.
  133             if test -n "$OBSOLETE_ALL_LINGUAS"; then
  134               test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
  135             fi
  136             ALL_LINGUAS=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"`
  137             POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS"
  138           else
  139             # The set of available languages was given in configure.in.
  140             ALL_LINGUAS=$OBSOLETE_ALL_LINGUAS
  141           fi
  142           # Compute POFILES
  143           # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po)
  144           # Compute UPDATEPOFILES
  145           # as      $(foreach lang, $(ALL_LINGUAS), $(lang).po-update)
  146           # Compute DUMMYPOFILES
  147           # as      $(foreach lang, $(ALL_LINGUAS), $(lang).nop)
  148           # Compute GMOFILES
  149           # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo)
  150           case "$ac_given_srcdir" in
  151             .) srcdirpre= ;;
  152             *) srcdirpre='$(srcdir)/' ;;
  153           esac
  154           POFILES=
  155           UPDATEPOFILES=
  156           DUMMYPOFILES=
  157           GMOFILES=
  158           for lang in $ALL_LINGUAS; do
  159             POFILES="$POFILES $srcdirpre$lang.po"
  160             UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
  161             DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
  162             GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
  163           done
  164           # CATALOGS depends on both $ac_dir and the user's LINGUAS
  165           # environment variable.
  166           INST_LINGUAS=
  167           if test -n "$ALL_LINGUAS"; then
  168             for presentlang in $ALL_LINGUAS; do
  169               useit=no
  170               if test "%UNSET%" != "$LINGUAS"; then
  171                 desiredlanguages="$LINGUAS"
  172               else
  173                 desiredlanguages="$ALL_LINGUAS"
  174               fi
  175               for desiredlang in $desiredlanguages; do
  176                 # Use the presentlang catalog if desiredlang is
  177                 #   a. equal to presentlang, or
  178                 #   b. a variant of presentlang (because in this case,
  179                 #      presentlang can be used as a fallback for messages
  180                 #      which are not translated in the desiredlang catalog).
  181                 case "$desiredlang" in
  182                   "$presentlang"*) useit=yes;;
  183                 esac
  184               done
  185               if test $useit = yes; then
  186                 INST_LINGUAS="$INST_LINGUAS $presentlang"
  187               fi
  188             done
  189           fi
  190           CATALOGS=
  191           if test -n "$INST_LINGUAS"; then
  192             for lang in $INST_LINGUAS; do
  193               CATALOGS="$CATALOGS $lang.gmo"
  194             done
  195           fi
  196           test -n "$as_me" && echo "$as_me: creating $ac_dir/Makefile" || echo "creating $ac_dir/Makefile"
  197           sed -e "/^POTFILES =/r $ac_dir/POTFILES" -e "/^# Makevars/r $ac_given_srcdir/$ac_dir/Makevars" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@POMAKEFILEDEPS@|$POMAKEFILEDEPS|g" "$ac_dir/Makefile.in" > "$ac_dir/Makefile"
  198           for f in "$ac_given_srcdir/$ac_dir"/Rules-*; do
  199             if test -f "$f"; then
  200               case "$f" in
  201                 *.orig | *.bak | *~) ;;
  202                 *) cat "$f" >> "$ac_dir/Makefile" ;;
  203               esac
  204             fi
  205           done
  206         fi
  207         ;;
  208       esac
  209     done]],
  210    [# Capture the value of obsolete ALL_LINGUAS because we need it to compute
  211     # POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES, CATALOGS.
  212     OBSOLETE_ALL_LINGUAS="$ALL_LINGUAS"
  213     # Capture the value of LINGUAS because we need it to compute CATALOGS.
  214     LINGUAS="${LINGUAS-%UNSET%}"
  215    ])
  216 ])
  217 
  218 dnl Postprocesses a Makefile in a directory containing PO files.
  219 AC_DEFUN([AM_POSTPROCESS_PO_MAKEFILE],
  220 [
  221   # When this code is run, in config.status, two variables have already been
  222   # set:
  223   # - OBSOLETE_ALL_LINGUAS is the value of LINGUAS set in configure.in,
  224   # - LINGUAS is the value of the environment variable LINGUAS at configure
  225   #   time.
  226 
  227 changequote(,)dnl
  228   # Adjust a relative srcdir.
  229   ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
  230   ac_dir_suffix=/`echo "$ac_dir"|sed 's%^\./%%'`
  231   ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
  232   # In autoconf-2.13 it is called $ac_given_srcdir.
  233   # In autoconf-2.50 it is called $srcdir.
  234   test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
  235   case "$ac_given_srcdir" in
  236     .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
  237     /*) top_srcdir="$ac_given_srcdir" ;;
  238     *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
  239   esac
  240 
  241   # Find a way to echo strings without interpreting backslash.
  242   if test "X`(echo '\t') 2>/dev/null`" = 'X\t'; then
  243     gt_echo='echo'
  244   else
  245     if test "X`(printf '%s\n' '\t') 2>/dev/null`" = 'X\t'; then
  246       gt_echo='printf %s\n'
  247     else
  248       echo_func () {
  249         cat <<EOT
  250 $*
  251 EOT
  252       }
  253       gt_echo='echo_func'
  254     fi
  255   fi
  256 
  257   # A sed script that extracts the value of VARIABLE from a Makefile.
  258   tab=`printf '\t'`
  259   sed_x_variable='
  260 # Test if the hold space is empty.
  261 x
  262 s/P/P/
  263 x
  264 ta
  265 # Yes it was empty. Look if we have the expected variable definition.
  266 /^['"${tab}"' ]*VARIABLE['"${tab}"' ]*=/{
  267   # Seen the first line of the variable definition.
  268   s/^['"${tab}"' ]*VARIABLE['"${tab}"' ]*=//
  269   ba
  270 }
  271 bd
  272 :a
  273 # Here we are processing a line from the variable definition.
  274 # Remove comment, more precisely replace it with a space.
  275 s/#.*$/ /
  276 # See if the line ends in a backslash.
  277 tb
  278 :b
  279 s/\\$//
  280 # Print the line, without the trailing backslash.
  281 p
  282 tc
  283 # There was no trailing backslash. The end of the variable definition is
  284 # reached. Clear the hold space.
  285 s/^.*$//
  286 x
  287 bd
  288 :c
  289 # A trailing backslash means that the variable definition continues in the
  290 # next line. Put a nonempty string into the hold space to indicate this.
  291 s/^.*$/P/
  292 x
  293 :d
  294 '
  295 changequote([,])dnl
  296 
  297   # Set POTFILES to the value of the Makefile variable POTFILES.
  298   sed_x_POTFILES=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/POTFILES/g'`
  299   POTFILES=`sed -n -e "$sed_x_POTFILES" < "$ac_file"`
  300   # Compute POTFILES_DEPS as
  301   #   $(foreach file, $(POTFILES), $(top_srcdir)/$(file))
  302   POTFILES_DEPS=
  303   for file in $POTFILES; do
  304     POTFILES_DEPS="$POTFILES_DEPS "'$(top_srcdir)/'"$file"
  305   done
  306   POMAKEFILEDEPS=""
  307 
  308   if test -n "$OBSOLETE_ALL_LINGUAS"; then
  309     test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
  310   fi
  311   if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
  312     # The LINGUAS file contains the set of available languages.
  313     ALL_LINGUAS=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"`
  314     POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS"
  315   else
  316     # Set ALL_LINGUAS to the value of the Makefile variable LINGUAS.
  317     sed_x_LINGUAS=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/LINGUAS/g'`
  318     ALL_LINGUAS=`sed -n -e "$sed_x_LINGUAS" < "$ac_file"`
  319   fi
  320   # Compute POFILES
  321   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po)
  322   # Compute UPDATEPOFILES
  323   # as      $(foreach lang, $(ALL_LINGUAS), $(lang).po-update)
  324   # Compute DUMMYPOFILES
  325   # as      $(foreach lang, $(ALL_LINGUAS), $(lang).nop)
  326   # Compute GMOFILES
  327   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo)
  328   # Compute PROPERTIESFILES
  329   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(DOMAIN)_$(lang).properties)
  330   # Compute CLASSFILES
  331   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(DOMAIN)_$(lang).class)
  332   # Compute QMFILES
  333   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).qm)
  334   # Compute MSGFILES
  335   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang)).msg)
  336   # Compute RESOURCESDLLFILES
  337   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang))/$(DOMAIN).resources.dll)
  338   case "$ac_given_srcdir" in
  339     .) srcdirpre= ;;
  340     *) srcdirpre='$(srcdir)/' ;;
  341   esac
  342   POFILES=
  343   UPDATEPOFILES=
  344   DUMMYPOFILES=
  345   GMOFILES=
  346   PROPERTIESFILES=
  347   CLASSFILES=
  348   QMFILES=
  349   MSGFILES=
  350   RESOURCESDLLFILES=
  351   for lang in $ALL_LINGUAS; do
  352     POFILES="$POFILES $srcdirpre$lang.po"
  353     UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
  354     DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
  355     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
  356     PROPERTIESFILES="$PROPERTIESFILES \$(srcdir)/\$(DOMAIN)_$lang.properties"
  357     CLASSFILES="$CLASSFILES \$(srcdir)/\$(DOMAIN)_$lang.class"
  358     QMFILES="$QMFILES $srcdirpre$lang.qm"
  359     frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
  360     MSGFILES="$MSGFILES $srcdirpre$frobbedlang.msg"
  361     frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
  362     RESOURCESDLLFILES="$RESOURCESDLLFILES $srcdirpre$frobbedlang/\$(DOMAIN).resources.dll"
  363   done
  364   # CATALOGS depends on both $ac_dir and the user's LINGUAS
  365   # environment variable.
  366   INST_LINGUAS=
  367   if test -n "$ALL_LINGUAS"; then
  368     for presentlang in $ALL_LINGUAS; do
  369       useit=no
  370       if test "%UNSET%" != "$LINGUAS"; then
  371         desiredlanguages="$LINGUAS"
  372       else
  373         desiredlanguages="$ALL_LINGUAS"
  374       fi
  375       for desiredlang in $desiredlanguages; do
  376         # Use the presentlang catalog if desiredlang is
  377         #   a. equal to presentlang, or
  378         #   b. a variant of presentlang (because in this case,
  379         #      presentlang can be used as a fallback for messages
  380         #      which are not translated in the desiredlang catalog).
  381         case "$desiredlang" in
  382           "$presentlang"*) useit=yes;;
  383         esac
  384       done
  385       if test $useit = yes; then
  386         INST_LINGUAS="$INST_LINGUAS $presentlang"
  387       fi
  388     done
  389   fi
  390   CATALOGS=
  391   JAVACATALOGS=
  392   QTCATALOGS=
  393   TCLCATALOGS=
  394   CSHARPCATALOGS=
  395   if test -n "$INST_LINGUAS"; then
  396     for lang in $INST_LINGUAS; do
  397       CATALOGS="$CATALOGS $lang.gmo"
  398       JAVACATALOGS="$JAVACATALOGS \$(DOMAIN)_$lang.properties"
  399       QTCATALOGS="$QTCATALOGS $lang.qm"
  400       frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
  401       TCLCATALOGS="$TCLCATALOGS $frobbedlang.msg"
  402       frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
  403       CSHARPCATALOGS="$CSHARPCATALOGS $frobbedlang/\$(DOMAIN).resources.dll"
  404     done
  405   fi
  406 
  407   sed -e "s|@POTFILES_DEPS@|$POTFILES_DEPS|g" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@PROPERTIESFILES@|$PROPERTIESFILES|g" -e "s|@CLASSFILES@|$CLASSFILES|g" -e "s|@QMFILES@|$QMFILES|g" -e "s|@MSGFILES@|$MSGFILES|g" -e "s|@RESOURCESDLLFILES@|$RESOURCESDLLFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@JAVACATALOGS@|$JAVACATALOGS|g" -e "s|@QTCATALOGS@|$QTCATALOGS|g" -e "s|@TCLCATALOGS@|$TCLCATALOGS|g" -e "s|@CSHARPCATALOGS@|$CSHARPCATALOGS|g" -e 's,^#distdir:,distdir:,' < "$ac_file" > "$ac_file.tmp"
  408   tab=`printf '\t'`
  409   if grep -l '@TCLCATALOGS@' "$ac_file" > /dev/null; then
  410     # Add dependencies that cannot be formulated as a simple suffix rule.
  411     for lang in $ALL_LINGUAS; do
  412       frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
  413       cat >> "$ac_file.tmp" <<EOF
  414 $frobbedlang.msg: $lang.po
  415 ${tab}@echo "\$(MSGFMT) -c --tcl -d \$(srcdir) -l $lang $srcdirpre$lang.po"; \
  416 ${tab}\$(MSGFMT) -c --tcl -d "\$(srcdir)" -l $lang $srcdirpre$lang.po || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; }
  417 EOF
  418     done
  419   fi
  420   if grep -l '@CSHARPCATALOGS@' "$ac_file" > /dev/null; then
  421     # Add dependencies that cannot be formulated as a simple suffix rule.
  422     for lang in $ALL_LINGUAS; do
  423       frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
  424       cat >> "$ac_file.tmp" <<EOF
  425 $frobbedlang/\$(DOMAIN).resources.dll: $lang.po
  426 ${tab}@echo "\$(MSGFMT) -c --csharp -d \$(srcdir) -l $lang $srcdirpre$lang.po -r \$(DOMAIN)"; \
  427 ${tab}\$(MSGFMT) -c --csharp -d "\$(srcdir)" -l $lang $srcdirpre$lang.po -r "\$(DOMAIN)" || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; }
  428 EOF
  429     done
  430   fi
  431   if test -n "$POMAKEFILEDEPS"; then
  432     cat >> "$ac_file.tmp" <<EOF
  433 Makefile: $POMAKEFILEDEPS
  434 EOF
  435   fi
  436   mv "$ac_file.tmp" "$ac_file"
  437 ])
  438 
  439 dnl Initializes the accumulator used by AM_XGETTEXT_OPTION.
  440 AC_DEFUN([AM_XGETTEXT_OPTION_INIT],
  441 [
  442   XGETTEXT_EXTRA_OPTIONS=
  443 ])
  444 
  445 dnl Registers an option to be passed to xgettext in the po subdirectory.
  446 AC_DEFUN([AM_XGETTEXT_OPTION],
  447 [
  448   AC_REQUIRE([AM_XGETTEXT_OPTION_INIT])
  449   XGETTEXT_EXTRA_OPTIONS="$XGETTEXT_EXTRA_OPTIONS $1"
  450 ])