"Fossies" - the Fresh Open Source Software Archive

Member "fuse-3.2.3/example/meson.build" (11 May 2018, 1167 Bytes) of package /linux/misc/fuse-3.2.3.tar.xz:


As a special service "Fossies" has tried to format the requested text file into HTML format (style: standard) with prefixed line numbers. Alternatively you can here view or download the uninterpreted source code file. See also the last Fossies "Diffs" side-by-side code changes report for "meson.build": 3.2.1_vs_3.2.2.

    1 examples = [ 'passthrough', 'passthrough_fh',
    2              'hello', 'hello_ll', 'printcap',
    3              'ioctl_client', 'poll_client', 'ioctl',
    4              'cuse', 'cuse_client' ]
    5 
    6 if not platform.endswith('bsd') and platform != 'dragonfly'
    7     examples += 'passthrough_ll'
    8 
    9     # According to Conrad Meyer <cem@freebsd.org>, FreeBSD doesn't
   10     # support mounting files, This is enforced in vfs_domount_first()
   11     # with the v_type != VDIR check.
   12     examples += [ 'null' ]
   13 endif
   14 
   15 threaded_examples = [ 'notify_inval_inode',
   16                       'invalidate_path',
   17                       'notify_store_retrieve',
   18                       'notify_inval_entry',
   19                       'poll' ]
   20 
   21 foreach ex : examples
   22     executable(ex, ex + '.c',
   23                include_directories: include_dirs,
   24                link_with: [ libfuse ],
   25                install: false)
   26 endforeach
   27 
   28 
   29 foreach ex : threaded_examples
   30     executable(ex, ex + '.c',
   31                include_directories: include_dirs,
   32                link_with: [ libfuse ],
   33                dependencies: thread_dep,
   34                install: false)
   35 endforeach
   36 
   37 # TODO: Link passthrough_fh with ulockmgr if available