"Fossies" - the Fresh Open Source Software Archive

Member "elasticsearch-6.8.23/settings.gradle" (29 Dec 2021, 3339 Bytes) of package /linux/www/elasticsearch-6.8.23-src.tar.gz:


As a special service "Fossies" has tried to format the requested source page into HTML format using (guessed) Java source code syntax highlighting (style: standard) with prefixed line numbers and code folding option. Alternatively you can here view or download the uninterpreted source code file.

    1 import org.elasticsearch.gradle.Version
    2 
    3 rootProject.name = "elasticsearch"
    4 
    5 List projects = [
    6   'build-tools',
    7   'rest-api-spec',
    8   'docs',
    9   'client:rest',
   10   'client:rest-high-level',
   11   'client:sniffer',
   12   'client:transport',
   13   'client:test',
   14   'client:client-benchmark-noop-api-plugin',
   15   'client:benchmark',
   16   'benchmarks',
   17   'distribution:archives:integ-test-zip',
   18   'distribution:archives:oss-zip',
   19   'distribution:archives:zip',
   20   'distribution:archives:oss-tar',
   21   'distribution:archives:tar',
   22   'distribution:docker',
   23   'distribution:docker:oss-docker-build-context',
   24   'distribution:docker:docker-build-context',
   25   'distribution:packages:oss-deb',
   26   'distribution:packages:deb',
   27   'distribution:packages:oss-rpm',
   28   'distribution:packages:rpm',
   29   'distribution:bwc:bugfix',
   30   'distribution:bwc:maintenance',
   31   'distribution:bwc:minor',
   32   'distribution:bwc:staged',
   33   'distribution:tools:java-version-checker',
   34   'distribution:tools:launchers',
   35   'distribution:tools:plugin-cli',
   36   'server',
   37   'server:cli',
   38   'test:framework',
   39   'test:fixtures:hdfs-fixture',
   40   'test:fixtures:krb5kdc-fixture',
   41   'test:fixtures:old-elasticsearch',
   42   'test:logger-usage'
   43 ]
   44 
   45 /**
   46   * Iterates over sub directories, looking for build.gradle, and adds a project if found
   47   * for that dir with the given path prefix. Note that this requires each level
   48   * of the dir hierarchy to have a build.gradle. Otherwise we would have to iterate
   49   * all files/directories in the source tree to find all projects.
   50   */
   51 void addSubProjects(String path, File dir) {
   52   if (dir.isDirectory() == false) return;
   53   if (dir.name == 'buildSrc') return;
   54   if (new File(dir, 'build.gradle').exists() == false) return;
   55   if (findProject(dir) != null) return;
   56 
   57   final String projectName = "${path}:${dir.name}"
   58   include projectName
   59   if (path.isEmpty() || path.startsWith(':example-plugins')) {
   60       project(projectName).projectDir = dir
   61     }
   62     for (File subdir : dir.listFiles()) {
   63       addSubProjects(projectName, subdir)
   64     }
   65   }
   66 
   67 
   68 // include example plugins first, so adding plugin dirs below won't muck with :example-plugins
   69 File examplePluginsDir = new File(rootProject.projectDir, 'plugins/examples')
   70 for (File example : examplePluginsDir.listFiles()) {
   71   if (example.isDirectory() == false) continue;
   72   if (example.name.startsWith('build') || example.name.startsWith('.')) continue;
   73   addSubProjects(':example-plugins', example)
   74 }
   75 project(':example-plugins').projectDir = new File(rootProject.projectDir, 'plugins/examples')
   76 
   77 addSubProjects('', new File(rootProject.projectDir, 'libs'))
   78 addSubProjects('', new File(rootProject.projectDir, 'modules'))
   79 addSubProjects('', new File(rootProject.projectDir, 'plugins'))
   80 addSubProjects('', new File(rootProject.projectDir, 'qa'))
   81 addSubProjects('', new File(rootProject.projectDir, 'x-pack'))
   82 
   83 List startTasks = gradle.startParameter.taskNames
   84 
   85 include projects.toArray(new String[0])
   86 
   87 project(':build-tools').projectDir = new File(rootProject.projectDir, 'buildSrc')
   88 
   89 // look for extra plugins for elasticsearch
   90 File extraProjects = new File(rootProject.projectDir.parentFile, "${rootProject.projectDir.name}-extra")
   91 if (extraProjects.exists()) {
   92   for (File extraProjectDir : extraProjects.listFiles()) {
   93     addSubProjects('', extraProjectDir)
   94   }
   95 }
   96 
   97 project(":libs:ssl-config").name = 'elasticsearch-ssl-config'