"Fossies" - the Fresh Open Source Software Archive

Member "glibmm-2.74.0/configure.ac" (19 Sep 2022, 6320 Bytes) of package /linux/misc/glibmm-2.74.0.tar.xz:


As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) C and C++ source code syntax highlighting (style: standard) with prefixed line numbers and code folding option. Alternatively you can here view or download the uninterpreted source code file. See also the latest Fossies "Diffs" side-by-side code changes reports for "configure.ac": 2.73.2_vs_2.74.0 or 2.72.1_vs_2.74.0.

    1 ## Copyright (c) 2009  Openismus GmbH  <http://www.openismus.com/>
    2 ##
    3 ## This file is part of glibmm.
    4 ##
    5 ## glibmm is free software: you can redistribute it and/or modify it
    6 ## under the terms of the GNU Lesser General Public License as published
    7 ## by the Free Software Foundation, either version 2.1 of the License,
    8 ## or (at your option) any later version.
    9 ##
   10 ## glibmm is distributed in the hope that it will be useful, but
   11 ## WITHOUT ANY WARRANTY; without even the implied warranty of
   12 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
   13 ## See the GNU Lesser General Public License for more details.
   14 ##
   15 ## You should have received a copy of the GNU Lesser General Public License
   16 ## along with this library.  If not, see <http://www.gnu.org/licenses/>.
   17 
   18 AC_INIT([glibmm], [2.74.0],
   19         [https://gitlab.gnome.org/GNOME/glibmm/issues],
   20         [glibmm], [http://www.gtkmm.org/])
   21 AC_PREREQ([2.59])
   22 
   23 AC_CONFIG_SRCDIR([glib/glibmm.h])
   24 AC_CONFIG_AUX_DIR([build])
   25 AC_CONFIG_MACRO_DIR([build])
   26 AC_CONFIG_HEADERS([config.h glib/glibmmconfig.h gio/giommconfig.h])
   27 
   28 AM_INIT_AUTOMAKE([1.9 -Wno-portability no-dist-gzip dist-xz tar-ustar no-define nostdinc])
   29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   30 AM_MAINTAINER_MODE
   31 AC_ARG_VAR([ACLOCAL_FLAGS], [aclocal flags, e.g. -I <macro dir>])
   32 
   33 MM_PREREQ([0.9.12])
   34 MM_INIT_MODULE([glibmm-2.68])
   35 MM_INIT_MODULE([giomm-2.68])
   36 
   37 # Copy the mm-common .pl scripts into docs/,
   38 # and use them from there,
   39 # so we can dist them to avoid a tarball-build dependency.
   40 MM_CONFIG_DOCTOOL_DIR([docs])
   41 
   42 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   43 AC_SUBST([LIBGLIBMM_SO_VERSION], [4:0:3])
   44 AC_SUBST([MSVC_TOOLSET_VER], [''])
   45 
   46 AC_PROG_CXX
   47 MM_AX_CXX_COMPILE_STDCXX([17], [noext], [mandatory])
   48 
   49 AC_DISABLE_STATIC
   50 LT_INIT([win32-dll])
   51 MM_PATH_PERL
   52 AS_IF([test "x$USE_MAINTAINER_MODE" != xno], [MM_CHECK_PERL])
   53 
   54 AC_MSG_CHECKING([for native Windows host])
   55 AS_CASE([$host_os], [mingw*], [glibmm_host_windows=yes], [glibmm_host_windows=no])
   56 AC_MSG_RESULT([$glibmm_host_windows])
   57 AM_CONDITIONAL([HOST_WINDOWS_NATIVE], [test "x$glibmm_host_windows" = xyes])
   58 
   59 # This test for Mac OS is copied from glib. If the result of glib's test
   60 # is ever made available outside glib, use glib's result instead of this test.
   61 # glib: https://bugzilla.gnome.org/show_bug.cgi?id=780309
   62 # glibmm: https://bugzilla.gnome.org/show_bug.cgi?id=781947
   63 glibmm_have_cocoa=no
   64 AC_MSG_CHECKING([for Mac OS X Cocoa support])
   65 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
   66 #include <Cocoa/Cocoa.h>
   67 #ifdef GNUSTEP_BASE_VERSION
   68 #error "Detected GNUstep, not Cocoa"
   69 #endif
   70 ]])],[glibmm_have_cocoa=yes],[])
   71 
   72 AC_MSG_RESULT([$glibmm_have_cocoa])
   73 AM_CONDITIONAL(OS_COCOA, [test "$glibmm_have_cocoa" = "yes"])
   74 AS_IF([test "$glibmm_have_cocoa" = "yes"],
   75 [
   76   AC_DEFINE([GLIBMM_OS_COCOA], [1], [Define only on Mac OS, COCOA])
   77 ])
   78 
   79 # TODO: This makes no sense. --danielk
   80 AS_IF([test "x$enable_static" = xyes],
   81 [
   82   AC_DEFINE([GLIBMM_STATIC_LIB], [1], [Define if glibmm is built as a static library])
   83   AC_DEFINE([GIOMM_STATIC_LIB],  [1], [Define if giomm is built as a static library])
   84 ])
   85 
   86 glibreq='2.0 >= 2.73.2'
   87 
   88 GLIBMM_MODULES="sigc++-3.0 >= 3.0.0 glib-$glibreq gobject-$glibreq gmodule-$glibreq"
   89 GIOMM_MODULES="$GLIBMM_MODULES gio-$glibreq"
   90 test "x$glibmm_host_windows" = xyes || GIOMM_MODULES="$GIOMM_MODULES gio-unix-$glibreq"
   91 
   92 PKG_CHECK_MODULES([GLIBMM], [$GLIBMM_MODULES])
   93 PKG_CHECK_MODULES([GIOMM],  [$GIOMM_MODULES])
   94 
   95 AC_CHECK_PROGS([M4], [gm4 m4], [m4])
   96 GLIB_GSETTINGS
   97 
   98 AC_CHECK_FUNCS([flockfile funlockfile getc_unlocked mkfifo])
   99 
  100 # Ensure MSVC-compatible struct packing convention is used when
  101 # compiling for Win32 with gcc.
  102 # TODO: Disabled for now. I don't think this should be enabled by the
  103 # libraries themselves on behalf of the user.  That makes no sense as
  104 # it is a platform-wide ABI choice.
  105 
  106 AC_LANG([C++])
  107 
  108 AC_CHECK_SIZEOF([wchar_t])
  109 DK_CHECK_FEATURE([wide stream],
  110 [
  111   AC_LANG_PROGRAM([[#include <sstream>]],
  112                   [[std::wostringstream s; (void) s.str();]])
  113 ])
  114 
  115 GLIBMM_CXX_HAS_STD_ITERATOR_TRAITS
  116 GLIBMM_CXX_HAS_SUN_REVERSE_ITERATOR
  117 GLIBMM_CXX_HAS_TEMPLATE_SEQUENCE_CTORS
  118 GLIBMM_CXX_CAN_DISAMBIGUATE_CONST_TEMPLATE_SPECIALIZATIONS
  119 GLIBMM_CXX_CAN_USE_DYNAMIC_CAST_IN_UNUSED_TEMPLATE_WITHOUT_DEFINITION
  120 GLIBMM_CXX_CAN_ASSIGN_NON_EXTERN_C_FUNCTIONS_TO_EXTERN_C_CALLBACKS
  121 GLIBMM_CXX_ALLOWS_STATIC_INLINE_NPOS
  122 
  123 MM_ARG_ENABLE_DOCUMENTATION
  124 MM_ARG_WITH_TAGFILE_DOC([libstdc++.tag], [mm-common-libstdc++])
  125 MM_ARG_WITH_TAGFILE_DOC([libsigc++-3.0.tag], [sigc++-3.0])
  126 
  127 # Check whether --enable-debug-refcounting was given.
  128 GLIBMM_ARG_ENABLE_DEBUG_REFCOUNTING
  129 
  130 # Evaluate the --enable-warnings=level option.
  131 MM_ARG_ENABLE_WARNINGS([GLIBMM_WXXFLAGS],
  132                        [-Wall],
  133                        [-pedantic -Wall -Wextra -Wformat-security -Wsuggest-override -Wshadow -Wno-long-long],
  134                        [G SIGCXX])
  135 
  136 # Offer the ability to omit some API from the library,
  137 # to reduce the code size:
  138 MM_ARG_DISABLE_DEPRECATED_API([GLIBMM GIOMM])
  139 
  140 AC_CHECK_PROGS([CLANG_FORMAT], [clang-format clang-format-3.9 clang-format-3.8 clang-format-3.7], [])
  141 AM_CONDITIONAL([HAVE_CLANG_FORMAT], test -n "$CLANG_FORMAT")
  142 
  143 AC_CONFIG_FILES([Makefile
  144                  tools/Makefile
  145                  tools/gmmproc
  146                  tools/generate_wrap_init.pl
  147                  glib/${GLIBMM_MODULE_NAME}.pc:glib/glibmm.pc.in
  148                  glib/${GLIBMM_MODULE_NAME}-uninstalled.pc:glib/glibmm-uninstalled.pc.in
  149                  glib/src/Makefile
  150                  glib/glibmm/Makefile
  151                  gio/${GIOMM_MODULE_NAME}.pc:gio/giomm.pc.in
  152                  gio/${GIOMM_MODULE_NAME}-uninstalled.pc:gio/giomm-uninstalled.pc.in
  153                  gio/src/Makefile
  154                  gio/giomm/Makefile
  155                  tests/Makefile
  156                  examples/Makefile
  157                  docs/Makefile
  158                  docs/reference/Doxyfile
  159                  MSVC_NMake/glibmm/glibmm.rc
  160                  MSVC_NMake/giomm/giomm.rc])
  161 
  162 # Copy the generated configuration headers into the MSVC project directories.
  163 AC_CONFIG_COMMANDS([MSVC_NMake/glibmm/glibmmconfig.h],
  164                    [cp -f glib/glibmmconfig.h MSVC_NMake/glibmm/glibmmconfig.h])
  165 AC_CONFIG_COMMANDS([MSVC_NMake/giomm/giommconfig.h],
  166                    [cp -f gio/giommconfig.h MSVC_NMake/giomm/giommconfig.h])
  167 AC_OUTPUT